<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package HTML::PullParser;

use strict;

require HTML::Parser;
our @ISA = qw(HTML::Parser);
our $VERSION = '3.83';

use Carp ();

sub new
{
    my($class, %cnf) = @_;

    # Construct argspecs for the various events
    my %argspec;
    for (qw(start end text declaration comment process default)) {
	my $tmp = delete $cnf{$_};
	next unless defined $tmp;
	$argspec{$_} = $tmp;
    }
    Carp::croak("Info not collected for any events")
	  unless %argspec;

    my $file = delete $cnf{file};
    my $doc  = delete $cnf{doc};
    Carp::croak("Can't parse from both 'doc' and 'file' at the same time")
	  if defined($file) &amp;&amp; defined($doc);
    Carp::croak("No 'doc' or 'file' given to parse from")
	  unless defined($file) || defined($doc);

    # Create object
    $cnf{api_version} = 3;
    my $self = $class-&gt;SUPER::new(%cnf);

    my $accum = $self-&gt;{pullparser_accum} = [];
    while (my($event, $argspec) = each %argspec) {
	$self-&gt;SUPER::handler($event =&gt; $accum, $argspec);
    }

    if (defined $doc) {
	$self-&gt;{pullparser_str_ref} = ref($doc) ? $doc : \$doc;
	$self-&gt;{pullparser_str_pos} = 0;
    }
    else {
	if (!ref($file) &amp;&amp; ref(\$file) ne "GLOB") {
	    require IO::File;
	    $file = IO::File-&gt;new($file, "r") || return;
	}

	$self-&gt;{pullparser_file} = $file;
    }
    $self;
}


sub handler
{
    Carp::croak("Can't set handlers for HTML::PullParser");
}


sub get_token
{
    my $self = shift;
    while (!@{$self-&gt;{pullparser_accum}} &amp;&amp; !$self-&gt;{pullparser_eof}) {
	if (my $f = $self-&gt;{pullparser_file}) {
	    # must try to parse more from the file
	    my $buf;
	    if (read($f, $buf, 512)) {
		$self-&gt;parse($buf);
	    } else {
		$self-&gt;eof;
		$self-&gt;{pullparser_eof}++;
		delete $self-&gt;{pullparser_file};
	    }
	}
	elsif (my $sref = $self-&gt;{pullparser_str_ref}) {
	    # must try to parse more from the scalar
	    my $pos = $self-&gt;{pullparser_str_pos};
	    my $chunk = substr($$sref, $pos, 512);
	    $self-&gt;parse($chunk);
	    $pos += length($chunk);
	    if ($pos &lt; length($$sref)) {
		$self-&gt;{pullparser_str_pos} = $pos;
	    }
	    else {
		$self-&gt;eof;
		$self-&gt;{pullparser_eof}++;
		delete $self-&gt;{pullparser_str_ref};
		delete $self-&gt;{pullparser_str_pos};
	    }
	}
	else {
	    die;
	}
    }
    shift @{$self-&gt;{pullparser_accum}};
}


sub unget_token
{
    my $self = shift;
    unshift @{$self-&gt;{pullparser_accum}}, @_;
    $self;
}

1;


__END__

=head1 NAME

HTML::PullParser - Alternative HTML::Parser interface

=head1 SYNOPSIS

 use HTML::PullParser;

 $p = HTML::PullParser-&gt;new(file =&gt; "index.html",
                            start =&gt; 'event, tagname, @attr',
                            end   =&gt; 'event, tagname',
                            ignore_elements =&gt; [qw(script style)],
                           ) || die "Can't open: $!";
 while (my $token = $p-&gt;get_token) {
     #...do something with $token
 }

=head1 DESCRIPTION

The HTML::PullParser is an alternative interface to the HTML::Parser class.
It basically turns the HTML::Parser inside out.  You associate a file
(or any IO::Handle object or string) with the parser at construction time and
then repeatedly call $parser-&gt;get_token to obtain the tags and text
found in the parsed document.

The following methods are provided:

=over 4

=item $p = HTML::PullParser-&gt;new( file =&gt; $file, %options )

=item $p = HTML::PullParser-&gt;new( doc =&gt; \$doc, %options )

A C&lt;HTML::PullParser&gt; can be made to parse from either a file or a
literal document based on whether the C&lt;file&gt; or C&lt;doc&gt; option is
passed to the parser's constructor.

The C&lt;file&gt; passed in can either be a file name or a file handle
object.  If a file name is passed, and it can't be opened for reading,
then the constructor will return an undefined value and $!  will tell
you why it failed.  Otherwise the argument is taken to be some object
that the C&lt;HTML::PullParser&gt; can read() from when it needs more data.
The stream will be read() until EOF, but not closed.

A C&lt;doc&gt; can be passed plain or as a reference
to a scalar.  If a reference is passed then the value of this scalar
should not be changed before all tokens have been extracted.

Next the information to be returned for the different token types must
be set up.  This is done by simply associating an argspec (as defined
in L&lt;HTML::Parser&gt;) with the events you have an interest in.  For
instance, if you want C&lt;start&gt; tokens to be reported as the string
C&lt;'S'&gt; followed by the tagname and the attributes you might pass an
C&lt;start&gt;-option like this:

   $p = HTML::PullParser-&gt;new(
          doc   =&gt; $document_to_parse,
          start =&gt; '"S", tagname, @attr',
          end   =&gt; '"E", tagname',
        );

At last other C&lt;HTML::Parser&gt; options, like C&lt;ignore_tags&gt;, and
C&lt;unbroken_text&gt;, can be passed in.  Note that you should not use the
I&lt;event&gt;_h options to set up parser handlers.  That would confuse the
inner logic of C&lt;HTML::PullParser&gt;.

=item $token = $p-&gt;get_token

This method will return the next I&lt;token&gt; found in the HTML document,
or C&lt;undef&gt; at the end of the document.  The token is returned as an
array reference.  The content of this array match the argspec set up
during C&lt;HTML::PullParser&gt; construction.

=item $p-&gt;unget_token( @tokens )

If you find out you have read too many tokens you can push them back,
so that they are returned again the next time $p-&gt;get_token is called.

=back

=head1 EXAMPLES

The 'eg/hform' script shows how we might parse the form section of
HTML::Documents using HTML::PullParser.

=head1 SEE ALSO

L&lt;HTML::Parser&gt;, L&lt;HTML::TokeParser&gt;

=head1 COPYRIGHT

Copyright 1998-2001 Gisle Aas.

This library is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=cut
</pre></body></html>