<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">use 5.008001;
use strict;
use warnings;
package Parse::CPAN::Meta;
# ABSTRACT: Parse META.yml and META.json CPAN metadata files

our $VERSION = '2.150010';

use Exporter;
use Carp 'croak';

our @ISA = qw/Exporter/;
our @EXPORT_OK = qw/Load LoadFile/;

sub load_file {
  my ($class, $filename) = @_;

  my $meta = _slurp($filename);

  if ($filename =~ /\.ya?ml$/) {
    return $class-&gt;load_yaml_string($meta);
  }
  elsif ($filename =~ /\.json$/) {
    return $class-&gt;load_json_string($meta);
  }
  else {
    $class-&gt;load_string($meta); # try to detect yaml/json
  }
}

sub load_string {
  my ($class, $string) = @_;
  if ( $string =~ /^---/ ) { # looks like YAML
    return $class-&gt;load_yaml_string($string);
  }
  elsif ( $string =~ /^\s*\{/ ) { # looks like JSON
    return $class-&gt;load_json_string($string);
  }
  else { # maybe doc-marker-free YAML
    return $class-&gt;load_yaml_string($string);
  }
}

sub load_yaml_string {
  my ($class, $string) = @_;
  my $backend = $class-&gt;yaml_backend();
  my $data = eval { no strict 'refs'; &amp;{"$backend\::Load"}($string) };
  croak $@ if $@;
  return $data || {}; # in case document was valid but empty
}

sub load_json_string {
  my ($class, $string) = @_;
  require Encode;
  # load_json_string takes characters, decode_json expects bytes
  my $encoded = Encode::encode('UTF-8', $string, Encode::PERLQQ());
  my $data = eval { $class-&gt;json_decoder()-&gt;can('decode_json')-&gt;($encoded) };
  croak $@ if $@;
  return $data || {};
}

sub yaml_backend {
  if ($ENV{PERL_CORE} or not defined $ENV{PERL_YAML_BACKEND} ) {
    _can_load( 'CPAN::Meta::YAML', 0.011 )
      or croak "CPAN::Meta::YAML 0.011 is not available\n";
    return "CPAN::Meta::YAML";
  }
  else {
    my $backend = $ENV{PERL_YAML_BACKEND};
    _can_load( $backend )
      or croak "Could not load PERL_YAML_BACKEND '$backend'\n";
    $backend-&gt;can("Load")
      or croak "PERL_YAML_BACKEND '$backend' does not implement Load()\n";
    return $backend;
  }
}

sub json_decoder {
  if ($ENV{PERL_CORE}) {
    _can_load( 'JSON::PP' =&gt; 2.27300 )
      or croak "JSON::PP 2.27300 is not available\n";
    return 'JSON::PP';
  }
  if (my $decoder = $ENV{CPAN_META_JSON_DECODER}) {
    _can_load( $decoder )
      or croak "Could not load CPAN_META_JSON_DECODER '$decoder'\n";
    $decoder-&gt;can('decode_json')
      or croak "No decode_json sub provided by CPAN_META_JSON_DECODER '$decoder'\n";
    return $decoder;
  }
  return $_[0]-&gt;json_backend;
}

sub json_backend {
  if ($ENV{PERL_CORE}) {
    _can_load( 'JSON::PP' =&gt; 2.27300 )
      or croak "JSON::PP 2.27300 is not available\n";
    return 'JSON::PP';
  }
  if (my $backend = $ENV{CPAN_META_JSON_BACKEND}) {
    _can_load( $backend )
      or croak "Could not load CPAN_META_JSON_BACKEND '$backend'\n";
    $backend-&gt;can('new')
      or croak "No constructor provided by CPAN_META_JSON_BACKEND '$backend'\n";
    return $backend;
  }
  if (! $ENV{PERL_JSON_BACKEND} or $ENV{PERL_JSON_BACKEND} eq 'JSON::PP') {
    _can_load( 'JSON::PP' =&gt; 2.27300 )
      or croak "JSON::PP 2.27300 is not available\n";
    return 'JSON::PP';
  }
  else {
    _can_load( 'JSON' =&gt; 2.5 )
      or croak  "JSON 2.5 is required for " .
                "\$ENV{PERL_JSON_BACKEND} = '$ENV{PERL_JSON_BACKEND}'\n";
    return "JSON";
  }
}

sub _slurp {
  require Encode;
  open my $fh, "&lt;:raw", "$_[0]" ## no critic
    or die "can't open $_[0] for reading: $!";
  my $content = do { local $/; &lt;$fh&gt; };
  $content = Encode::decode('UTF-8', $content, Encode::PERLQQ());
  return $content;
}

sub _can_load {
  my ($module, $version) = @_;
  (my $file = $module) =~ s{::}{/}g;
  $file .= ".pm";
  return 1 if $INC{$file};
  return 0 if exists $INC{$file}; # prior load failed
  eval { require $file; 1 }
    or return 0;
  if ( defined $version ) {
    eval { $module-&gt;VERSION($version); 1 }
      or return 0;
  }
  return 1;
}

# Kept for backwards compatibility only
# Create an object from a file
sub LoadFile ($) { ## no critic
  return Load(_slurp(shift));
}

# Parse a document from a string.
sub Load ($) { ## no critic
  require CPAN::Meta::YAML;
  my $object = eval { CPAN::Meta::YAML::Load(shift) };
  croak $@ if $@;
  return $object;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Parse::CPAN::Meta - Parse META.yml and META.json CPAN metadata files

=head1 VERSION

version 2.150010

=head1 SYNOPSIS

    #############################################
    # In your file

    ---
    name: My-Distribution
    version: 1.23
    resources:
      homepage: "http://example.com/dist/My-Distribution"


    #############################################
    # In your program

    use Parse::CPAN::Meta;

    my $distmeta = Parse::CPAN::Meta-&gt;load_file('META.yml');

    # Reading properties
    my $name     = $distmeta-&gt;{name};
    my $version  = $distmeta-&gt;{version};
    my $homepage = $distmeta-&gt;{resources}{homepage};

=head1 DESCRIPTION

B&lt;Parse::CPAN::Meta&gt; is a parser for F&lt;META.json&gt; and F&lt;META.yml&gt; files, using
L&lt;JSON::PP&gt; and/or L&lt;CPAN::Meta::YAML&gt;.

B&lt;Parse::CPAN::Meta&gt; provides three methods: C&lt;load_file&gt;, C&lt;load_json_string&gt;,
and C&lt;load_yaml_string&gt;.  These will read and deserialize CPAN metafiles, and
are described below in detail.

B&lt;Parse::CPAN::Meta&gt; provides a legacy API of only two functions,
based on the YAML functions of the same name. Wherever possible,
identical calling semantics are used.  These may only be used with YAML sources.

All error reporting is done with exceptions (die'ing).

Note that META files are expected to be in UTF-8 encoding, only.  When
converted string data, it must first be decoded from UTF-8.

=begin Pod::Coverage




=end Pod::Coverage

=head1 METHODS

=head2 load_file

  my $metadata_structure = Parse::CPAN::Meta-&gt;load_file('META.json');

  my $metadata_structure = Parse::CPAN::Meta-&gt;load_file('META.yml');

This method will read the named file and deserialize it to a data structure,
determining whether it should be JSON or YAML based on the filename.
The file will be read using the ":utf8" IO layer.

=head2 load_yaml_string

  my $metadata_structure = Parse::CPAN::Meta-&gt;load_yaml_string($yaml_string);

This method deserializes the given string of YAML and returns the first
document in it.  (CPAN metadata files should always have only one document.)
If the source was UTF-8 encoded, the string must be decoded before calling
C&lt;load_yaml_string&gt;.

=head2 load_json_string

  my $metadata_structure = Parse::CPAN::Meta-&gt;load_json_string($json_string);

This method deserializes the given string of JSON and the result.
If the source was UTF-8 encoded, the string must be decoded before calling
C&lt;load_json_string&gt;.

=head2 load_string

  my $metadata_structure = Parse::CPAN::Meta-&gt;load_string($some_string);

If you don't know whether a string contains YAML or JSON data, this method
will use some heuristics and guess.  If it can't tell, it assumes YAML.

=head2 yaml_backend

  my $backend = Parse::CPAN::Meta-&gt;yaml_backend;

Returns the module name of the YAML serializer. See L&lt;/ENVIRONMENT&gt;
for details.

=head2 json_backend

  my $backend = Parse::CPAN::Meta-&gt;json_backend;

Returns the module name of the JSON serializer.  If C&lt;CPAN_META_JSON_BACKEND&gt;
is set, this will be whatever that's set to.  If not, this will either
be L&lt;JSON::PP&gt; or L&lt;JSON&gt;.  If C&lt;PERL_JSON_BACKEND&gt; is set,
this will return L&lt;JSON&gt; as further delegation is handled by
the L&lt;JSON&gt; module.  See L&lt;/ENVIRONMENT&gt; for details.

=head2 json_decoder

  my $decoder = Parse::CPAN::Meta-&gt;json_decoder;

Returns the module name of the JSON decoder.  Unlike L&lt;/json_backend&gt;, this
is not necessarily a full L&lt;JSON&gt;-style module, but only something that will
provide a C&lt;decode_json&gt; subroutine.  If C&lt;CPAN_META_JSON_DECODER&gt; is set,
this will be whatever that's set to.  If not, this will be whatever has
been selected as L&lt;/json_backend&gt;.  See L&lt;/ENVIRONMENT&gt; for more notes.

=head1 FUNCTIONS

For maintenance clarity, no functions are exported by default.  These functions
are available for backwards compatibility only and are best avoided in favor of
C&lt;load_file&gt;.

=head2 Load

  my @yaml = Parse::CPAN::Meta::Load( $string );

Parses a string containing a valid YAML stream into a list of Perl data
structures.

=head2 LoadFile

  my @yaml = Parse::CPAN::Meta::LoadFile( 'META.yml' );

Reads the YAML stream from a file instead of a string.

=head1 ENVIRONMENT

=head2 CPAN_META_JSON_DECODER

By default, L&lt;JSON::PP&gt; will be used for deserializing JSON data.  If the
C&lt;CPAN_META_JSON_DECODER&gt; environment variable exists, this is expected to
be the name of a loadable module that provides a C&lt;decode_json&gt; subroutine,
which will then be used for deserialization.  Relying only on the existence
of said subroutine allows for maximum compatibility, since this API is
provided by all of L&lt;JSON::PP&gt;, L&lt;JSON::XS&gt;, L&lt;Cpanel::JSON::XS&gt;,
L&lt;JSON::MaybeXS&gt;, L&lt;JSON::Tiny&gt;, and L&lt;Mojo::JSON&gt;.

=head2 CPAN_META_JSON_BACKEND

By default, L&lt;JSON::PP&gt; will be used for deserializing JSON data.  If the
C&lt;CPAN_META_JSON_BACKEND&gt; environment variable exists, this is expected to
be the name of a loadable module that provides the L&lt;JSON&gt; API, since
downstream code expects to be able to call C&lt;new&gt; on this class.  As such,
while L&lt;JSON::PP&gt;, L&lt;JSON::XS&gt;, L&lt;Cpanel::JSON::XS&gt; and L&lt;JSON::MaybeXS&gt; will
work for this, to use L&lt;Mojo::JSON&gt; or L&lt;JSON::Tiny&gt; for decoding requires
setting L&lt;/CPAN_META_JSON_DECODER&gt;.

=head2 PERL_JSON_BACKEND

If the C&lt;CPAN_META_JSON_BACKEND&gt; environment variable does not exist, and if
C&lt;PERL_JSON_BACKEND&gt; environment variable exists, is true and is not
"JSON::PP", then the L&lt;JSON&gt; module (version 2.5 or greater) will be loaded and
used to interpret C&lt;PERL_JSON_BACKEND&gt;.  If L&lt;JSON&gt; is not installed or is too
old, an exception will be thrown.  Note that at the time of writing, the only
useful values are 1, which will tell L&lt;JSON&gt; to guess, or L&lt;JSON::XS&gt; - if
you want to use a newer JSON module, see L&lt;/CPAN_META_JSON_BACKEND&gt;.

=head2 PERL_YAML_BACKEND

By default, L&lt;CPAN::Meta::YAML&gt; will be used for deserializing YAML data. If
the C&lt;PERL_YAML_BACKEND&gt; environment variable is defined, then it is interpreted
as a module to use for deserialization.  The given module must be installed,
must load correctly and must implement the C&lt;Load()&gt; function or an exception
will be thrown.

=head1 AUTHORS

=over 4

=item *

David Golden &lt;dagolden@cpan.org&gt;

=item *

Ricardo Signes &lt;rjbs@cpan.org&gt;

=item *

Adam Kennedy &lt;adamk@cpan.org&gt;

=back

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2010 by David Golden, Ricardo Signes, Adam Kennedy and Contributors.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</pre></body></html>