<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package TAP::Parser::SourceHandler::RawTAP;

use strict;
use warnings;

use TAP::Parser::IteratorFactory ();
use TAP::Parser::Iterator::Array ();

use base 'TAP::Parser::SourceHandler';

TAP::Parser::IteratorFactory-&gt;register_handler(__PACKAGE__);

=head1 NAME

TAP::Parser::SourceHandler::RawTAP - Stream output from raw TAP in a scalar/array ref.

=head1 VERSION

Version 3.48

=cut

our $VERSION = '3.48';

=head1 SYNOPSIS

  use TAP::Parser::Source;
  use TAP::Parser::SourceHandler::RawTAP;

  my $source = TAP::Parser::Source-&gt;new-&gt;raw( \"1..1\nok 1\n" );
  $source-&gt;assemble_meta;

  my $class = 'TAP::Parser::SourceHandler::RawTAP';
  my $vote  = $class-&gt;can_handle( $source );
  my $iter  = $class-&gt;make_iterator( $source );

=head1 DESCRIPTION

This is a I&lt;raw TAP output&gt; L&lt;TAP::Parser::SourceHandler&gt; - it has 2 jobs:

1. Figure out if the L&lt;TAP::Parser::Source&gt; it's given is raw TAP output
(L&lt;/can_handle&gt;).

2. Creates an iterator for raw TAP output (L&lt;/make_iterator&gt;).

Unless you're writing a plugin or subclassing L&lt;TAP::Parser&gt;, you probably
won't need to use this module directly.

=head1 METHODS

=head2 Class Methods

=head3 C&lt;can_handle&gt;

  my $vote = $class-&gt;can_handle( $source );

Only votes if $source is an array, or a scalar with newlines.  Casts the
following votes:

  0.9  if it's a scalar with '..' in it
  0.7  if it's a scalar with 'ok' in it
  0.3  if it's just a scalar with newlines
  0.5  if it's an array

=cut

sub can_handle {
    my ( $class, $src ) = @_;
    my $meta = $src-&gt;meta;

    return 0 if $meta-&gt;{file};
    if ( $meta-&gt;{is_scalar} ) {
        return 0 unless $meta-&gt;{has_newlines};
        return 0.9 if ${ $src-&gt;raw } =~ /\d\.\.\d/;
        return 0.7 if ${ $src-&gt;raw } =~ /ok/;
        return 0.3;
    }
    elsif ( $meta-&gt;{is_array} ) {
        return 0.5;
    }
    return 0;
}

=head3 C&lt;make_iterator&gt;

  my $iterator = $class-&gt;make_iterator( $source );

Returns a new L&lt;TAP::Parser::Iterator::Array&gt; for the source.
C&lt;$source-E&lt;gt&gt;raw&gt; must be an array ref, or a scalar ref.

C&lt;croak&gt;s on error.

=cut

sub make_iterator {
    my ( $class, $src ) = @_;
    my $meta = $src-&gt;meta;

    my $tap_array;
    if ( $meta-&gt;{is_scalar} ) {
        $tap_array = [ split "\n" =&gt; ${ $src-&gt;raw } ];
    }
    elsif ( $meta-&gt;{is_array} ) {
        $tap_array = $src-&gt;raw;
    }

    $class-&gt;_croak('No raw TAP found in $source-&gt;raw')
      unless scalar $tap_array;

    return TAP::Parser::Iterator::Array-&gt;new($tap_array);
}

1;

=head1 SUBCLASSING

Please see L&lt;TAP::Parser/SUBCLASSING&gt; for a subclassing overview.

=head1 SEE ALSO

L&lt;TAP::Object&gt;,
L&lt;TAP::Parser&gt;,
L&lt;TAP::Parser::IteratorFactory&gt;,
L&lt;TAP::Parser::SourceHandler&gt;,
L&lt;TAP::Parser::SourceHandler::Executable&gt;,
L&lt;TAP::Parser::SourceHandler::Perl&gt;,
L&lt;TAP::Parser::SourceHandler::File&gt;,
L&lt;TAP::Parser::SourceHandler::Handle&gt;

=cut
</pre></body></html>