<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package bytes 1.09;

use v5.38;

BEGIN { $bytes::hint_bits = 0x0000_0008 }

sub   import { $^H |=  $bytes::hint_bits }
sub unimport { $^H &amp;= ~$bytes::hint_bits }

sub chr    :prototype(_)     { BEGIN { import() } &amp;CORE::chr    }
sub index  :prototype($$;$)  { BEGIN { import() } &amp;CORE::index  }
sub length :prototype(_)     { BEGIN { import() } &amp;CORE::length }
sub ord    :prototype(_)     { BEGIN { import() } &amp;CORE::ord    }
sub rindex :prototype($$;$)  { BEGIN { import() } &amp;CORE::rindex }
sub substr :prototype($$;$$) { BEGIN { import() } &amp;CORE::substr }

__END__

=head1 NAME

bytes - Perl pragma to expose the individual bytes of characters

=head1 NOTICE

Because the bytes pragma breaks encapsulation (i.e. it exposes the innards of
how the perl executable currently happens to store a string), the byte values
that result are in an unspecified encoding.

B&lt;Use of this module for anything other than debugging purposes is
strongly discouraged.&gt;  If you feel that the functions here within
might be useful for your application, this possibly indicates a
mismatch between your mental model of Perl Unicode and the current
reality. In that case, you may wish to read some of the perl Unicode
documentation: L&lt;perluniintro&gt;, L&lt;perlunitut&gt;, L&lt;perlunifaq&gt; and
L&lt;perlunicode&gt;.

=head1 SYNOPSIS

    use bytes;
    ... chr(...);       # or bytes::chr
    ... index(...);     # or bytes::index
    ... length(...);    # or bytes::length
    ... ord(...);       # or bytes::ord
    ... rindex(...);    # or bytes::rindex
    ... substr(...);    # or bytes::substr
    no bytes;


=head1 DESCRIPTION

Perl's characters are stored internally as sequences of one or more bytes.
This pragma allows for the examination of the individual bytes that together
comprise a character.

Originally the pragma was designed for the loftier goal of helping incorporate
Unicode into Perl, but the approach that used it was found to be defective,
and the one remaining legitimate use is for debugging when you need to
non-destructively examine characters' individual bytes.  Just insert this
pragma temporarily, and remove it after the debugging is finished.

The original usage can be accomplished by explicit (rather than this pragma's
implicit) encoding using the L&lt;Encode&gt; module:

    use Encode qw/encode/;

    my $utf8_byte_string   = encode "UTF8",   $string;
    my $latin1_byte_string = encode "Latin1", $string;

Or, if performance is needed and you are only interested in the UTF-8
representation:

    utf8::encode(my $utf8_byte_string = $string);

C&lt;no bytes&gt; can be used to reverse the effect of C&lt;use bytes&gt; within the
current lexical scope.

As an example, when Perl sees C&lt;$x = chr(400)&gt;, it encodes the character
in UTF-8 and stores it in C&lt;$x&gt;. Then it is marked as character data, so,
for instance, C&lt;length $x&gt; returns C&lt;1&gt;. However, in the scope of the
C&lt;bytes&gt; pragma, C&lt;$x&gt; is treated as a series of bytes - the bytes that make
up the UTF8 encoding - and C&lt;length $x&gt; returns C&lt;2&gt;:

 $x = chr(400);
 print "Length is ", length $x, "\n";     # "Length is 1"
 printf "Contents are %vd\n", $x;         # "Contents are 400"
 {
     use bytes; # or "require bytes; bytes::length()"
     print "Length is ", length $x, "\n"; # "Length is 2"
     printf "Contents are %vd\n", $x;     # "Contents are 198.144 (on
                                          # ASCII platforms)"
 }

C&lt;chr()&gt;, C&lt;ord()&gt;, C&lt;substr()&gt;, C&lt;index()&gt; and C&lt;rindex()&gt; behave similarly.

For more on the implications, see L&lt;perluniintro&gt; and L&lt;perlunicode&gt;.

C&lt;bytes::length()&gt; is admittedly handy if you need to know the
B&lt;byte length&gt; of a Perl scalar.  But a more modern way is:

   use Encode 'encode';
   length(encode('UTF-8', $scalar))

=head1 LIMITATIONS

C&lt;bytes::substr()&gt; does not work as an I&lt;lvalue()&gt;.

=head1 SEE ALSO

L&lt;perluniintro&gt;, L&lt;perlunicode&gt;, L&lt;utf8&gt;, L&lt;Encode&gt;
</pre></body></html>