dnl Process this file with autoconf to produce a configure script.
AC_INIT(xmms/main.c)
AC_CANONICAL_HOST

cflags_set=${CFLAGS+set}
AM_CONFIG_HEADER(config.h xmms/i18n.h)

AM_INIT_AUTOMAKE(xmms, 1.2.7)

AC_ARG_ENABLE( one-plugin-dir,
[  --enable-one-plugin-dir  use a single plugin dir [default=no]],,
		enable_one_plugin_dir="no")

AC_ARG_ENABLE( user-plugin-dir,
[  --disable-user-plugin-dir disable per-user plugin dir],,
		enable_user_plugin_dir="yes")

AC_ARG_WITH(dev-dsp, 
  [  --with-dev-dsp=path     Path to OSS DSP data pipe, default is /dev/dsp.],
	dev_dsp="$withval", dev_dsp="/dev/dsp")
AC_DEFINE_UNQUOTED(DEV_DSP,"$dev_dsp", [Path to OSS DSP, really just a data pipe, default is /dev/dsp.])

AC_ARG_WITH(dev-mixer, 
  [  --with-dev-mixer=path   Path to OSS sound mixer, default is /dev/mixer.],
	dev_mixer="$withval", dev_mixer="/dev/mixer")
AC_DEFINE_UNQUOTED(DEV_MIXER,"$dev_mixer", [Path to OSS mixer, default is /dev/mixer.])

AC_ARG_WITH(cdda-device, 
  [  --with-cdda-device=path Path to default cdaudio device.],
  AC_DEFINE_UNQUOTED(CDDA_DEVICE,"$withval", [Path to default cdaudio device.]))

AC_ARG_WITH(cdda-dir, 
  [  --with-cdda-dir=path    Path to default cdaudio directory.],
  AC_DEFINE_UNQUOTED(CDDA_DIRECTORY,"$withval", [Path to default cdaudio directory.]))

AC_PREFIX_PROGRAM(xmms)

dnl Various compiler setup.
AC_PROG_CC
AC_ISC_POSIX
dnl AC_PROG_CXX
AC_C_BIGENDIAN
AC_C_INLINE
AC_C_CONST

dnl Checks for programs.
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET

AM_DISABLE_STATIC
AM_PROG_LIBTOOL

AC_CHECK_HEADER(pthread.h,,AC_MSG_ERROR([*** POSIX thread support not installed - please install first ***]))

AM_PATH_GLIB(1.2.2,,AC_MSG_ERROR([*** GLIB >= 1.2.2 not installed - please install first ***]))
AM_PATH_GTK(1.2.2,,AC_MSG_ERROR([*** GTK+ >= 1.2.2 not installed - please install first ***]),gthread)
AC_PATH_PROG(XMMS_PATH,xmms,no)

LIBS_save=$LIBS
LIBS="$LIBS $GTK_LIBS"
SM_LIBS=""
AC_CHECK_LIB(SM, SmcOpenConnection,[
AC_DEFINE(WITH_SM)
SM_LIBS="-lSM -lICE"])
AC_SUBST(SM_LIBS)
LIBS=$LIBS_save

AC_PATH_X

CFLAGS_save=$CFLAGS
LIBS_save=$LIBS
CFLAGS="$CFLAGS $GTK_CFLAGS"
LIBS="$LIBS $GTK_LIBS"
AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,[
    AC_DEFINE(XF86VIDMODE,1,[XF86VidMode extension is present])
        VM_LIBS="-lXxf86vm"],,
    -L$x_libraries -lXext)

CFLAGS=$CFLAGS_save
LIBS=$LIBS_save
AC_SUBST(VM_LIBS)

PTHREAD_LIBS=error
AC_MSG_CHECKING(for old style FreeBSD -pthread flag)
AC_EGREP_CPP(yes,
	[#if defined(__FreeBSD_cc_version) && __FreeBSD_cc_version <= 500001
	  yes
	#endif
	], AC_MSG_RESULT(yes)
	CFLAGS="$CFLAGS -D_THREAD_SAFE" PTHREAD_LIBS="-pthread",
	AC_MSG_RESULT(no))
if test "x$PTHREAD_LIBS" = xerror; then
	AC_CHECK_LIB(pthread, pthread_attr_init,
		PTHREAD_LIBS="-lpthread")
fi
if test "x$PTHREAD_LIBS" = xerror; then
        AC_CHECK_LIB(pthreads, pthread_attr_init,
		PTHREAD_LIBS="-lpthreads")
fi
if test "x$PTHREAD_LIBS" = xerror; then
        AC_CHECK_LIB(c_r, pthread_attr_init,
		PTHREAD_LIBS="-lc_r")
fi
if test "x$PTHREAD_LIBS" = xerror; then
	AC_CHECK_FUNC(pthread_attr_init, PTHREAD_LIBS="")
fi
if test "x$PTHREAD_LIBS" = xerror; then
	AC_MSG_ERROR(*** Unable to locate working posix thread library ***)
fi
AC_SUBST(PTHREAD_LIBS)

dnl *** OpenGL
AC_ARG_ENABLE( opengl,
[  --disable-opengl        Disable OpenGL plugin(s) [default=yes]],,
		enable_opengl="yes")

if test "x$enable_opengl" = xyes; then
	LIBS_save=$LIBS
	LIBS="$LIBS $GTK_LIBS"
	OPENGL_LIBS=error
	AC_CHECK_LIB(GL, glBegin, OPENGL_LIBS="-lGL")

	if test "x$OPENGL_LIBS" = xerror; then
		AC_CHECK_LIB(MesaGL, glBegin,OPENGL_LIBS="-lMesaGL")
	fi

	CPPFLAGS_save=$CPPFLAGS
	CPPFLAGS="$GTK_CFLAGS $CPPFLAGS"
	have_opengl_headers=yes
	AC_CHECK_HEADERS(GL/gl.h GL/glx.h,,have_opengl_headers=no)

	if test "x$OPENGL_LIBS" = xerror || test "x$have_opengl_headers" = xno; then
		have_opengl=no
	else
		have_opengl=yes
	fi

	CPPFLAGS=$CPPFLAGS_save
	LIBS=$LIBS_save
else
	AC_MSG_RESULT([*** Disabling OpenGL plugins per user request ***])
	have_opengl=no
fi

AC_SUBST(OPENGL_LIBS)

AM_CONDITIONAL(HAVE_OPENGL, test "x$have_opengl" = xyes)


dnl *** zlib
LIBS_save=$LIBS
Z_LIBS=""
AC_CHECK_LIB(z, inflate, [Z_LIBS="-lz"
                          AC_DEFINE(HAVE_LIBZ,,[Define if zlib is available])])
AC_SUBST(Z_LIBS)
LIBS=$LIBS_save

dnl *** libxml
AC_ARG_ENABLE( cdindex,
[  --disable-cdindex       Disable cdindex support [default=enabled]],,
		enable_cdindex="yes")

if test "x$enable_cdindex" = xyes; then
	AM_PATH_LIBXML(1.7.0, 
	   [AC_DEFINE(WITH_CDINDEX,,[Define if libxml is present])
	    AC_CHECK_LIB(xml, xmlDocGetRootElement, 
	       AC_DEFINE(HAVE_XMLDOCGETROOTELEMENT,,
		  [Define if libxml has the xmlDocGetRootElement function]), , $XML_LIBS)], 
	   [AC_MSG_WARN([*** libxml not installed, disabling CDindex support ***])])
else
	AC_MSG_RESULT([*** CDindex support disabled per user request ***])
fi

dnl *** esound
AC_ARG_ENABLE( esd,
[  --disable-esd           Disable esound output plugin [default=enabled]],,
		enable_esd="yes")

if test "x$enable_esd" = xyes; then
	AM_PATH_ESD(0.2.8, 
	   [have_esd=yes 
	    AC_CHECK_LIB(esd, esd_get_latency, 
	       AC_DEFINE(HAVE_ESD_GET_LATENCY,,
		  [Define if libesd has the esd_get_latency function]))], 
	   have_esd=no)
else
	AC_MSG_RESULT([*** esound plugin disabled per user request ***])
	have_esd=no
fi

AM_CONDITIONAL(HAVE_ESD,test "x$have_esd" = xyes)

dnl *** mikmod
AC_ARG_ENABLE( mikmod,
[  --disable-mikmod        Disable mikmod input plugin [default=enabled]],,
		enable_mikmod="yes")

if test "x$enable_mikmod" = xyes; then
	AM_PATH_LIBMIKMOD(3.1.5,have_mikmod=yes, have_mikmod=no)
else
	AC_MSG_RESULT([*** mikmod plugin disabled per user request ***])
	have_mikmod=no
fi
AM_CONDITIONAL(HAVE_MIKMOD,test "x$have_mikmod" = xyes)

dnl *** Ogg Vorbis
AC_ARG_ENABLE( vorbis,
[  --disable-vorbis        Disable Ogg Vorbis input plugin [default=enabled]],,
		enable_vorbis="yes")

if test "x$enable_vorbis" = xyes; then
	AM_PATH_OGG(have_ogg=yes, have_ogg=no)
	AM_PATH_VORBIS(have_vorbis=yes, have_vorbis=no)
	if test "x$have_vorbis" = xyes; then
	  AC_MSG_CHECKING(if vorbis is sufficiently new)
	  CFLAGS_save=$CFLAGS
	  LIBS_save=$LIBS
	  CFLAGS="$CFLAGS $VORBIS_CFLAGS $OGG_CFLAGS"
	  LIBS="$LIBS $VORBIS_LIBS $OGG_LIBS"
	  AC_TRY_LINK(
		[#include <vorbis/codec.h>],
		[vorbis_info info;
		 ogg_packet op;
                 vorbis_packet_blocksize(&info, &op);],
		[AC_MSG_RESULT(yes)],
		[AC_MSG_RESULT([no (need atleast 1.0rc1)])
		 have_vorbis=no])
	  AC_MSG_CHECKING(if ov_read_float() takes four arguments)
	  AC_TRY_COMPILE(
		[#include <vorbis/vorbisfile.h>],
		[OggVorbis_File vf;
		 float **pcm;
		 ov_read_float(&vf, &pcm, 1024, 0);],
		[AC_MSG_RESULT(yes)],
		[AC_MSG_RESULT(no)
		 AC_DEFINE(VORBISFILE_OV_READ_FLOAT_3_ARGS,,[Define if ov_read_float only takes 3 args])])
	  CFLAGS=$CFLAGS_save
	  LIBS=$LIBS_save
	fi
	have_oggvorbis=no
	if test "x$have_ogg" = xyes
	then
	  if test "x$have_vorbis" = xyes
	  then
	    have_oggvorbis=yes
	  fi
	fi
else
	AC_MSG_RESULT([*** Ogg Vorbis plugin disabled per user request ***])
	have_oggvorbis=no
fi
AM_CONDITIONAL(HAVE_OGGVORBIS,test $have_oggvorbis = yes)

dnl *** Gnome

have_gnome="no"
GNOME_INIT_HOOK(have_gnome=yes,,"applets")
if test "x$have_gnome" = xyes
then
    CPPFLAGS_save=$CPPFLAGS
    CPPFLAGS="$CPP_FLAGS $GNOME_INCLUDEDIR"
    AC_CHECK_HEADER(applet-widget.h,,[have_gnome=no])
    CPPFLAGS=$CPPFLAGS_save
    
    AC_MSG_CHECKING(for GNOME's sysconf dir)
    GNOME_SYSCONFDIR=`$GNOME_CONFIG --sysconfdir`
    AC_SUBST(GNOME_SYSCONFDIR)
    AC_MSG_RESULT($GNOME_SYSCONFDIR)

    AC_MSG_CHECKING(for GNOME's data dir)
    GNOME_DATADIR=`$GNOME_CONFIG --datadir`
    AC_SUBST(GNOME_DATADIR)
    AC_MSG_RESULT($GNOME_DATADIR)
fi
AM_CONDITIONAL(HAVE_GNOME,test "x$have_gnome" = xyes)

dnl *** Thread-safe xlib check
CFLAGS_save=$CFLAGS
LIBS_save=$LIBS
CFLAGS="$CFLAGS $GTK_CFLAGS"
LIBS="$LIBS $GTK_LIBS"
AC_CACHE_CHECK(for thread-safe Xlib, xmms_cv_lib_xlibs_threadsafe,
[AC_TRY_RUN([
#include <X11/Xlib.h>
int main()
{
   exit(!(XInitThreads()));
}],
xmms_cv_lib_xlibs_threadsafe=yes,
xmms_cv_lib_xlibs_threadsafe=no,
xmms_cv_lib_xlibs_threadsafe=yes)])
CFLAGS=$CFLAGS_save
LIBS=$LIBS_save

dnl Set of available languages.
ALL_LINGUAS="af az bg ca cs da de el eo es eu fr ga gl hr hu id it ja ko lt lv nn nl no pl pt pt_BR ro ru sk sr sv tg th tr uk vi wa zh_CN.GB2312 zh_TW"

AM_GNU_GETTEXT

dnl Make gettext > 0.10.35 work
GMSGFMT="OLD_PO_FILE_INPUT=yes $GMSGFMT"
MSGFMT="OLD_PO_FILE_INPUT=yes $MSGFMT"

localedir=${datadir}/locale
AC_SUBST(localedir)

dnl If {type}_PLUGINS is defined, it should be a comma or space separated
dnl list of plugins that should be built, e.g.,
dnl INPUT_PLUGINS="mpg123,cdaudio cdin".  If variable is not defined, all
dnl buildable plugins are compiled.  This stuff makes life easier for
dnl automated builds that want to disable certain plugins.

for class in EFFECT GENERAL INPUT OUTPUT VISUALIZATION; do
    value=`eval echo "\\$${class}_PLUGINS"`
    if test "x${value}" = x; then
       eval ${class}_PLUGINS="\$\(ALL_PLUGINS\)"
    else
       value=`echo ${value} | sed -e 's/,/ /g'`
       eval ${class}_PLUGINS="\${value}"
    fi
done

AC_SUBST(EFFECT_PLUGINS)
AC_SUBST(GENERAL_PLUGINS)
AC_SUBST(INPUT_PLUGINS)
AC_SUBST(OUTPUT_PLUGINS)
AC_SUBST(VISUALIZATION_PLUGINS)


dnl 3DNow! instructions support
dnl ========================
AC_ARG_ENABLE(3dnow,
	[  --enable-3dnow	  build with 3DNow! instructions support],
			USE_3DNOW=$enableval, USE_3DNOW=no)
if test "x$USE_3DNOW" = xyes; then
  AC_DEFINE(USE_3DNOW)
fi
AM_CONDITIONAL(USE_3DNOW,test "x$USE_3DNOW" = xyes)
AC_SUBST(USE_3DNOW_TRUE)
dnl ========================

AC_CACHE_CHECK(for socklen_t, xmms_cv_type_socklen_t,
[AC_TRY_COMPILE(
[#include <sys/types.h>
#include <sys/socket.h>],
[socklen_t s;], xmms_cv_type_socklen_t=yes, xmms_cv_type_socklen_t=no)])
if test "x$xmms_cv_type_socklen_t" = "xno"; then
  AC_DEFINE(socklen_t, int, [Define to int if the socklen_t type is missing])
fi


AC_MSG_CHECKING(for OSS include dir)
OSS_CFLAGS=""
if test -f "/etc/oss.conf"
then
	for i in `cat /etc/oss.conf`; 
	do
		t=`echo $i | sed -e 's/OSSLIBDIR=//'`
		if test "x$i" != "x$t"
		then
			if test -f "$t/include/sys/soundcard.h"
			then
				OSS_CFLAGS="-I$t/include"
			fi
		fi
	done
fi
if test -n "$OSS_CFLAGS"
then
	AC_MSG_RESULT("$OSS_CFLAGS")
else
	AC_MSG_RESULT("not found")
fi
AC_SUBST(OSS_CFLAGS)
CPPFLAGS_save=$CPPFLAGS
CPPFLAGS="$CPPFLAGS $OSS_CFLAGS"
AC_CHECK_HEADERS(sys/soundcard.h)
AC_CHECK_HEADERS(machine/soundcard.h)
CPPFLAGS=$CPPFLAGS_save


dnl FreeBSD newpcm driver detection
AC_CACHE_CHECK(for FreeBSD newpcm driver, xmms_cv_newpcm_driver,
  if test -r "/dev/sndstat"; then
    grep 'newpcm' /dev/sndstat 2>/dev/null 1>/dev/null
    if test "x$?" = "x0"; then
      xmms_cv_newpcm_driver="yes"
    else
      xmms_cv_newpcm_driver="no"
    fi
  else
    xmms_cv_newpcm_driver="no"
  fi)
if test "x$xmms_cv_newpcm_driver" = "xyes"; then
  AC_DEFINE(HAVE_NEWPCM, 1, [Define if you have the FreeBSD newpcm driver])
fi


AC_CHECK_HEADERS(linux/cdrom.h)
AC_CHECK_HEADERS(sys/cdio.h)
AC_CHECK_HEADERS(linux/joystick.h)
AC_CHECK_HEADERS(unistd.h)
AC_CHECK_HEADERS(fcntl.h)
AC_CHECK_HEADERS(sys/ioctl.h)
AC_CHECK_HEADERS(fnmatch.h)
AC_CHECK_HEADERS(limits.h)
AC_CHECK_HEADERS(sched.h)
AC_CHECK_HEADERS(sys/sched.h)
AC_CHECK_HEADERS(wchar.h)
AC_CHECK_HEADERS(fts.h)

XMMS_FUNC_POSIX(sched_setscheduler)

AC_CHECK_FUNCS(mkdtemp)
AC_CHECK_FUNCS(getmntinfo)
AC_CHECK_FUNCS(sched_get_priority_max)
AC_CHECK_FUNCS(srandomdev)
AC_CHECK_FUNCS(iconv_open)

AC_CACHE_CHECK([for nl_langinfo(CODESET)], xmms_cv_func_langinfo, [
AC_TRY_COMPILE([#include <langinfo.h>],
        [char *codeset = nl_langinfo (CODESET);],
   xmms_cv_func_langinfo=yes,
   xmms_cv_func_langinfo=no)])
if test "x$xmms_cv_func_langinfo" = "xyes"; then
  AC_DEFINE(HAVE_CODESET,,[Define if nl_langinfo(CODESET) is available.])
fi

if test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes"
then
    case "$host" in 
	*-sun-* | *-*-linux*)
	    AC_DEFINE(XMMS_CDROM_SOLARIS,, [Define if cdrom access is in Solaris style])
	;;
	*-*-freebsd*)
	    AC_DEFINE(XMMS_CDROM_BSD,, [Define if cdrom access is in BSD style])
	;;
	*-*-netbsd* | *-*-openbsd*)
	    AC_DEFINE(XMMS_CDROM_BSD,, [Define if cdrom access is in BSD style])
	    AC_DEFINE(XMMS_CDROM_BSD_NETBSD,, [Define if cdrom access uses NetBSD variant])
	;;
	*-*darwin*)
	    AC_DEFINE(XMMS_CDROM_BSD,, [Define if cdrom access is in BSD style])
	    AC_DEFINE(XMMS_CDROM_BSD_DARWIN,, [Define if cdrom access uses Darwin variant])
	;;
    esac
fi


AM_CONDITIONAL(HAVE_OSS,test "${ac_cv_header_sys_soundcard_h}" = "yes" || test "${ac_cv_header_machine_soundcard_h}" = "yes")
AM_CONDITIONAL(HAVE_CDROM, test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes")
AM_CONDITIONAL(HAVE_LINUX_JOYSTICK,test "${ac_cv_header_linux_joystick_h}" = "yes")

AC_CHECK_SIZEOF(long)

if test -n "$GCC"
then
  CFLAGS="$CFLAGS -Wall -Wpointer-arith -finline-functions -ffast-math"
  case "$CFLAGS" in
    -g*) ;;
    *\ -g*) ;;
    *) CFLAGS="$CFLAGS -fomit-frame-pointer" ;;
  esac
  case "$host" in
    *-*-freebsd*)
	;;
    *)
	CFLAGS="$CFLAGS -funroll-all-loops"
	;;
  esac
fi

arch_type=other
have_solaris=no
ARCH_DEFINES=""
case "$host" in 
	*-*-openbsd* | *-*-netbsd* | *-*darwin*)
		AC_DEFINE(SYMBOL_PREFIX, "_", [Define to symbol prefix, if any])
	;;
	i386-*-* | i486-*-* | i586-*-* | i686-*-* | i86pc-*-*)
		ARCH_DEFINES="-DI386_ASSEM"
		arch_type=ix86
	;;
	ppc-*-*)
		arch_type=ppc
	;;
	*-hpux-*)
		ARCH_DEFINES="-DHPUX"
	;;
	*-sun-*)
		have_solaris=yes
	;;
esac

AC_SUBST(ARCH_DEFINES)
AM_CONDITIONAL(ARCH_X86, test "x$arch_type" = "xix86")
AM_CONDITIONAL(ARCH_PPC, test "x$arch_type" = "xppc")
AM_CONDITIONAL(HAVE_SOLARIS, test "x$have_solaris" = xyes)

plugindir=$libdir/xmms
AC_SUBST(plugindir)

if test "x$enable_one_plugin_dir" = "xyes"; then
  pluginsubs="\\\"Plugins\\\""
  INPUT_PLUGIN_DIR=Plugins
  OUTPUT_PLUGIN_DIR=Plugins
  EFFECT_PLUGIN_DIR=Plugins
  GENERAL_PLUGIN_DIR=Plugins
  VISUALIZATION_PLUGIN_DIR=Plugins
else
  pluginsubs="\\\"Output\\\",\\\"Input\\\",\\\"Effect\\\",\\\"General\\\",\\\"Visualization\\\""
  INPUT_PLUGIN_DIR=Input
  OUTPUT_PLUGIN_DIR=Output
  EFFECT_PLUGIN_DIR=Effect
  GENERAL_PLUGIN_DIR=General
  VISUALIZATION_PLUGIN_DIR=Visualization
fi

AC_SUBST(INPUT_PLUGIN_DIR)
AC_SUBST(OUTPUT_PLUGIN_DIR)
AC_SUBST(EFFECT_PLUGIN_DIR)
AC_SUBST(GENERAL_PLUGIN_DIR)
AC_SUBST(VISUALIZATION_PLUGIN_DIR)
AC_SUBST(pluginsubs)

XMMS_DEFINES="$CFLAGS -DDATA_DIR=\\\"$datadir/xmms\\\" -DPLUGIN_DIR=\\\"$plugindir\\\" -DPLUGINSUBS=$pluginsubs -DLOCALEDIR=\\\"$localedir\\\""

if test "x$enable_user_plugin_dir" = "xno"; then
	AC_DEFINE(DISABLE_USER_PLUGIN_DIR,,�[Define to disable per user plugin directory])
fi

AC_SUBST(XMMS_DEFINES)

PLUGIN_LDFLAGS='-module -avoid-version -export-symbols-regex "get_.plugin_info"'
AC_SUBST(PLUGIN_LDFLAGS)

AC_CONFIG_SUBDIRS(libxmms)

AC_SUBST(xmmsdir)
AC_SUBST(plugindir)

AC_OUTPUT([
Makefile
xmms.1
wmxmms.1
gnomexmms.1
xmms.spec
xmms-config
xmms/Makefile
xmms/defskin/Makefile
Output/Makefile
Output/OSS/Makefile
Output/esd/Makefile
Output/disk_writer/Makefile
Output/solaris/Makefile
Input/Makefile
Input/wav/Makefile
Input/mpg123/Makefile
Input/mikmod/Makefile
Input/cdaudio/Makefile
Input/idcin/Makefile
Input/tonegen/Makefile
Input/vorbis/Makefile
Effect/Makefile
Effect/voice/Makefile
Effect/echo_plugin/Makefile
Effect/stereo_plugin/Makefile
General/Makefile
General/ir/Makefile
General/joystick/Makefile
General/song_change/Makefile
Visualization/Makefile
Visualization/blur_scope/Makefile
Visualization/sanalyzer/Makefile
Visualization/opengl_spectrum/Makefile
wmxmms/Makefile
gnomexmms/Makefile
po/Makefile.in
intl/Makefile],
[chmod +x xmms-config])

echo ""
echo "Configuration:"
echo "  Install path:               ${prefix}"
if test "$XMMS_PATH" != "no"; then
echo "  Current xmms                $XMMS_PATH"
fi

echo "  Build esd plugin:           $have_esd"
echo "  Build mikmod plugin:        $have_mikmod"
echo "  Build Ogg Vorbis plugin:    $have_oggvorbis"
echo "  Build Solaris plugin:       $have_solaris"
echo "  Build gnomexmms:            $have_gnome"
echo "  Build OpenGL plugins:       $have_opengl"
echo "  Pthread flag:               $PTHREAD_LIBS"
echo "  Use one plugin dir:         $enable_one_plugin_dir"
echo "  Allow user plugin dir:      $enable_user_plugin_dir"
echo ""

echo ""
if test "$xmms_cv_lib_xlibs_threadsafe" = "no"; then
  echo "Note: You need to have thread-safe xlibs to use xmms."
  echo "If you are using libc5 thread aware Xlibs just skip this." 
  echo ""
  echo "If you don't have those libs and you are on a libc5 system get them at:"
  echo "ftp://ftp.dent.med.uni-muenchen.de/pub/wmglo/"
fi

if test "$XMMS_PATH" != "no" && test "$prefix/bin/xmms" != "$XMMS_PATH" ; then
  echo ""
  echo "Note: Configure has discovered that you already have xmms installed"
  echo "and it do not match with the given --prefix. You have xmms installed "
  echo "in $XMMS_PATH and you chose $prefix/bin/xmms."
  echo "If you don't want two copies of XMMS installed, rerun configure with"
  echo "the --prefix option set to the location of the old xmms, or uninstall"
  echo "the old xmms."
fi
