<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Math::BigFloat;

#
# Mike grinned. 'Two down, infinity to go' - Mike Nostrus in 'Before and After'
#

# The following hash values are used internally:
#
#          sign : "+", "-", "+inf", "-inf", or "NaN"
#            _m : absolute value of mantissa ($LIB thingy)
#           _es : sign of exponent ("+" or "-")
#            _e : absolute value of exponent ($LIB thingy)
#      accuracy : accuracy (scalar)
#     precision : precision (scalar)

use 5.006001;
use strict;
use warnings;

use Carp          qw&lt; carp croak &gt;;
use Scalar::Util  qw&lt; blessed &gt;;
use Math::BigInt  qw&lt; &gt;;

our $VERSION = '2.003002';
$VERSION =~ tr/_//d;

require Exporter;
our @ISA        = qw/Math::BigInt/;
our @EXPORT_OK  = qw/bpi/;

# $_trap_inf/$_trap_nan are internal and should never be accessed from outside
our ($AUTOLOAD, $accuracy, $precision, $div_scale, $round_mode, $rnd_mode,
     $upgrade, $downgrade, $_trap_nan, $_trap_inf);

use overload

  # overload key: with_assign

  '+'     =&gt;      sub { $_[0] -&gt; copy() -&gt; badd($_[1]); },

  '-'     =&gt;      sub { my $c = $_[0] -&gt; copy();
                        $_[2] ? $c -&gt; bneg() -&gt; badd($_[1])
                              : $c -&gt; bsub($_[1]); },

  '*'     =&gt;      sub { $_[0] -&gt; copy() -&gt; bmul($_[1]); },

  '/'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bdiv($_[0])
                              : $_[0] -&gt; copy() -&gt; bdiv($_[1]); },

  '%'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bmod($_[0])
                              : $_[0] -&gt; copy() -&gt; bmod($_[1]); },

  '**'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bpow($_[0])
                              : $_[0] -&gt; copy() -&gt; bpow($_[1]); },

  '&lt;&lt;'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bblsft($_[0])
                              : $_[0] -&gt; copy() -&gt; bblsft($_[1]); },

  '&gt;&gt;'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bbrsft($_[0])
                              : $_[0] -&gt; copy() -&gt; bbrsft($_[1]); },

  # overload key: assign

  '+='    =&gt;      sub { $_[0] -&gt; badd($_[1]); },

  '-='    =&gt;      sub { $_[0] -&gt; bsub($_[1]); },

  '*='    =&gt;      sub { $_[0] -&gt; bmul($_[1]); },

  '/='    =&gt;      sub { scalar $_[0] -&gt; bdiv($_[1]); },

  '%='    =&gt;      sub { $_[0] -&gt; bmod($_[1]); },

  '**='   =&gt;      sub { $_[0] -&gt; bpow($_[1]); },

  '&lt;&lt;='   =&gt;      sub { $_[0] -&gt; bblsft($_[1]); },

  '&gt;&gt;='   =&gt;      sub { $_[0] -&gt; bbrsft($_[1]); },

#  'x='    =&gt;      sub { },

#  '.='    =&gt;      sub { },

  # overload key: num_comparison

  '&lt;'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; blt($_[0])
                              : $_[0] -&gt; blt($_[1]); },

  '&lt;='    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; ble($_[0])
                              : $_[0] -&gt; ble($_[1]); },

  '&gt;'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bgt($_[0])
                              : $_[0] -&gt; bgt($_[1]); },

  '&gt;='    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bge($_[0])
                              : $_[0] -&gt; bge($_[1]); },

  '=='    =&gt;      sub { $_[0] -&gt; beq($_[1]); },

  '!='    =&gt;      sub { $_[0] -&gt; bne($_[1]); },

  # overload key: 3way_comparison

  '&lt;=&gt;'   =&gt;      sub { my $cmp = $_[0] -&gt; bcmp($_[1]);
                        defined($cmp) &amp;&amp; $_[2] ? -$cmp : $cmp; },

  'cmp'   =&gt;      sub { $_[2] ? "$_[1]" cmp $_[0] -&gt; bstr()
                              : $_[0] -&gt; bstr() cmp "$_[1]"; },

  # overload key: str_comparison

#  'lt'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrlt($_[0])
#                              : $_[0] -&gt; bstrlt($_[1]); },
#
#  'le'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrle($_[0])
#                              : $_[0] -&gt; bstrle($_[1]); },
#
#  'gt'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrgt($_[0])
#                              : $_[0] -&gt; bstrgt($_[1]); },
#
#  'ge'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrge($_[0])
#                              : $_[0] -&gt; bstrge($_[1]); },
#
#  'eq'    =&gt;      sub { $_[0] -&gt; bstreq($_[1]); },
#
#  'ne'    =&gt;      sub { $_[0] -&gt; bstrne($_[1]); },

  # overload key: binary

  '&amp;'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; band($_[0])
                              : $_[0] -&gt; copy() -&gt; band($_[1]); },

  '&amp;='    =&gt;      sub { $_[0] -&gt; band($_[1]); },

  '|'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bior($_[0])
                              : $_[0] -&gt; copy() -&gt; bior($_[1]); },

  '|='    =&gt;      sub { $_[0] -&gt; bior($_[1]); },

  '^'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bxor($_[0])
                              : $_[0] -&gt; copy() -&gt; bxor($_[1]); },

  '^='    =&gt;      sub { $_[0] -&gt; bxor($_[1]); },

#  '&amp;.'    =&gt;      sub { },

#  '&amp;.='   =&gt;      sub { },

#  '|.'    =&gt;      sub { },

#  '|.='   =&gt;      sub { },

#  '^.'    =&gt;      sub { },

#  '^.='   =&gt;      sub { },

  # overload key: unary

  'neg'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bneg(); },

#  '!'     =&gt;      sub { },

  '~'     =&gt;      sub { $_[0] -&gt; copy() -&gt; bnot(); },

#  '~.'    =&gt;      sub { },

  # overload key: mutators

  '++'    =&gt;      sub { $_[0] -&gt; binc() },

  '--'    =&gt;      sub { $_[0] -&gt; bdec() },

  # overload key: func

  'atan2' =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; batan2($_[0])
                              : $_[0] -&gt; copy() -&gt; batan2($_[1]); },

  'cos'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bcos(); },

  'sin'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bsin(); },

  'exp'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bexp($_[1]); },

  'abs'   =&gt;      sub { $_[0] -&gt; copy() -&gt; babs(); },

  'log'   =&gt;      sub { $_[0] -&gt; copy() -&gt; blog(); },

  'sqrt'  =&gt;      sub { $_[0] -&gt; copy() -&gt; bsqrt(); },

  'int'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bint(); },

  # overload key: conversion

  'bool'  =&gt;      sub { $_[0] -&gt; is_zero() ? '' : 1; },

  '""'    =&gt;      sub { $_[0] -&gt; bstr(); },

  '0+'    =&gt;      sub { $_[0] -&gt; numify(); },

  '='     =&gt;      sub { $_[0] -&gt; copy(); },

  ;

##############################################################################
# global constants, flags and assorted stuff

# the following are public, but their usage is not recommended. Use the
# accessor methods instead.

# class constants, use Class-&gt;constant_name() to access
# one of 'even', 'odd', '+inf', '-inf', 'zero', 'trunc' or 'common'
$round_mode = 'even';
$accuracy   = undef;
$precision  = undef;
$div_scale  = 40;

$upgrade = undef;
$downgrade = undef;
# the package we are using for our private parts, defaults to:
# Math::BigInt-&gt;config('lib')
my $LIB = 'Math::BigInt::Calc';

# are NaNs ok? (otherwise it dies when encountering an NaN) set w/ config()
$_trap_nan = 0;
# the same for infinity
$_trap_inf = 0;

# constant for easier life
my $nan = 'NaN';

# Has import() been called yet? This variable is needed to make "require" work.

my $IMPORT = 0;

# some digits of accuracy for blog(undef, 10); which we use in blog() for speed
my $LOG_10 =
 '2.3025850929940456840179914546843642076011014886287729760333279009675726097';
my $LOG_10_A = length($LOG_10)-1;
# ditto for log(2)
my $LOG_2 =
 '0.6931471805599453094172321214581765680755001343602552541206800094933936220';
my $LOG_2_A = length($LOG_2)-1;
my $HALF = '0.5';                       # made into an object if nec.

##############################################################################
# the old code had $rnd_mode, so we need to support it, too

sub TIESCALAR {
    my ($class) = @_;
    bless \$round_mode, $class;
}

sub FETCH {
    return $round_mode;
}

sub STORE {
    $rnd_mode = (ref $_[0]) -&gt; round_mode($_[1]);
}

BEGIN {
    *objectify = \&amp;Math::BigInt::objectify;

    # when someone sets $rnd_mode, we catch this and check the value to see
    # whether it is valid or not.
    $rnd_mode   = 'even';
    tie $rnd_mode, 'Math::BigFloat';

    *as_number = \&amp;as_int;
}

sub DESTROY {
    # going through AUTOLOAD for every DESTROY is costly, avoid it by empty sub
}

sub AUTOLOAD {

    # Make fxxx() work by mapping fxxx() to Math::BigFloat::bxxx().

    my $name = $AUTOLOAD;
    $name =~ s/^(.*):://;               # strip package name
    my $class = $1 || __PACKAGE__;

    $class -&gt; import() if $IMPORT == 0;

    # E.g., "fabs" -&gt; "babs", but "is_neg" -&gt; "is_neg"

    my $bname = $name;
    $bname =~ s/^f/b/;

    # Map, e.g., Math::BigFloat::fabs() to Math::BigFloat::babs()

    if ($bname ne $name &amp;&amp; Math::BigFloat -&gt; can($bname)) {
        no strict 'refs';
        return &amp;{"Math::BigFloat::$bname"}(@_);
    }

    # Map, e.g., Math::BigFloat::babs() to Math::BigInt::babs()

    elsif (Math::BigInt -&gt; can($bname)) {
        no strict 'refs';
        return &amp;{"Math::BigInt::$bname"}(@_);
    }

    else {
        croak("Can't call $class-&gt;$name(), not a valid method");
    }
}

##############################################################################

# Compare the following function with @ISA above. This inheritance mess needs a
# clean up. When doing so, also consider the BEGIN block and the AUTOLOAD code.
# Fixme!

sub isa {
    my ($self, $class) = @_;
    return if $class =~ /^Math::BigInt/; # we aren't one of these
    UNIVERSAL::isa($self, $class);
}

sub config {
    # return (later set?) configuration data as hash ref
    my $class = shift || 'Math::BigFloat';

    # Getter/accessor.

    if (@_ == 1 &amp;&amp; ref($_[0]) ne 'HASH') {
        my $param = shift;
        return $class if $param eq 'class';
        return $LIB   if $param eq 'with';
        return $class-&gt;SUPER::config($param);
    }

    # Setter.

    my $cfg = $class-&gt;SUPER::config(@_);

    # now we need only to override the ones that are different from our parent
    $cfg-&gt;{class} = $class;
    $cfg-&gt;{with} = $LIB;
    $cfg;
}

###############################################################################
# Constructor methods
###############################################################################

sub new {
    # Create a new Math::BigFloat object from a string or another bigfloat
    # object.
    # _e: exponent
    # _m: mantissa
    # sign  =&gt; ("+", "-", "+inf", "-inf", or "NaN")

    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Although this use has been discouraged for more than 10 years, people
    # apparently still use it, so we still support it.

    return $class -&gt; bzero() unless @_;

    my ($wanted, @r) = @_;

    if (!defined($wanted)) {
        #if (warnings::enabled("uninitialized")) {
        #    warnings::warn("uninitialized",
        #                   "Use of uninitialized value in new()");
        #}
        return $class -&gt; bzero(@r);
    }

    if (!ref($wanted) &amp;&amp; $wanted eq "") {
        #if (warnings::enabled("numeric")) {
        #    warnings::warn("numeric",
        #                   q|Argument "" isn't numeric in new()|);
        #}
        #return $class -&gt; bzero(@r);
        return $class -&gt; bnan(@r);
    }

    # Initialize a new object.

    $self = bless {}, $class unless $selfref;

    # Math::BigFloat or subclass

    if (defined(blessed($wanted)) &amp;&amp; $wanted -&gt; isa(__PACKAGE__)) {

        # Don't copy the accuracy and precision, because a new object should get
        # them from the global configuration.

        $self -&gt; {sign} = $wanted -&gt; {sign};
        $self -&gt; {_m}   = $LIB -&gt; _copy($wanted -&gt; {_m});
        $self -&gt; {_es}  = $wanted -&gt; {_es};
        $self -&gt; {_e}   = $LIB -&gt; _copy($wanted -&gt; {_e});
        $self = $self-&gt;round(@r)
          unless @r &gt;= 2 &amp;&amp; !defined($r[0]) &amp;&amp; !defined($r[1]);
        return $self;
    }

    # Shortcut for Math::BigInt and its subclasses. This should be improved.

    if (defined(blessed($wanted))) {
        if ($wanted -&gt; isa('Math::BigInt')) {
            $self-&gt;{sign} = $wanted -&gt; {sign};
            $self-&gt;{_m}   = $LIB -&gt; _copy($wanted -&gt; {value});
            $self-&gt;{_es}  = '+';
            $self-&gt;{_e}   = $LIB -&gt; _zero();
            return $self -&gt; bnorm();
        }

        if ($wanted -&gt; can("as_number")) {
            $self-&gt;{sign} = $wanted -&gt; sign();
            $self-&gt;{_m}   = $wanted -&gt; as_number() -&gt; {value};
            $self-&gt;{_es}  = '+';
            $self-&gt;{_e}   = $LIB -&gt; _zero();
            return $self -&gt; bnorm();
        }
    }

    # Shortcut for simple forms like '123' that have no trailing zeros. Trailing
    # zeros would require a non-zero exponent.

    if ($wanted =~
        / ^
          \s*                           # optional leading whitespace
          ( [+-]? )                     # optional sign
          0*                            # optional leading zeros
          ( [1-9] (?: [0-9]* [1-9] )? ) # significand
          \s*                           # optional trailing whitespace
          $
        /x)
    {
        return $downgrade -&gt; new($1 . $2) if defined $downgrade;
        $self-&gt;{sign} = $1 || '+';
        $self-&gt;{_m}   = $LIB -&gt; _new($2);
        $self-&gt;{_es}  = '+';
        $self-&gt;{_e}   = $LIB -&gt; _zero();
        $self = $self-&gt;round(@r)
          unless @r &gt;= 2 &amp;&amp; !defined $r[0] &amp;&amp; !defined $r[1];
        return $self;
    }

    # Handle Infs.

    if ($wanted =~ / ^
                     \s*
                     ( [+-]? )
                     inf (?: inity )?
                     \s*
                     \z
                   /ix)
    {
        my $sgn = $1 || '+';
        return $class -&gt; binf($sgn, @r);
    }

    # Handle explicit NaNs (not the ones returned due to invalid input).

    if ($wanted =~ / ^
                     \s*
                     ( [+-]? )
                     nan
                     \s*
                     \z
                   /ix)
    {
        return $class -&gt; bnan(@r);
    }

    my @parts;

    if (
        # Handle hexadecimal numbers. We auto-detect hexadecimal numbers if they
        # have a "0x", "0X", "x", or "X" prefix, cf. CORE::oct().

        $wanted =~ /^\s*[+-]?0?[Xx]/ and
        @parts = $class -&gt; _hex_str_to_flt_lib_parts($wanted)

          or

        # Handle octal numbers. We auto-detect octal numbers if they have a
        # "0o", "0O", "o", "O" prefix, cf. CORE::oct().

        $wanted =~ /^\s*[+-]?0?[Oo]/ and
        @parts = $class -&gt; _oct_str_to_flt_lib_parts($wanted)

          or

        # Handle binary numbers. We auto-detect binary numbers if they have a
        # "0b", "0B", "b", or "B" prefix, cf. CORE::oct().

        $wanted =~ /^\s*[+-]?0?[Bb]/ and
        @parts = $class -&gt; _bin_str_to_flt_lib_parts($wanted)

          or

        # At this point, what is left are decimal numbers that aren't handled
        # above and octal floating point numbers that don't have any of the
        # "0o", "0O", "o", or "O" prefixes. First see if it is a decimal number.

        @parts = $class -&gt; _dec_str_to_flt_lib_parts($wanted)
          or

        # See if it is an octal floating point number. The extra check is
        # included because _oct_str_to_flt_lib_parts() accepts octal numbers
        # that don't have a prefix (this is needed to make it work with, e.g.,
        # from_oct() that don't require a prefix). However, Perl requires a
        # prefix for octal floating point literals. For example, "1p+0" is not
        # valid, but "01p+0" and "0__1p+0" are.

        $wanted =~ /^\s*[+-]?0_*\d/ and
        @parts = $class -&gt; _oct_str_to_flt_lib_parts($wanted))
    {
        ($self-&gt;{sign}, $self-&gt;{_m}, $self-&gt;{_es}, $self-&gt;{_e}) = @parts;

        $self = $self-&gt;round(@r)
          unless @r &gt;= 2 &amp;&amp; !defined($r[0]) &amp;&amp; !defined($r[1]);

        return $downgrade -&gt; new($self -&gt; bdstr(), @r)
          if defined($downgrade) &amp;&amp; $self -&gt; is_int();
        return $self;
    }

    # If we get here, the value is neither a valid decimal, binary, octal, or
    # hexadecimal number. It is not an explicit Inf or a NaN either.

    return $class -&gt; bnan(@r);
}

sub from_dec {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_dec');

    my $str = shift;
    my @r = @_;

    # If called as a class method, initialize a new object.

    $self = bless {}, $class unless $selfref;

    if (my @parts = $class -&gt; _dec_str_to_flt_lib_parts($str)) {
        ($self-&gt;{sign}, $self-&gt;{_m}, $self-&gt;{_es}, $self-&gt;{_e}) = @parts;

        $self = $self-&gt;round(@r)
          unless @r &gt;= 2 &amp;&amp; !defined($r[0]) &amp;&amp; !defined($r[1]);

        return $downgrade -&gt; new($self -&gt; bdstr(), @r)
          if defined($downgrade) &amp;&amp; $self -&gt; is_int();
        return $self;
    }

    return $self -&gt; bnan(@r);
}

sub from_hex {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_hex');

    my $str = shift;
    my @r = @_;

    # If called as a class method, initialize a new object.

    $self = bless {}, $class unless $selfref;

    if (my @parts = $class -&gt; _hex_str_to_flt_lib_parts($str)) {
        ($self-&gt;{sign}, $self-&gt;{_m}, $self-&gt;{_es}, $self-&gt;{_e}) = @parts;

        $self = $self-&gt;round(@r)
          unless @r &gt;= 2 &amp;&amp; !defined($r[0]) &amp;&amp; !defined($r[1]);

        return $downgrade -&gt; new($self -&gt; bdstr(), @r)
          if defined($downgrade) &amp;&amp; $self -&gt; is_int();
        return $self;
    }

    return $self -&gt; bnan(@r);
}

sub from_oct {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_oct');

    my $str = shift;
    my @r = @_;

    # If called as a class method, initialize a new object.

    $self = bless {}, $class unless $selfref;

    if (my @parts = $class -&gt; _oct_str_to_flt_lib_parts($str)) {
        ($self-&gt;{sign}, $self-&gt;{_m}, $self-&gt;{_es}, $self-&gt;{_e}) = @parts;

        $self = $self-&gt;round(@r)
          unless @r &gt;= 2 &amp;&amp; !defined($r[0]) &amp;&amp; !defined($r[1]);

        return $downgrade -&gt; new($self -&gt; bdstr(), @r)
          if defined($downgrade) &amp;&amp; $self -&gt; is_int();
        return $self;
    }

    return $self -&gt; bnan(@r);
}

sub from_bin {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_bin');

    my $str = shift;
    my @r = @_;

    # If called as a class method, initialize a new object.

    $self = bless {}, $class unless $selfref;

    if (my @parts = $class -&gt; _bin_str_to_flt_lib_parts($str)) {
        ($self-&gt;{sign}, $self-&gt;{_m}, $self-&gt;{_es}, $self-&gt;{_e}) = @parts;

        $self = $self-&gt;round(@r)
          unless @r &gt;= 2 &amp;&amp; !defined($r[0]) &amp;&amp; !defined($r[1]);

        return $downgrade -&gt; new($self -&gt; bdstr(), @r)
          if defined($downgrade) &amp;&amp; $self -&gt; is_int();
        return $self;
    }

    return $self -&gt; bnan(@r);
}

sub from_ieee754 {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_ieee754');

    my $in     = shift;     # input string (or raw bytes)
    my $format = shift;     # format ("binary32", "decimal64" etc.)
    my $enc;                # significand encoding (applies only to decimal)
    my $k;                  # storage width in bits
    my $b;                  # base
    my @r = @_;             # rounding parameters, if any

    if ($format =~ /^binary(\d+)\z/) {
        $k = $1;
        $b = 2;
    } elsif ($format =~ /^decimal(\d+)(dpd|bcd)?\z/) {
        $k = $1;
        $b = 10;
        $enc = $2 || 'dpd';     # default is dencely-packed decimals (DPD)
    } elsif ($format eq 'half') {
        $k = 16;
        $b = 2;
    } elsif ($format eq 'single') {
        $k = 32;
        $b = 2;
    } elsif ($format eq 'double') {
        $k = 64;
        $b = 2;
    } elsif ($format eq 'quadruple') {
        $k = 128;
        $b = 2;
    } elsif ($format eq 'octuple') {
        $k = 256;
        $b = 2;
    } elsif ($format eq 'sexdecuple') {
        $k = 512;
        $b = 2;
    }

    if ($b == 2) {

        # Get the parameters for this format.

        my $p;                      # precision (in bits)
        my $t;                      # number of bits in significand
        my $w;                      # number of bits in exponent

        if ($k == 16) {             # binary16 (half-precision)
            $p = 11;
            $t = 10;
            $w =  5;
        } elsif ($k == 32) {        # binary32 (single-precision)
            $p = 24;
            $t = 23;
            $w =  8;
        } elsif ($k == 64) {        # binary64 (double-precision)
            $p = 53;
            $t = 52;
            $w = 11;
        } else {                    # binaryN (quadruple-precision and above)
            if ($k &lt; 128 || $k != 32 * sprintf('%.0f', $k / 32)) {
                croak "Number of bits must be 16, 32, 64, or &gt;= 128 and",
                  " a multiple of 32";
            }
            $p = $k - sprintf('%.0f', 4 * log($k) / log(2)) + 13;
            $t = $p - 1;
            $w = $k - $t - 1;
        }

        # The maximum exponent, minimum exponent, and exponent bias.

        my $emax = $class -&gt; new(2) -&gt; bpow($w - 1) -&gt; bdec();
        my $emin = 1 - $emax;
        my $bias = $emax;

        # Undefined input.

        unless (defined $in) {
            carp("Input is undefined");
            return $self -&gt; bzero(@r);
        }

        # Make sure input string is a string of zeros and ones.

        my $len = CORE::length $in;
        if (8 * $len == $k) {                   # bytes
            $in = unpack "B*", $in;
        } elsif (4 * $len == $k) {              # hexadecimal
            if ($in =~ /([^\da-f])/i) {
                croak "Illegal hexadecimal digit '$1'";
            }
            $in = unpack "B*", pack "H*", $in;
        } elsif ($len == $k) {                  # bits
            if ($in =~ /([^01])/) {
                croak "Illegal binary digit '$1'";
            }
        } else {
            croak "Unknown input -- $in";
        }

        # Split bit string into sign, exponent, and mantissa/significand.

        my $sign = substr($in, 0, 1) eq '1' ? '-' : '+';
        my $expo = $class -&gt; from_bin(substr($in, 1, $w));
        my $mant = $class -&gt; from_bin(substr($in, $w + 1));

        my $x;

        $expo = $expo -&gt; bsub($bias);           # subtract bias

        if ($expo &lt; $emin) {                    # zero and subnormals
            if ($mant == 0) {                   # zero
                $x = $class -&gt; bzero();
            } else {                            # subnormals
                # compute (1/$b)**(N) rather than ($b)**(-N)
                $x = $class -&gt; new("0.5");      # 1/$b
                $x = $x -&gt; bpow($bias + $t - 1) -&gt; bmul($mant);
                $x = $x -&gt; bneg() if $sign eq '-';
            }
        }

        elsif ($expo &gt; $emax) {                 # inf and nan
            if ($mant == 0) {                   # inf
                $x = $class -&gt; binf($sign);
            } else {                            # nan
                $x = $class -&gt; bnan(@r);
            }
        }

        else {                                  # normals
            $mant = $class -&gt; new(2) -&gt; bpow($t) -&gt; badd($mant);
            if ($expo &lt; $t) {
                # compute (1/$b)**(N) rather than ($b)**(-N)
                $x = $class -&gt; new("0.5");      # 1/$b
                $x = $x -&gt; bpow($t - $expo) -&gt; bmul($mant);
            } else {
                $x = $class -&gt; new(2);
                $x = $x -&gt; bpow($expo - $t) -&gt; bmul($mant);
            }
            $x = $x -&gt; bneg() if $sign eq '-';
        }

        if ($selfref) {
            $self -&gt; {sign} = $x -&gt; {sign};
            $self -&gt; {_m}   = $x -&gt; {_m};
            $self -&gt; {_es}  = $x -&gt; {_es};
            $self -&gt; {_e}   = $x -&gt; {_e};
        } else {
            $self = $x;
        }

        return $downgrade -&gt; new($self -&gt; bdstr(), @r)
          if defined($downgrade) &amp;&amp; $self -&gt; is_int();
        return $self -&gt; round(@r);
    }

    croak("The format '$format' is not yet supported.");
}

sub bzero {
    # create/assign '+0'

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('bzero');

    # Get the rounding parameters, if any.

    my @r = @_;

    return $downgrade -&gt; bzero(@r) if defined $downgrade;

    # If called as a class method, initialize a new object.

    $self = bless {}, $class unless $selfref;

    $self -&gt; {sign} = '+';
    $self -&gt; {_m}   = $LIB -&gt; _zero();
    $self -&gt; {_es}  = '+';
    $self -&gt; {_e}   = $LIB -&gt; _zero();

    # If rounding parameters are given as arguments, use them. If no rounding
    # parameters are given, and if called as a class method initialize the new
    # instance with the class variables.

    #return $self -&gt; round(@r);  # this should work, but doesnt; fixme!

    if (@r) {
        if (@r &gt;= 2 &amp;&amp; defined($r[0]) &amp;&amp; defined($r[1])) {
            carp "can't specify both accuracy and precision";
            return $self -&gt; bnan();
        }
        $self-&gt;{accuracy} = $r[0];
        $self-&gt;{precision} = $r[1];
    } else {
        unless($selfref) {
            $self-&gt;{accuracy} = $class -&gt; accuracy();
            $self-&gt;{precision} = $class -&gt; precision();
        }
    }

    return $self;
}

sub bone {
    # Create or assign '+1' (or -1 if given sign '-').

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('bone');

    return $downgrade -&gt; bone(@_) if defined $downgrade;

    # Get the sign.

    my $sign = '+';     # default is to return +1
    if (defined($_[0]) &amp;&amp; $_[0] =~ /^\s*([+-])\s*$/) {
        $sign = $1;
        shift;
    }

    # Get the rounding parameters, if any.

    my @r = @_;

    # If called as a class method, initialize a new object.

    $self = bless {}, $class unless $selfref;

    $self -&gt; {sign} = $sign;
    $self -&gt; {_m}   = $LIB -&gt; _one();
    $self -&gt; {_es}  = '+';
    $self -&gt; {_e}   = $LIB -&gt; _zero();

    # If rounding parameters are given as arguments, use them. If no rounding
    # parameters are given, and if called as a class method initialize the new
    # instance with the class variables.

    #return $self -&gt; round(@r);  # this should work, but doesnt; fixme!

    if (@r) {
        if (@r &gt;= 2 &amp;&amp; defined($r[0]) &amp;&amp; defined($r[1])) {
            carp "can't specify both accuracy and precision";
            return $self -&gt; bnan();
        }
        $self-&gt;{accuracy} = $_[0];
        $self-&gt;{precision} = $_[1];
    } else {
        unless($selfref) {
            $self-&gt;{accuracy} = $class -&gt; accuracy();
            $self-&gt;{precision} = $class -&gt; precision();
        }
    }

    return $self;
}

sub binf {
    # create/assign a '+inf' or '-inf'

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    {
        no strict 'refs';
        if (${"${class}::_trap_inf"}) {
            croak("Tried to create +-inf in $class-&gt;binf()");
        }
    }

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('binf');

    return $downgrade -&gt; binf(@_) if $downgrade;

    # Get the sign.

    my $sign = '+';     # default is to return positive infinity
    if (defined($_[0]) &amp;&amp; $_[0] =~ /^\s*([+-])(inf|$)/i) {
        $sign = $1;
        shift;
    }

    # Get the rounding parameters, if any.

    my @r = @_;

    # If called as a class method, initialize a new object.

    $self = bless {}, $class unless $selfref;

    $self -&gt; {sign} = $sign . 'inf';
    $self -&gt; {_m}   = $LIB -&gt; _zero();
    $self -&gt; {_es}  = '+';
    $self -&gt; {_e}   = $LIB -&gt; _zero();

    # If rounding parameters are given as arguments, use them. If no rounding
    # parameters are given, and if called as a class method initialize the new
    # instance with the class variables.

    #return $self -&gt; round(@r);  # this should work, but doesnt; fixme!

    if (@r) {
        if (@r &gt;= 2 &amp;&amp; defined($r[0]) &amp;&amp; defined($r[1])) {
            carp "can't specify both accuracy and precision";
            return $self -&gt; bnan();
        }
        $self-&gt;{accuracy} = $r[0];
        $self-&gt;{precision} = $r[1];
    } else {
        unless($selfref) {
            $self-&gt;{accuracy} = $class -&gt; accuracy();
            $self-&gt;{precision} = $class -&gt; precision();
        }
    }

    return $self;
}

sub bnan {
    # create/assign a 'NaN'

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    {
        no strict 'refs';
        if (${"${class}::_trap_nan"}) {
            croak("Tried to create NaN in $class-&gt;bnan()");
        }
    }

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('bnan');

    return $downgrade -&gt; bnan(@_) if defined $downgrade;

    # Get the rounding parameters, if any.

    my @r = @_;

    # If called as a class method, initialize a new object.

    $self = bless {}, $class unless $selfref;

    $self -&gt; {sign} = $nan;
    $self -&gt; {_m}   = $LIB -&gt; _zero();
    $self -&gt; {_es}  = '+';
    $self -&gt; {_e}   = $LIB -&gt; _zero();

    # If rounding parameters are given as arguments, use them. If no rounding
    # parameters are given, and if called as a class method initialize the new
    # instance with the class variables.

    #return $self -&gt; round(@r);  # this should work, but doesnt; fixme!

    if (@r) {
        if (@r &gt;= 2 &amp;&amp; defined($r[0]) &amp;&amp; defined($r[1])) {
            carp "can't specify both accuracy and precision";
            return $self -&gt; bnan();
        }
        $self-&gt;{accuracy} = $r[0];
        $self-&gt;{precision} = $r[1];
    } else {
        unless($selfref) {
            $self-&gt;{accuracy} = $class -&gt; accuracy();
            $self-&gt;{precision} = $class -&gt; precision();
        }
    }

    return $self;
}

sub bpi {

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    # Called as                 Argument list
    # ---------                 -------------
    # Math::BigFloat-&gt;bpi()     ("Math::BigFloat")
    # Math::BigFloat-&gt;bpi(10)   ("Math::BigFloat", 10)
    # $x-&gt;bpi()                 ($x)
    # $x-&gt;bpi(10)               ($x, 10)
    # Math::BigFloat::bpi()     ()
    # Math::BigFloat::bpi(10)   (10)
    #
    # In ambiguous cases, we favour the OO-style, so the following case
    #
    #   $n = Math::BigFloat-&gt;new("10");
    #   $x = Math::BigFloat-&gt;bpi($n);
    #
    # which gives an argument list with the single element $n, is resolved as
    #
    #   $n-&gt;bpi();

    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;
    my @r       = @_;                   # rounding paramters

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    if ($selfref) {                     # bpi() called as an instance method
        return $self if $self -&gt; modify('bpi');
    } else {                            # bpi() called as a class method
        $self  = bless {}, $class;      # initialize new instance
    }

    ($self, @r) = $self -&gt; _find_round_parameters(@r);

    # The accuracy, i.e., the number of digits. Pi has one digit before the
    # dot, so a precision of 4 digits is equivalent to an accuracy of 5 digits.

    my $n = defined $r[0] ? $r[0]
          : defined $r[1] ? 1 - $r[1]
          : $self -&gt; div_scale();

    my $rmode = defined $r[2] ? $r[2] : $self -&gt; round_mode();

    my $pi;

    if ($n &lt;= 1000) {

        # 75 x 14 = 1050 digits

        my $all_digits = &lt;&lt;EOF;
314159265358979323846264338327950288419716939937510582097494459230781640628
620899862803482534211706798214808651328230664709384460955058223172535940812
848111745028410270193852110555964462294895493038196442881097566593344612847
564823378678316527120190914564856692346034861045432664821339360726024914127
372458700660631558817488152092096282925409171536436789259036001133053054882
046652138414695194151160943305727036575959195309218611738193261179310511854
807446237996274956735188575272489122793818301194912983367336244065664308602
139494639522473719070217986094370277053921717629317675238467481846766940513
200056812714526356082778577134275778960917363717872146844090122495343014654
958537105079227968925892354201995611212902196086403441815981362977477130996
051870721134999999837297804995105973173281609631859502445945534690830264252
230825334468503526193118817101000313783875288658753320838142061717766914730
359825349042875546873115956286388235378759375195778185778053217122680661300
192787661119590921642019893809525720106548586327886593615338182796823030195
EOF

        # Should we round up?

        my $round_up;

        # From the string above, we need to extract the number of digits we
        # want plus extra characters for the newlines.

        my $nchrs = $n + int($n / 75);

        # Extract the digits we want.

        my $digits = substr($all_digits, 0, $nchrs);

        # Find out whether we should round up or down. Rounding is easy, since
        # pi is trancendental. With directed rounding, it doesn't matter what
        # the following digits are. With rounding to nearest, we only have to
        # look at one extra digit.

        if ($rmode eq 'trunc') {
            $round_up = 0;
        } else {
            my $next_digit = substr($all_digits, $nchrs, 1);
            $round_up = $next_digit lt '5' ? 0 : 1;
        }

        # Remove the newlines.

        $digits =~ tr/0-9//cd;

        # Now do the rounding. We could easily make the regex substitution
        # handle all cases, but we avoid using the regex engine when it is
        # simple to avoid it.

        if ($round_up) {
            my $last_digit = substr($digits, -1, 1);
            if ($last_digit lt '9') {
                substr($digits, -1, 1) = ++$last_digit;
            } else {
                $digits =~ s{([0-8])(9+)$}
                            { ($1 + 1) . ("0" x CORE::length($2)) }e;
            }
        }

        # Convert to an object.

        $pi = bless {
                     sign =&gt; '+',
                     _m   =&gt; $LIB -&gt; _new($digits),
                     _es  =&gt; '-',
                     _e   =&gt; $LIB -&gt; _new($n - 1),
                    }, $class;

    } else {

        # For large accuracy, the arctan formulas become very inefficient with
        # Math::BigFloat, so use Brent-Salamin (aka AGM or Gauss-Legendre).

        # Use a few more digits in the intermediate computations.
        $n += 8;

        $HALF = $class -&gt; new($HALF) unless ref($HALF);
        my ($an, $bn, $tn, $pn)
          = ($class -&gt; bone, $HALF -&gt; copy() -&gt; bsqrt($n),
             $HALF -&gt; copy() -&gt; bmul($HALF), $class -&gt; bone);
        while ($pn &lt; $n) {
            my $prev_an = $an -&gt; copy();
            $an = $an -&gt; badd($bn) -&gt; bmul($HALF, $n);
            $bn = $bn -&gt; bmul($prev_an) -&gt; bsqrt($n);
            $prev_an = $prev_an -&gt; bsub($an);
            $tn = $tn -&gt; bsub($pn * $prev_an * $prev_an);
            $pn = $pn -&gt; badd($pn);
        }
        $an = $an -&gt; badd($bn);
        $an = $an -&gt; bmul($an, $n) -&gt; bdiv(4 * $tn, $n);

        $an = $an -&gt; round(@r);
        $pi = $an;
    }

    if (defined $r[0]) {
        $pi -&gt; accuracy($r[0]);
    } elsif (defined $r[1]) {
        $pi -&gt; precision($r[1]);
    }

    for my $key (qw/ sign _m _es _e accuracy precision /) {
        $self -&gt; {$key} = $pi -&gt; {$key};
    }

    return $downgrade -&gt; new($self -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; $self-&gt;is_int();
    return $self;
}

sub copy {
    my ($x, $class);
    if (ref($_[0])) {           # $y = $x -&gt; copy()
        $x = shift;
        $class = ref($x);
    } else {                    # $y = Math::BigInt -&gt; copy($y)
        $class = shift;
        $x = shift;
    }

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @_;

    my $copy = bless {}, $class;

    $copy-&gt;{sign} = $x-&gt;{sign};
    $copy-&gt;{_es}  = $x-&gt;{_es};
    $copy-&gt;{_m}   = $LIB-&gt;_copy($x-&gt;{_m});
    $copy-&gt;{_e}   = $LIB-&gt;_copy($x-&gt;{_e});
    $copy-&gt;{accuracy}   = $x-&gt;{accuracy} if exists $x-&gt;{accuracy};
    $copy-&gt;{precision}   = $x-&gt;{precision} if exists $x-&gt;{precision};

    return $copy;
}

sub as_int {
    # return copy as a bigint representation of this Math::BigFloat number
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);
    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x -&gt; copy() if $x -&gt; isa("Math::BigInt");

    # Disable upgrading and downgrading.

    require Math::BigInt;
    my $upg = Math::BigInt -&gt; upgrade();
    my $dng = Math::BigInt -&gt; downgrade();
    Math::BigInt -&gt; upgrade(undef);
    Math::BigInt -&gt; downgrade(undef);

    # Copy the value.

    my $y;
    if ($x -&gt; is_inf()) {
        $y = Math::BigInt -&gt; binf($x-&gt;sign());
    } elsif ($x -&gt; is_nan()) {
        $y = Math::BigInt -&gt; bnan();
    } else {
        $y = $LIB-&gt;_copy($x-&gt;{_m});
        if ($x-&gt;{_es} eq '-') {                     # &lt; 0
            $y = $LIB-&gt;_rsft($y, $x-&gt;{_e}, 10);
        } elsif (! $LIB-&gt;_is_zero($x-&gt;{_e})) {      # &gt; 0
            $y = $LIB-&gt;_lsft($y, $x-&gt;{_e}, 10);
        }
        $y = Math::BigInt-&gt;new($x-&gt;{sign} . $LIB-&gt;_str($y));
    }

    # Copy the remaining instance variables.

    ($y-&gt;{accuracy}, $y-&gt;{precision}) = ($x-&gt;{accuracy}, $x-&gt;{precision});

    # Restore upgrading and downgrading.

    Math::BigInt -&gt; upgrade($upg);
    Math::BigInt -&gt; downgrade($dng);

    return $y;
}

sub as_float {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);
    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x -&gt; copy() if $x -&gt; isa("Math::BigFloat");

    # Disable upgrading and downgrading.

    my $upg = Math::BigFloat -&gt; upgrade();
    my $dng = Math::BigFloat -&gt; downgrade();
    Math::BigFloat -&gt; upgrade(undef);
    Math::BigFloat -&gt; downgrade(undef);

    # Copy the value.

    my $y = Math::BigFloat -&gt; new($x);

    # Copy the remaining instance variables.

    ($y-&gt;{accuracy}, $y-&gt;{precision}) = ($x-&gt;{accuracy}, $x-&gt;{precision});

    # Restore upgrading and downgrading.

    Math::BigFloat -&gt; upgrade($upg);
    Math::BigFloat -&gt; downgrade($dng);

    return $y;
}

sub as_rat {
    # return copy as a Math::BigRat representation of this Math::BigFloat
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);
    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x -&gt; copy() if $x -&gt; isa("Math::BigRat");

    # Disable upgrading and downgrading.

    require Math::BigRat;
    my $upg = Math::BigRat -&gt; upgrade();
    my $dng = Math::BigRat -&gt; downgrade();
    Math::BigRat -&gt; upgrade(undef);
    Math::BigRat -&gt; downgrade(undef);

    # Copy the value.

    my $y;
    if ($x -&gt; is_inf()) {
        $y = Math::BigRat -&gt; binf($x -&gt; sign());
    } elsif ($x -&gt; is_nan()) {
        $y = Math::BigRat -&gt; bnan();
    } else {
        my @flt_parts = ($x-&gt;{sign}, $x-&gt;{_m}, $x-&gt;{_es}, $x-&gt;{_e});
        my @rat_parts = $class -&gt; _flt_lib_parts_to_rat_lib_parts(@flt_parts);
        $y = Math::BigRat -&gt; new($rat_parts[0] . $LIB -&gt; _str($rat_parts[1])
                                         . '/' . $LIB -&gt; _str($rat_parts[2]));
    }

    # Copy the remaining instance variables.

    ($y-&gt;{accuracy}, $y-&gt;{precision}) = ($x-&gt;{accuracy}, $x-&gt;{precision});

    # Restore upgrading and downgrading.

    Math::BigRat -&gt; upgrade($upg);
    Math::BigRat -&gt; downgrade($dng);

    return $y;
}

###############################################################################
# Boolean methods
###############################################################################

sub is_zero {
    # return true if arg (BFLOAT or num_str) is zero
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    ($x-&gt;{sign} eq '+' &amp;&amp; $LIB-&gt;_is_zero($x-&gt;{_m})) ? 1 : 0;
}

sub is_one {
    # return true if arg (BFLOAT or num_str) is +1 or -1 if signis given
    my (undef, $x, $sign) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    $sign = '+' if !defined $sign || $sign ne '-';

    ($x-&gt;{sign} eq $sign &amp;&amp;
     $LIB-&gt;_is_zero($x-&gt;{_e}) &amp;&amp;
     $LIB-&gt;_is_one($x-&gt;{_m})) ? 1 : 0;
}

sub is_odd {
    # return true if arg (BFLOAT or num_str) is odd or false if even
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    (($x-&gt;{sign} =~ /^[+-]$/) &amp;&amp; # NaN &amp; +-inf aren't
     ($LIB-&gt;_is_zero($x-&gt;{_e})) &amp;&amp;
     ($LIB-&gt;_is_odd($x-&gt;{_m}))) ? 1 : 0;
}

sub is_even {
    # return true if arg (BINT or num_str) is even or false if odd
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    (($x-&gt;{sign} =~ /^[+-]$/) &amp;&amp;        # NaN &amp; +-inf aren't
     ($x-&gt;{_es} eq '+') &amp;&amp;              # 123.45 isn't
     ($LIB-&gt;_is_even($x-&gt;{_m}))) ? 1 : 0; # but 1200 is
}

sub is_int {
    # return true if arg (BFLOAT or num_str) is an integer
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    (($x-&gt;{sign} =~ /^[+-]$/) &amp;&amp; # NaN and +-inf aren't
     ($x-&gt;{_es} eq '+')) ? 1 : 0; # 1e-1 =&gt; no integer
}

###############################################################################
# Comparison methods
###############################################################################

sub bcmp {
    # Compares 2 values.  Returns one of undef, &lt;0, =0, &gt;0. (suitable for sort)

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Handle all 'nan' cases.

    return    if ($x-&gt;{sign} eq $nan) || ($y-&gt;{sign} eq $nan);

    # Handle all '+inf' and '-inf' cases.

    return  0 if ($x-&gt;{sign} eq '+inf' &amp;&amp; $y-&gt;{sign} eq '+inf' ||
                  $x-&gt;{sign} eq '-inf' &amp;&amp; $y-&gt;{sign} eq '-inf');
    return +1 if $x-&gt;{sign} eq '+inf'; # x = +inf and y &lt; +inf
    return -1 if $x-&gt;{sign} eq '-inf'; # x = -inf and y &gt; -inf
    return -1 if $y-&gt;{sign} eq '+inf'; # x &lt; +inf and y = +inf
    return +1 if $y-&gt;{sign} eq '-inf'; # x &gt; -inf and y = -inf

    # Handle all cases with opposite signs.

    return +1 if $x-&gt;{sign} eq '+' &amp;&amp; $y-&gt;{sign} eq '-'; # also does 0 &lt;=&gt; -y
    return -1 if $x-&gt;{sign} eq '-' &amp;&amp; $y-&gt;{sign} eq '+'; # also does -x &lt;=&gt; 0

    # Handle all remaining zero cases.

    my $xz = $x-&gt;is_zero();
    my $yz = $y-&gt;is_zero();
    return  0 if $xz &amp;&amp; $yz;             # 0 &lt;=&gt; 0
    return -1 if $xz &amp;&amp; $y-&gt;{sign} eq '+'; # 0 &lt;=&gt; +y
    return +1 if $yz &amp;&amp; $x-&gt;{sign} eq '+'; # +x &lt;=&gt; 0

    # Both arguments are now finite, non-zero numbers with the same sign.

    my $cmp;

    # The next step is to compare the exponents, but since each mantissa is an
    # integer of arbitrary value, the exponents must be normalized by the length
    # of the mantissas before we can compare them.

    my $mxl = $LIB-&gt;_len($x-&gt;{_m});
    my $myl = $LIB-&gt;_len($y-&gt;{_m});

    # If the mantissas have the same length, there is no point in normalizing
    # the exponents by the length of the mantissas, so treat that as a special
    # case.

    if ($mxl == $myl) {

        # First handle the two cases where the exponents have different signs.

        if ($x-&gt;{_es} eq '+' &amp;&amp; $y-&gt;{_es} eq '-') {
            $cmp = +1;
        } elsif ($x-&gt;{_es} eq '-' &amp;&amp; $y-&gt;{_es} eq '+') {
            $cmp = -1;
        }

        # Then handle the case where the exponents have the same sign.

        else {
            $cmp = $LIB-&gt;_acmp($x-&gt;{_e}, $y-&gt;{_e});
            $cmp = -$cmp if $x-&gt;{_es} eq '-';
        }

        # Adjust for the sign, which is the same for x and y, and bail out if
        # we're done.

        $cmp = -$cmp if $x-&gt;{sign} eq '-'; # 124 &gt; 123, but -124 &lt; -123
        return $cmp if $cmp;

    }

    # We must normalize each exponent by the length of the corresponding
    # mantissa. Life is a lot easier if we first make both exponents
    # non-negative. We do this by adding the same positive value to both
    # exponent. This is safe, because when comparing the exponents, only the
    # relative difference is important.

    my $ex;
    my $ey;

    if ($x-&gt;{_es} eq '+') {

        # If the exponent of x is &gt;= 0 and the exponent of y is &gt;= 0, there is
        # no need to do anything special.

        if ($y-&gt;{_es} eq '+') {
            $ex = $LIB-&gt;_copy($x-&gt;{_e});
            $ey = $LIB-&gt;_copy($y-&gt;{_e});
        }

        # If the exponent of x is &gt;= 0 and the exponent of y is &lt; 0, add the
        # absolute value of the exponent of y to both.

        else {
            $ex = $LIB-&gt;_copy($x-&gt;{_e});
            $ex = $LIB-&gt;_add($ex, $y-&gt;{_e}); # ex + |ey|
            $ey = $LIB-&gt;_zero();             # -ex + |ey| = 0
        }

    } else {

        # If the exponent of x is &lt; 0 and the exponent of y is &gt;= 0, add the
        # absolute value of the exponent of x to both.

        if ($y-&gt;{_es} eq '+') {
            $ex = $LIB-&gt;_zero(); # -ex + |ex| = 0
            $ey = $LIB-&gt;_copy($y-&gt;{_e});
            $ey = $LIB-&gt;_add($ey, $x-&gt;{_e}); # ey + |ex|
        }

        # If the exponent of x is &lt; 0 and the exponent of y is &lt; 0, add the
        # absolute values of both exponents to both exponents.

        else {
            $ex = $LIB-&gt;_copy($y-&gt;{_e}); # -ex + |ey| + |ex| = |ey|
            $ey = $LIB-&gt;_copy($x-&gt;{_e}); # -ey + |ex| + |ey| = |ex|
        }

    }

    # Now we can normalize the exponents by adding lengths of the mantissas.

    $ex = $LIB-&gt;_add($ex, $LIB-&gt;_new($mxl));
    $ey = $LIB-&gt;_add($ey, $LIB-&gt;_new($myl));

    # We're done if the exponents are different.

    $cmp = $LIB-&gt;_acmp($ex, $ey);
    $cmp = -$cmp if $x-&gt;{sign} eq '-'; # 124 &gt; 123, but -124 &lt; -123
    return $cmp if $cmp;

    # Compare the mantissas, but first normalize them by padding the shorter
    # mantissa with zeros (shift left) until it has the same length as the
    # longer mantissa.

    my $mx = $x-&gt;{_m};
    my $my = $y-&gt;{_m};

    if ($mxl &gt; $myl) {
        $my = $LIB-&gt;_lsft($LIB-&gt;_copy($my), $LIB-&gt;_new($mxl - $myl), 10);
    } elsif ($mxl &lt; $myl) {
        $mx = $LIB-&gt;_lsft($LIB-&gt;_copy($mx), $LIB-&gt;_new($myl - $mxl), 10);
    }

    $cmp = $LIB-&gt;_acmp($mx, $my);
    $cmp = -$cmp if $x-&gt;{sign} eq '-'; # 124 &gt; 123, but -124 &lt; -123
    return $cmp;

}

sub bacmp {
    # Compares 2 values, ignoring their signs.
    # Returns one of undef, &lt;0, =0, &gt;0. (suitable for sort)

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # handle +-inf and NaN's
    if ($x-&gt;{sign} !~ /^[+-]$/ || $y-&gt;{sign} !~ /^[+-]$/) {
        return    if (($x-&gt;{sign} eq $nan) || ($y-&gt;{sign} eq $nan));
        return  0 if ($x-&gt;is_inf() &amp;&amp; $y-&gt;is_inf());
        return  1 if ($x-&gt;is_inf() &amp;&amp; !$y-&gt;is_inf());
        return -1;
    }

    # shortcut
    my $xz = $x-&gt;is_zero();
    my $yz = $y-&gt;is_zero();
    return 0 if $xz &amp;&amp; $yz;     # 0 &lt;=&gt; 0
    return -1 if $xz &amp;&amp; !$yz;   # 0 &lt;=&gt; +y
    return 1 if $yz &amp;&amp; !$xz;    # +x &lt;=&gt; 0

    # adjust so that exponents are equal
    my $lxm = $LIB-&gt;_len($x-&gt;{_m});
    my $lym = $LIB-&gt;_len($y-&gt;{_m});
    my ($xes, $yes) = (1, 1);
    $xes = -1 if $x-&gt;{_es} ne '+';
    $yes = -1 if $y-&gt;{_es} ne '+';
    # the numify somewhat limits our length, but makes it much faster
    my $lx = $lxm + $xes * $LIB-&gt;_num($x-&gt;{_e});
    my $ly = $lym + $yes * $LIB-&gt;_num($y-&gt;{_e});
    my $l = $lx - $ly;
    return $l &lt;=&gt; 0 if $l != 0;

    # lengths (corrected by exponent) are equal
    # so make mantissa equal-length by padding with zero (shift left)
    my $diff = $lxm - $lym;
    my $xm = $x-&gt;{_m};          # not yet copy it
    my $ym = $y-&gt;{_m};
    if ($diff &gt; 0) {
        $ym = $LIB-&gt;_copy($y-&gt;{_m});
        $ym = $LIB-&gt;_lsft($ym, $LIB-&gt;_new($diff), 10);
    } elsif ($diff &lt; 0) {
        $xm = $LIB-&gt;_copy($x-&gt;{_m});
        $xm = $LIB-&gt;_lsft($xm, $LIB-&gt;_new(-$diff), 10);
    }
    $LIB-&gt;_acmp($xm, $ym);
}

###############################################################################
# Arithmetic methods
###############################################################################

sub bneg {
    # (BINT or num_str) return BINT
    # negate number or make a negated number from string
    my (undef, $x, @r) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bneg');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan();

    # For +0 do not negate (to have always normalized +0).
    $x-&gt;{sign} =~ tr/+-/-+/
      unless $x-&gt;{sign} eq '+' &amp;&amp; $LIB-&gt;_is_zero($x-&gt;{_m});

    return $downgrade -&gt; new($x -&gt; bdstr(), @r) if defined($downgrade)
      &amp;&amp; ($x -&gt; is_int() || $x -&gt; is_inf() || $x -&gt; is_nan());
    return $x -&gt; round(@r);
}

sub bnorm {
    # bnorm() can't support rounding, because bround() and bfround() call
    # bnorm(), which would recurse indefinitely.

    # adjust m and e so that m is smallest possible
    my (undef, $x, @r) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # inf, nan etc
    if ($x-&gt;{sign} !~ /^[+-]$/) {
        return $downgrade -&gt; new($x) if defined $downgrade;
        return $x;
    }

    my $zeros = $LIB-&gt;_zeros($x-&gt;{_m}); # correct for trailing zeros
    if ($zeros != 0) {
        my $z = $LIB-&gt;_new($zeros);
        $x-&gt;{_m} = $LIB-&gt;_rsft($x-&gt;{_m}, $z, 10);
        if ($x-&gt;{_es} eq '-') {
            if ($LIB-&gt;_acmp($x-&gt;{_e}, $z) &gt;= 0) {
                $x-&gt;{_e} = $LIB-&gt;_sub($x-&gt;{_e}, $z);
                $x-&gt;{_es} = '+' if $LIB-&gt;_is_zero($x-&gt;{_e});
            } else {
                $x-&gt;{_e} = $LIB-&gt;_sub($LIB-&gt;_copy($z), $x-&gt;{_e});
                $x-&gt;{_es} = '+';
            }
        } else {
            $x-&gt;{_e} = $LIB-&gt;_add($x-&gt;{_e}, $z);
        }
    } else {
        # $x can only be 0Ey if there are no trailing zeros ('0' has 0 trailing
        # zeros). So, for something like 0Ey, set y to 0, and -0 =&gt; +0
        if ($LIB-&gt;_is_zero($x-&gt;{_m})) {
            $x-&gt;{sign} = '+';
            $x-&gt;{_es}  = '+';
            $x-&gt;{_e}   = $LIB-&gt;_zero();
        }
    }

    return $downgrade -&gt; new($x)
      if defined($downgrade) &amp;&amp; $x-&gt;is_int();
    return $x;
}

sub binc {
    # increment arg by one
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('binc');

    # Inf and NaN

    return $x -&gt; bnan(@r)             if $x -&gt; is_nan();
    return $x -&gt; binf($x-&gt;{sign}, @r) if $x -&gt; is_inf();

    # Non-integer

    if ($x-&gt;{_es} eq '-') {
        return $x-&gt;badd($class-&gt;bone(), @r);
    }

    # If the exponent is non-zero, convert the internal representation, so that,
    # e.g., 12e+3 becomes 12000e+0 and we can easily increment the mantissa.

    if (!$LIB-&gt;_is_zero($x-&gt;{_e})) {
        $x-&gt;{_m} = $LIB-&gt;_lsft($x-&gt;{_m}, $x-&gt;{_e}, 10); # 1e2 =&gt; 100
        $x-&gt;{_e} = $LIB-&gt;_zero();                       # normalize
        $x-&gt;{_es} = '+';
        # we know that the last digit of $x will be '1' or '9', depending on the
        # sign
    }

    # now $x-&gt;{_e} == 0
    if ($x-&gt;{sign} eq '+') {
        $x-&gt;{_m} = $LIB-&gt;_inc($x-&gt;{_m});
        return $x-&gt;bnorm()-&gt;bround(@r);
    } elsif ($x-&gt;{sign} eq '-') {
        $x-&gt;{_m} = $LIB-&gt;_dec($x-&gt;{_m});
        $x-&gt;{sign} = '+' if $LIB-&gt;_is_zero($x-&gt;{_m}); # -1 +1 =&gt; -0 =&gt; +0
        return $x-&gt;bnorm()-&gt;bround(@r);
    }

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; $x -&gt; is_int();
    return $x;
}

sub bdec {
    # decrement arg by one
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bdec');

    # Inf and NaN

    return $x -&gt; bnan(@r)             if $x -&gt; is_nan();
    return $x -&gt; binf($x-&gt;{sign}, @r) if $x -&gt; is_inf();

    # Non-integer

    if ($x-&gt;{_es} eq '-') {
        return $x-&gt;badd($class-&gt;bone('-'), @r);
    }

    # If the exponent is non-zero, convert the internal representation, so that,
    # e.g., 12e+3 becomes 12000e+0 and we can easily increment the mantissa.

    if (!$LIB-&gt;_is_zero($x-&gt;{_e})) {
        $x-&gt;{_m} = $LIB-&gt;_lsft($x-&gt;{_m}, $x-&gt;{_e}, 10); # 1e2 =&gt; 100
        $x-&gt;{_e} = $LIB-&gt;_zero();                       # normalize
        $x-&gt;{_es} = '+';
    }

    # now $x-&gt;{_e} == 0
    my $zero = $x-&gt;is_zero();
    if (($x-&gt;{sign} eq '-') || $zero) {           # x &lt;= 0
        $x-&gt;{_m} = $LIB-&gt;_inc($x-&gt;{_m});
        $x-&gt;{sign} = '-' if $zero;                # 0 =&gt; 1 =&gt; -1
        $x-&gt;{sign} = '+' if $LIB-&gt;_is_zero($x-&gt;{_m}); # -1 +1 =&gt; -0 =&gt; +0
        return $x-&gt;bnorm()-&gt;round(@r);
    }
    elsif ($x-&gt;{sign} eq '+') {                   # x &gt; 0
        $x-&gt;{_m} = $LIB-&gt;_dec($x-&gt;{_m});
        return $x-&gt;bnorm()-&gt;round(@r);
    }

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; $x -&gt; is_int();
    return $x -&gt; round(@r);
}

sub badd {
    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x-&gt;modify('badd');

    # inf and NaN handling
    if ($x-&gt;{sign} !~ /^[+-]$/ || $y-&gt;{sign} !~ /^[+-]$/) {

        # $x is NaN and/or $y is NaN
        if ($x-&gt;{sign} eq $nan || $y-&gt;{sign} eq $nan) {
            $x = $x-&gt;bnan();
        }

        # $x is Inf and $y is Inf
        elsif ($x-&gt;{sign} =~ /^[+-]inf$/ &amp;&amp; $y-&gt;{sign} =~ /^[+-]inf$/) {
            # +Inf + +Inf or -Inf + -Inf =&gt; same, rest is NaN
            $x = $x-&gt;bnan() if $x-&gt;{sign} ne $y-&gt;{sign};
        }

        # +-inf + something =&gt; +-inf; something +-inf =&gt; +-inf
        elsif ($y-&gt;{sign} =~ /^[+-]inf$/) {
            $x-&gt;{sign} = $y-&gt;{sign};
        }

        return $downgrade -&gt; new($x -&gt; bdstr(), @r) if defined $downgrade;
        return $x -&gt; round(@r);
    }

    return $upgrade-&gt;badd($x, $y, @r) if defined $upgrade;

    $r[3] = $y;                 # no push!

    # for speed: no add for $x + 0
    if ($y-&gt;is_zero()) {
        $x = $x-&gt;round(@r);
    }

    # for speed: no add for 0 + $y
    elsif ($x-&gt;is_zero()) {
        # make copy, clobbering up x (modify in place!)
        $x-&gt;{_e} = $LIB-&gt;_copy($y-&gt;{_e});
        $x-&gt;{_es} = $y-&gt;{_es};
        $x-&gt;{_m} = $LIB-&gt;_copy($y-&gt;{_m});
        $x-&gt;{sign} = $y-&gt;{sign} || $nan;
        $x = $x-&gt;round(@r);
    }

    # both $x and $y are non-zero
    else {

        # take lower of the two e's and adapt m1 to it to match m2
        my $e = $y-&gt;{_e};
        $e = $LIB-&gt;_zero() if !defined $e; # if no BFLOAT?
        $e = $LIB-&gt;_copy($e);              # make copy (didn't do it yet)

        my $es;

        ($e, $es) = $LIB -&gt; _ssub($e, $y-&gt;{_es} || '+', $x-&gt;{_e}, $x-&gt;{_es});

        my $add = $LIB-&gt;_copy($y-&gt;{_m});

        if ($es eq '-') {                       # &lt; 0
            $x-&gt;{_m} = $LIB-&gt;_lsft($x-&gt;{_m}, $e, 10);
            ($x-&gt;{_e}, $x-&gt;{_es}) = $LIB -&gt; _sadd($x-&gt;{_e}, $x-&gt;{_es}, $e, $es);
        } elsif (!$LIB-&gt;_is_zero($e)) {         # &gt; 0
            $add = $LIB-&gt;_lsft($add, $e, 10);
        }

        # else: both e are the same, so just leave them

        if ($x-&gt;{sign} eq $y-&gt;{sign}) {
            $x-&gt;{_m} = $LIB-&gt;_add($x-&gt;{_m}, $add);
        } else {
            ($x-&gt;{_m}, $x-&gt;{sign}) =
              $LIB -&gt; _sadd($x-&gt;{_m}, $x-&gt;{sign}, $add, $y-&gt;{sign});
        }

        # delete trailing zeros, then round
        $x = $x-&gt;bnorm()-&gt;round(@r);
    }

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; $x -&gt; is_int();
    return $x;          # rounding already done above
}

sub bsub {
    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x -&gt; modify('bsub');

    if ($y -&gt; is_zero()) {
        $x = $x -&gt; round(@r);
    } else {

        # To correctly handle the special case $x -&gt; bsub($x), we note the sign
        # of $x, then flip the sign of $y, and if the sign of $x changed too,
        # then we know that $x and $y are the same object.

        my $xsign = $x -&gt; {sign};
        $y -&gt; {sign} =~ tr/+-/-+/;      # does nothing for NaN
        if ($xsign ne $x -&gt; {sign}) {
            # special case of $x -&gt; bsub($x) results in 0
            if ($xsign =~ /^[+-]$/) {
                $x = $x -&gt; bzero(@r);
            } else {
                $x = $x -&gt; bnan();      # NaN, -inf, +inf
            }
            return $downgrade -&gt; new($x -&gt; bdstr(), @r) if defined $downgrade;
            return $x -&gt; round(@r);
        }
        $x = $x -&gt; badd($y, @r);        # badd does not leave internal zeros
        $y -&gt; {sign} =~ tr/+-/-+/;      # reset $y (does nothing for NaN)
    }

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
    $x;                         # already rounded by badd() or no rounding
}

sub bmul {
    # multiply two numbers

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x-&gt;modify('bmul');

    return $x-&gt;bnan(@r) if ($x-&gt;{sign} eq $nan) || ($y-&gt;{sign} eq $nan);

    # inf handling
    if (($x-&gt;{sign} =~ /^[+-]inf$/) || ($y-&gt;{sign} =~ /^[+-]inf$/)) {
        return $x-&gt;bnan(@r) if $x-&gt;is_zero() || $y-&gt;is_zero();
        # result will always be +-inf:
        # +inf * +/+inf =&gt; +inf, -inf * -/-inf =&gt; +inf
        # +inf * -/-inf =&gt; -inf, -inf * +/+inf =&gt; -inf
        return $x-&gt;binf(@r) if ($x-&gt;{sign} =~ /^\+/ &amp;&amp; $y-&gt;{sign} =~ /^\+/);
        return $x-&gt;binf(@r) if ($x-&gt;{sign} =~ /^-/ &amp;&amp; $y-&gt;{sign} =~ /^-/);
        return $x-&gt;binf('-', @r);
    }

    return $upgrade-&gt;bmul($x, $y, @r) if defined $upgrade;

    # aEb * cEd = (a*c)E(b+d)
    $x-&gt;{_m} = $LIB-&gt;_mul($x-&gt;{_m}, $y-&gt;{_m});
    ($x-&gt;{_e}, $x-&gt;{_es})
      = $LIB -&gt; _sadd($x-&gt;{_e}, $x-&gt;{_es}, $y-&gt;{_e}, $y-&gt;{_es});

    $r[3] = $y;                 # no push!

    # adjust sign:
    $x-&gt;{sign} = $x-&gt;{sign} ne $y-&gt;{sign} ? '-' : '+';
    $x = $x-&gt;bnorm-&gt;round(@r);

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
    return $x;
}

sub bmuladd {
    # multiply two numbers and add the third to the result

    # set up parameters
    my ($class, $x, $y, $z, @r)
      = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1]) &amp;&amp; ref($_[1]) eq ref($_[2])
      ? (ref($_[0]), @_)
      : objectify(3, @_);

    return $x if $x-&gt;modify('bmuladd');

    return $x-&gt;bnan(@r) if (($x-&gt;{sign} eq $nan) ||
                            ($y-&gt;{sign} eq $nan) ||
                            ($z-&gt;{sign} eq $nan));

    # inf handling
    if (($x-&gt;{sign} =~ /^[+-]inf$/) || ($y-&gt;{sign} =~ /^[+-]inf$/)) {
        return $x-&gt;bnan(@r) if $x-&gt;is_zero() || $y-&gt;is_zero();
        # result will always be +-inf:
        # +inf * +/+inf =&gt; +inf, -inf * -/-inf =&gt; +inf
        # +inf * -/-inf =&gt; -inf, -inf * +/+inf =&gt; -inf
        return $x-&gt;binf(@r) if ($x-&gt;{sign} =~ /^\+/ &amp;&amp; $y-&gt;{sign} =~ /^\+/);
        return $x-&gt;binf(@r) if ($x-&gt;{sign} =~ /^-/ &amp;&amp; $y-&gt;{sign} =~ /^-/);
        return $x-&gt;binf('-', @r);
    }

    # aEb * cEd = (a*c)E(b+d)
    $x-&gt;{_m} = $LIB-&gt;_mul($x-&gt;{_m}, $y-&gt;{_m});
    ($x-&gt;{_e}, $x-&gt;{_es})
      = $LIB -&gt; _sadd($x-&gt;{_e}, $x-&gt;{_es}, $y-&gt;{_e}, $y-&gt;{_es});

    $r[3] = $y;                 # no push!

    # adjust sign:
    $x-&gt;{sign} = $x-&gt;{sign} ne $y-&gt;{sign} ? '-' : '+';

    # z=inf handling (z=NaN handled above)
    if ($z-&gt;{sign} =~ /^[+-]inf$/) {
        $x-&gt;{sign} = $z-&gt;{sign};
        return $downgrade -&gt; new($x -&gt; bdstr(), @r) if defined $downgrade;
        return $x -&gt; round(@r);
    }

    # take lower of the two e's and adapt m1 to it to match m2
    my $e = $z-&gt;{_e};
    $e = $LIB-&gt;_zero() if !defined $e; # if no BFLOAT?
    $e = $LIB-&gt;_copy($e);              # make copy (didn't do it yet)

    my $es;

    ($e, $es) = $LIB -&gt; _ssub($e, $z-&gt;{_es} || '+', $x-&gt;{_e}, $x-&gt;{_es});

    my $add = $LIB-&gt;_copy($z-&gt;{_m});

    if ($es eq '-')             # &lt; 0
    {
        $x-&gt;{_m} = $LIB-&gt;_lsft($x-&gt;{_m}, $e, 10);
        ($x-&gt;{_e}, $x-&gt;{_es}) = $LIB -&gt; _sadd($x-&gt;{_e}, $x-&gt;{_es}, $e, $es);
    } elsif (!$LIB-&gt;_is_zero($e)) # &gt; 0
    {
        $add = $LIB-&gt;_lsft($add, $e, 10);
    }
    # else: both e are the same, so just leave them

    if ($x-&gt;{sign} eq $z-&gt;{sign}) {
        # add
        $x-&gt;{_m} = $LIB-&gt;_add($x-&gt;{_m}, $add);
    } else {
        ($x-&gt;{_m}, $x-&gt;{sign}) =
          $LIB -&gt; _sadd($x-&gt;{_m}, $x-&gt;{sign}, $add, $z-&gt;{sign});
    }

    # delete trailing zeros, then round
    $x = $x-&gt;bnorm()-&gt;round(@r);

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
    return $x;
}

sub bdiv {
    # (dividend: BFLOAT or num_str, divisor: BFLOAT or num_str) return
    # (BFLOAT, BFLOAT) (quo, rem) or BFLOAT (only quo)

    # set up parameters
    my ($class, $x, $y, @r) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, @r) = objectify(2, @_);
    }

    return $x if $x-&gt;modify('bdiv');

    my $wantarray = wantarray;  # call only once

    # At least one argument is NaN. This is handled the same way as in
    # Math::BigInt -&gt; bdiv().

    if ($x -&gt; is_nan() || $y -&gt; is_nan()) {
        return $wantarray ? ($x -&gt; bnan(@r), $class -&gt; bnan(@r))
                          : $x -&gt; bnan(@r);
    }

    # Divide by zero and modulo zero. This is handled the same way as in
    # Math::BigInt -&gt; bdiv(). See the comment in the code for Math::BigInt -&gt;
    # bdiv() for further details.

    if ($y -&gt; is_zero()) {
        my ($quo, $rem);
        if ($wantarray) {
            $rem = $x -&gt; copy() -&gt; round(@r);
            $rem = $downgrade -&gt; new($rem, @r)
              if defined($downgrade) &amp;&amp; $rem -&gt; is_int();
        }
        if ($x -&gt; is_zero()) {
            $quo = $x -&gt; bnan(@r);
        } else {
            $quo = $x -&gt; binf($x -&gt; {sign}, @r);
        }
        return $wantarray ? ($quo, $rem) : $quo;
    }

    # Numerator (dividend) is +/-inf. This is handled the same way as in
    # Math::BigInt -&gt; bdiv(). See the comment in the code for Math::BigInt -&gt;
    # bdiv() for further details.

    if ($x -&gt; is_inf()) {
        my ($quo, $rem);
        $rem = $class -&gt; bnan(@r) if $wantarray;
        if ($y -&gt; is_inf()) {
            $quo = $x -&gt; bnan(@r);
        } else {
            my $sign = $x -&gt; bcmp(0) == $y -&gt; bcmp(0) ? '+' : '-';
            $quo = $x -&gt; binf($sign, @r);
        }
        return $wantarray ? ($quo, $rem) : $quo;
    }

    # Denominator (divisor) is +/-inf. This is handled the same way as in
    # Math::BigInt -&gt; bdiv(), with one exception: In scalar context,
    # Math::BigFloat does true division (although rounded), not floored division
    # (F-division), so a finite number divided by +/-inf is always zero. See the
    # comment in the code for Math::BigInt -&gt; bdiv() for further details.

    if ($y -&gt; is_inf()) {
        my ($quo, $rem);
        if ($wantarray) {
            if ($x -&gt; is_zero() || $x -&gt; bcmp(0) == $y -&gt; bcmp(0)) {
                $rem = $x -&gt; copy() -&gt; round(@r);
                $rem = $downgrade -&gt; new($rem, @r)
                  if defined($downgrade) &amp;&amp; $rem -&gt; is_int();
                $quo = $x -&gt; bzero(@r);
            } else {
                $rem = $class -&gt; binf($y -&gt; {sign}, @r);
                $quo = $x -&gt; bone('-', @r);
            }
            return ($quo, $rem);
        } else {
            if ($y -&gt; is_inf()) {
                if ($x -&gt; is_nan() || $x -&gt; is_inf()) {
                    return $x -&gt; bnan(@r);
                } else {
                    return $x -&gt; bzero(@r);
                }
            }
        }
    }

    # At this point, both the numerator and denominator are finite numbers, and
    # the denominator (divisor) is non-zero.

    # x == 0?
    if ($x-&gt;is_zero()) {
        my ($quo, $rem);
        $quo = $x-&gt;round(@r);
        $quo = $downgrade -&gt; new($quo, @r)
          if defined($downgrade) &amp;&amp; $quo -&gt; is_int();
        if ($wantarray) {
            $rem = $class -&gt; bzero(@r);
            return $quo, $rem;
        }
        return $quo;
    }

    # Division might return a value that we can not represent exactly, so
    # upgrade, if upgrading is enabled.

    return $upgrade -&gt; bdiv($x, $y, @r)
      if defined($upgrade) &amp;&amp; !wantarray &amp;&amp; !$LIB -&gt; _is_one($y -&gt; {_m});

    # we need to limit the accuracy to protect against overflow
    my $fallback = 0;
    my (@params, $scale);
    ($x, @params) = $x-&gt;_find_round_parameters($r[0], $r[1], $r[2], $y);

    return $x -&gt; round(@r) if $x-&gt;is_nan();  # error in _find_round_parameters?

    # no rounding at all, so must use fallback
    if (scalar @params == 0) {
        # simulate old behaviour
        $params[0] = $class-&gt;div_scale(); # and round to it as accuracy
        $scale = $params[0]+4;            # at least four more for proper round
        $params[2] = $r[2];               # round mode by caller or undef
        $fallback = 1;                    # to clear a/p afterwards
    } else {
        # the 4 below is empirical, and there might be cases where it is not
        # enough...
        $scale = abs($params[0] || $params[1]) + 4; # take whatever is defined
    }

    my $rem;
    $rem = $class -&gt; bzero() if wantarray;

    $y = $class-&gt;new($y) unless $y-&gt;isa('Math::BigFloat');

    my $lx = $LIB -&gt; _len($x-&gt;{_m});
    my $ly = $LIB -&gt; _len($y-&gt;{_m});
    $scale = $lx if $lx &gt; $scale;
    $scale = $ly if $ly &gt; $scale;
    my $diff = $ly - $lx;
    $scale += $diff if $diff &gt; 0; # if lx &lt;&lt; ly, but not if ly &lt;&lt; lx!

    # check that $y is not 1 nor -1 and cache the result:
    my $y_not_one = !($LIB-&gt;_is_zero($y-&gt;{_e}) &amp;&amp; $LIB-&gt;_is_one($y-&gt;{_m}));

    # flipping the sign of $y will also flip the sign of $x for the special
    # case of $x-&gt;bsub($x); so we can catch it below:
    my $xsign = $x-&gt;{sign};
    $y-&gt;{sign} =~ tr/+-/-+/;

    if ($xsign ne $x-&gt;{sign}) {
        # special case of $x /= $x results in 1
        $x = $x-&gt;bone();        # "fixes" also sign of $y, since $x is $y
    } else {
        # correct $y's sign again
        $y-&gt;{sign} =~ tr/+-/-+/;
        # continue with normal div code:

        # make copy of $x in case of list context for later remainder
        # calculation
        if (wantarray &amp;&amp; $y_not_one) {
            $rem = $x-&gt;copy();
        }

        $x-&gt;{sign} = $x-&gt;{sign} ne $y-&gt;sign() ? '-' : '+';

        # check for / +-1 (+/- 1E0)
        if ($y_not_one) {
            # promote Math::BigInt and its subclasses (except when already a
            # Math::BigFloat)
            $y = $class-&gt;new($y) unless $y-&gt;isa('Math::BigFloat');

            # calculate the result to $scale digits and then round it
            # a * 10 ** b / c * 10 ** d =&gt; a/c * 10 ** (b-d)
            $x-&gt;{_m} = $LIB-&gt;_lsft($x-&gt;{_m}, $LIB-&gt;_new($scale), 10);
            $x-&gt;{_m} = $LIB-&gt;_div($x-&gt;{_m}, $y-&gt;{_m}); # a/c

            # correct exponent of $x
            ($x-&gt;{_e}, $x-&gt;{_es})
              = $LIB -&gt; _ssub($x-&gt;{_e}, $x-&gt;{_es}, $y-&gt;{_e}, $y-&gt;{_es});
            # correct for 10**scale
            ($x-&gt;{_e}, $x-&gt;{_es})
              = $LIB -&gt; _ssub($x-&gt;{_e}, $x-&gt;{_es}, $LIB-&gt;_new($scale), '+');
            $x = $x-&gt;bnorm();   # remove trailing 0's
        }
    }                           # end else $x != $y

    # shortcut to not run through _find_round_parameters again
    if (defined $params[0]) {
        $x-&gt;{accuracy} = undef;               # clear before round
        $x = $x-&gt;bround($params[0], $params[2]); # then round accordingly
    } else {
        $x-&gt;{precision} = undef;               # clear before round
        $x = $x-&gt;bfround($params[1], $params[2]); # then round accordingly
    }
    if ($fallback) {
        # clear a/p after round, since user did not request it
        $x-&gt;{accuracy} = undef;
        $x-&gt;{precision} = undef;
    }

    if (wantarray) {
        if ($y_not_one) {
            $x = $x -&gt; bfloor();
            $rem = $rem-&gt;bmod($y, @params); # copy already done
        }
        if ($fallback) {
            # clear a/p after round, since user did not request it
            $rem-&gt;{accuracy} = undef;
            $rem-&gt;{precision} = undef;
        }
        $x = $downgrade -&gt; new($x -&gt; bdstr(), @r)
          if defined($downgrade) &amp;&amp; $x -&gt; is_int();
        $rem = $downgrade -&gt; new($rem -&gt; bdstr(), @r)
          if defined($downgrade) &amp;&amp; $rem -&gt; is_int();
        return ($x, $rem);
    }

    $x = $downgrade -&gt; new($x, @r)
      if defined($downgrade) &amp;&amp; $x -&gt; is_int();
    $x;         # rounding already done above
}

sub bmod {
    # (dividend: BFLOAT or num_str, divisor: BFLOAT or num_str) return remainder

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x-&gt;modify('bmod');

    # At least one argument is NaN. This is handled the same way as in
    # Math::BigInt -&gt; bmod().

    return $x -&gt; bnan(@r) if $x -&gt; is_nan() || $y -&gt; is_nan();

    # Modulo zero. This is handled the same way as in Math::BigInt -&gt; bmod().

    if ($y -&gt; is_zero()) {
        return $x -&gt; round(@r);
    }

    # Numerator (dividend) is +/-inf. This is handled the same way as in
    # Math::BigInt -&gt; bmod().

    if ($x -&gt; is_inf()) {
        return $x -&gt; bnan(@r);
    }

    # Denominator (divisor) is +/-inf. This is handled the same way as in
    # Math::BigInt -&gt; bmod().

    if ($y -&gt; is_inf()) {
        if ($x -&gt; is_zero() || $x -&gt; bcmp(0) == $y -&gt; bcmp(0)) {
            return $x -&gt; round(@r);
        } else {
            return $x -&gt; binf($y -&gt; sign(), @r);
        }
    }

    return $x-&gt;bzero(@r) if $x-&gt;is_zero()
      || ($x-&gt;is_int() &amp;&amp;
          # check that $y == +1 or $y == -1:
          ($LIB-&gt;_is_zero($y-&gt;{_e}) &amp;&amp; $LIB-&gt;_is_one($y-&gt;{_m})));

    my $cmp = $x-&gt;bacmp($y);    # equal or $x &lt; $y?
    if ($cmp == 0) {            # $x == $y =&gt; result 0
        return $x -&gt; bzero(@r);
    }

    # only $y of the operands negative?
    my $neg = $x-&gt;{sign} ne $y-&gt;{sign} ? 1 : 0;

    $x-&gt;{sign} = $y-&gt;{sign};     # calc sign first
    if ($cmp &lt; 0 &amp;&amp; $neg == 0) { # $x &lt; $y =&gt; result $x
        return $x -&gt; round(@r);
    }

    my $ym = $LIB-&gt;_copy($y-&gt;{_m});

    # 2e1 =&gt; 20
    $ym = $LIB-&gt;_lsft($ym, $y-&gt;{_e}, 10)
      if $y-&gt;{_es} eq '+' &amp;&amp; !$LIB-&gt;_is_zero($y-&gt;{_e});

    # if $y has digits after dot
    my $shifty = 0;             # correct _e of $x by this
    if ($y-&gt;{_es} eq '-')       # has digits after dot
    {
        # 123 % 2.5 =&gt; 1230 % 25 =&gt; 5 =&gt; 0.5
        $shifty = $LIB-&gt;_num($y-&gt;{_e});  # no more digits after dot
        # 123 =&gt; 1230, $y-&gt;{_m} is already 25
        $x-&gt;{_m} = $LIB-&gt;_lsft($x-&gt;{_m}, $y-&gt;{_e}, 10);
    }
    # $ym is now mantissa of $y based on exponent 0

    my $shiftx = 0;             # correct _e of $x by this
    if ($x-&gt;{_es} eq '-')       # has digits after dot
    {
        # 123.4 % 20 =&gt; 1234 % 200
        $shiftx = $LIB-&gt;_num($x-&gt;{_e}); # no more digits after dot
        $ym = $LIB-&gt;_lsft($ym, $x-&gt;{_e}, 10); # 123 =&gt; 1230
    }
    # 123e1 % 20 =&gt; 1230 % 20
    if ($x-&gt;{_es} eq '+' &amp;&amp; !$LIB-&gt;_is_zero($x-&gt;{_e})) {
        $x-&gt;{_m} = $LIB-&gt;_lsft($x-&gt;{_m}, $x-&gt;{_e}, 10); # es =&gt; '+' here
    }

    $x-&gt;{_e} = $LIB-&gt;_new($shiftx);
    $x-&gt;{_es} = '+';
    $x-&gt;{_es} = '-' if $shiftx != 0 || $shifty != 0;
    $x-&gt;{_e} = $LIB-&gt;_add($x-&gt;{_e}, $LIB-&gt;_new($shifty)) if $shifty != 0;

    # now mantissas are equalized, exponent of $x is adjusted, so calc result

    $x-&gt;{_m} = $LIB-&gt;_mod($x-&gt;{_m}, $ym);

    $x-&gt;{sign} = '+' if $LIB-&gt;_is_zero($x-&gt;{_m}); # fix sign for -0
    $x = $x-&gt;bnorm();

    # if one of them negative =&gt; correct in place
    if ($neg != 0 &amp;&amp; ! $x -&gt; is_zero()) {
        my $r = $y - $x;
        $x-&gt;{_m} = $r-&gt;{_m};
        $x-&gt;{_e} = $r-&gt;{_e};
        $x-&gt;{_es} = $r-&gt;{_es};
        $x-&gt;{sign} = '+' if $LIB-&gt;_is_zero($x-&gt;{_m}); # fix sign for -0
        $x = $x-&gt;bnorm();
    }

    $x = $x-&gt;round($r[0], $r[1], $r[2], $y);
    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
    return $x;
}

sub bmodpow {
    # takes a very large number to a very large exponent in a given very
    # large modulus, quickly, thanks to binary exponentiation. Supports
    # negative exponents.
    my ($class, $num, $exp, $mod, @r)
      = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1]) &amp;&amp; ref($_[1]) eq ref($_[2])
      ? (ref($_[0]), @_)
      : objectify(3, @_);

    return $num if $num-&gt;modify('bmodpow');

    return $num -&gt; bnan(@r)
      if $mod-&gt;is_nan() || $exp-&gt;is_nan() || $mod-&gt;is_nan();

    # check modulus for valid values
    return $num-&gt;bnan(@r) if $mod-&gt;{sign} ne '+' || $mod-&gt;is_zero();

    # check exponent for valid values
    if ($exp-&gt;{sign} =~ /\w/) {
        # i.e., if it's NaN, +inf, or -inf...
        return $num-&gt;bnan(@r);
    }

    $num = $num-&gt;bmodinv($mod, @r) if $exp-&gt;{sign} eq '-';

    # check num for valid values (also NaN if there was no inverse but $exp &lt; 0)
    return $num-&gt;bnan(@r) if $num-&gt;{sign} !~ /^[+-]$/;

    # $mod is positive, sign on $exp is ignored, result also positive

    # XXX TODO: speed it up when all three numbers are integers
    $num = $num-&gt;bpow($exp)-&gt;bmod($mod);

    return $downgrade -&gt; new($num -&gt; bdstr(), @r) if defined($downgrade)
      &amp;&amp; ($num-&gt;is_int() || $num-&gt;is_inf() || $num-&gt;is_nan());
    return $num -&gt; round(@r);
}

sub bpow {
    # (BFLOAT or num_str, BFLOAT or num_str) return BFLOAT
    # compute power of two numbers, second arg is used as integer
    # modifies first argument

    # set up parameters
    my ($class, $x, $y, $a, $p, $r) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, $a, $p, $r) = objectify(2, @_);
    }

    return $x if $x -&gt; modify('bpow');

    # $x and/or $y is a NaN
    return $x -&gt; bnan() if $x -&gt; is_nan() || $y -&gt; is_nan();

    # $x and/or $y is a +/-Inf
    if ($x -&gt; is_inf("-")) {
        return $x -&gt; bzero()   if $y -&gt; is_negative();
        return $x -&gt; bnan()    if $y -&gt; is_zero();
        return $x            if $y -&gt; is_odd();
        return $x -&gt; bneg();
    } elsif ($x -&gt; is_inf("+")) {
        return $x -&gt; bzero()   if $y -&gt; is_negative();
        return $x -&gt; bnan()    if $y -&gt; is_zero();
        return $x;
    } elsif ($y -&gt; is_inf("-")) {
        return $x -&gt; bnan()    if $x -&gt; is_one("-");
        return $x -&gt; binf("+") if $x &gt; -1 &amp;&amp; $x &lt; 1;
        return $x -&gt; bone()    if $x -&gt; is_one("+");
        return $x -&gt; bzero();
    } elsif ($y -&gt; is_inf("+")) {
        return $x -&gt; bnan()    if $x -&gt; is_one("-");
        return $x -&gt; bzero()   if $x &gt; -1 &amp;&amp; $x &lt; 1;
        return $x -&gt; bone()    if $x -&gt; is_one("+");
        return $x -&gt; binf("+");
    }

    if ($x -&gt; is_zero()) {
        return $x -&gt; bone() if $y -&gt; is_zero();
        return $x -&gt; binf() if $y -&gt; is_negative();
        return $x;
    }

    # We don't support complex numbers, so upgrade or return NaN.

    if ($x -&gt; is_negative() &amp;&amp; !$y -&gt; is_int()) {
        return $upgrade -&gt; bpow($x, $y, $a, $p, $r) if defined $upgrade;
        return $x -&gt; bnan();
    }

    if ($x -&gt; is_one("+") || $y -&gt; is_one()) {
        return $x;
    }

    if ($x -&gt; is_one("-")) {
        return $x if $y -&gt; is_odd();
        return $x -&gt; bneg();
    }

    return $x -&gt; _pow($y, $a, $p, $r) if !$y -&gt; is_int();

    my $y1 = $y -&gt; as_int()-&gt;{value}; # make MBI part

    my $new_sign = '+';
    $new_sign = $LIB -&gt; _is_odd($y1) ? '-' : '+' if $x-&gt;{sign} ne '+';

    # calculate $x-&gt;{_m} ** $y and $x-&gt;{_e} * $y separately (faster)
    $x-&gt;{_m} = $LIB -&gt; _pow($x-&gt;{_m}, $y1);
    $x-&gt;{_e} = $LIB -&gt; _mul($x-&gt;{_e}, $y1);

    $x-&gt;{sign} = $new_sign;
    $x = $x -&gt; bnorm();

    # x ** (-y) = 1 / (x ** y)

    if ($y-&gt;{sign} eq '-') {
        # modify $x in place!
        my $z = $x -&gt; copy();
        $x = $x -&gt; bone();
        # round in one go (might ignore y's A!)
        return scalar $x -&gt; bdiv($z, $a, $p, $r);
    }

    $x = $x -&gt; round($a, $p, $r, $y);

    return $downgrade -&gt; new($x)
      if defined($downgrade) &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
    return $x;
}

sub binv {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('binv');

    my $inv = $class -&gt; bdiv($class -&gt; bone(), $x, @r);

    return $downgrade -&gt; new($inv, @r) if defined($downgrade)
      &amp;&amp; ($inv -&gt; is_int() || $inv -&gt; is_inf() || $inv -&gt; is_nan());

    for my $key (qw/ sign _m _es _e /) {
        $x -&gt; {$key} = $inv -&gt; {$key};
    }

    $x;
}

sub blog {
    # Return the logarithm of the operand. If a second operand is defined, that
    # value is used as the base, otherwise the base is assumed to be Euler's
    # constant.

    my ($class, $x, $base, @r);

    # Only objectify the base if it is defined, since an undefined base, as in
    # $x-&gt;blog() or $x-&gt;blog(undef) signals that the base is Euler's number =
    # 2.718281828...

    if (!ref($_[0]) &amp;&amp; $_[0] =~ /^[A-Za-z]|::/) {
        # E.g., Math::BigFloat-&gt;blog(256, 2)
        ($class, $x, $base, @r) =
          defined $_[2] ? objectify(2, @_) : objectify(1, @_);
    } else {
        # E.g., $x-&gt;blog(2) or the deprecated Math::BigFloat::blog(256, 2)
        ($class, $x, $base, @r) =
          defined $_[1] ? objectify(2, @_) : objectify(1, @_);
    }

    return $x if $x-&gt;modify('blog');

    # Handle all exception cases and all trivial cases. I have used Wolfram
    # Alpha (http://www.wolframalpha.com) as the reference for these cases.

    return $x -&gt; bnan(@r) if $x -&gt; is_nan();

    if (defined $base) {
        $base = $class -&gt; new($base)
          unless defined(blessed($base)) &amp;&amp; $base -&gt; isa(__PACKAGE__);
        if ($base -&gt; is_nan() || $base -&gt; is_one()) {
            return $x -&gt; bnan(@r);
        } elsif ($base -&gt; is_inf() || $base -&gt; is_zero()) {
            return $x -&gt; bnan(@r) if $x -&gt; is_inf() || $x -&gt; is_zero();
            return $x -&gt; bzero(@r);
        } elsif ($base -&gt; is_negative()) {              # -inf &lt; base &lt; 0
            return $x -&gt; bzero(@r) if $x -&gt; is_one();   #     x = 1
            return $x -&gt; bone('+', @r)  if $x == $base; #     x = base
            # we can't handle these cases, so upgrade, if we can
            return $upgrade -&gt; blog($x, $base, @r) if defined $upgrade;
            return $x -&gt; bnan(@r);
        }
        return $x -&gt; bone(@r) if $x == $base;       # 0 &lt; base &amp;&amp; 0 &lt; x &lt; inf
    }

    if ($x -&gt; is_inf()) {                       # x = +/-inf
        my $sign = defined($base) &amp;&amp; $base &lt; 1 ? '-' : '+';
        return $x -&gt; binf($sign, @r);
    } elsif ($x -&gt; is_neg()) {                  # -inf &lt; x &lt; 0
        return $upgrade -&gt; blog($x, $base, @r) if defined $upgrade;
        return $x -&gt; bnan(@r);
    } elsif ($x -&gt; is_one()) {                  # x = 1
        return $x -&gt; bzero(@r);
    } elsif ($x -&gt; is_zero()) {                 # x = 0
        my $sign = defined($base) &amp;&amp; $base &lt; 1 ? '+' : '-';
        return $x -&gt; binf($sign, @r);
    }

    # we need to limit the accuracy to protect against overflow
    my $fallback = 0;
    my ($scale, @params);
    ($x, @params) = $x-&gt;_find_round_parameters(@r);

    # no rounding at all, so must use fallback
    if (scalar @params == 0) {
        # simulate old behaviour
        $params[0] = $class-&gt;div_scale(); # and round to it as accuracy
        $params[1] = undef;               # P = undef
        $scale = $params[0]+4;            # at least four more for proper round
        $params[2] = $r[2];               # round mode by caller or undef
        $fallback = 1;                    # to clear a/p afterwards
    } else {
        # the 4 below is empirical, and there might be cases where it is not
        # enough...
        $scale = abs($params[0] || $params[1]) + 4; # take whatever is defined
    }

    # When user set globals, they would interfere with our calculation, so
    # disable them and later re-enable them.

    my $ab = $class -&gt; accuracy();
    my $pb = $class -&gt; precision();
    $class -&gt; accuracy(undef);
    $class -&gt; precision(undef);

    # Disabling upgrading and downgrading is no longer necessary to avoid an
    # infinite recursion, but it avoids unnecessary upgrading and downgrading in
    # the intermediate computations.

    my $upg = $class -&gt; upgrade();
    my $dng = $class -&gt; downgrade();
    $class -&gt; upgrade(undef);
    $class -&gt; downgrade(undef);

    # We also need to disable any set A or P on $x (_find_round_parameters took
    # them already into account), since these would interfere, too.

    $x-&gt;{accuracy} = undef;
    $x-&gt;{precision} = undef;

    my $done = 0;

    # If both $x and $base are integers, try to calculate an integer result
    # first. This is very fast, and if the exact result was found, we are done.

    if (defined($base) &amp;&amp; $base -&gt; is_int() &amp;&amp; $x -&gt; is_int()) {
        my $x_lib = $LIB -&gt; _new($x -&gt; bdstr());
        my $b_lib = $LIB -&gt; _new($base -&gt; bdstr());
        ($x_lib, my $exact) = $LIB -&gt; _log_int($x_lib, $b_lib);
        if ($exact) {
            $x-&gt;{_m} = $x_lib;
            $x-&gt;{_e} = $LIB -&gt; _zero();
            $x = $x -&gt; bnorm();
            $done = 1;
        }
    }

    # If the integer result was not accurate, compute the natural logarithm
    # log($x) (using reduction by 10 and possibly also by 2), and if a
    # different base was requested, convert the result with log($x)/log($base).

    unless ($done) {
        $x = $x -&gt; _log_10($scale);
        if (defined $base) {
            # log_b(x) = ln(x) / ln(b), so compute ln(b)
            my $base_log_e = $base -&gt; copy() -&gt; _log_10($scale);
            $x = $x -&gt; bdiv($base_log_e, $scale);
        }
    }

    # shortcut to not run through _find_round_parameters again

    if (defined $params[0]) {
        $x = $x -&gt; bround($params[0], $params[2]); # then round accordingly
    } else {
        $x = $x -&gt; bfround($params[1], $params[2]); # then round accordingly
    }
    if ($fallback) {
        # clear a/p after round, since user did not request it
        $x-&gt;{accuracy} = undef;
        $x-&gt;{precision} = undef;
    }

    # Restore globals. We need to do it like this, because setting one
    # undefines the other.

    if (defined $ab) {
        $class -&gt; accuracy($ab);
    } else {
        $class -&gt; precision($pb);
    }

    $class -&gt; upgrade($upg);
    $class -&gt; downgrade($dng);

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; $x -&gt; is_int();
    return $x;
}

sub bexp {
    # Calculate e ** X (Euler's number to the power of X)
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x -&gt; modify('bexp');

    return $x -&gt; bnan(@r)  if $x -&gt; is_nan();
    return $x -&gt; binf(@r)  if $x-&gt;{sign} eq '+inf';
    return $x -&gt; bzero(@r) if $x-&gt;{sign} eq '-inf';

    # Get the rounding parameters, if any.

    my $fallback = 0;
    my ($scale, @params);
    ($x, @params) = $x -&gt; _find_round_parameters(@r);

    # Error in _find_round_parameters?

    return $x -&gt; bnan(@r) if $x-&gt;{sign} eq 'NaN';

    return $x -&gt; bone(@r) if $x -&gt; is_zero();

    # If no rounding parameters are give, use fallback.

    if (!@params) {
        $params[0] = $class -&gt; div_scale();     # fallback accuracy
        $params[1] = undef;                     # no precision
        $params[2] = $r[2];                     # rounding mode
        $scale = $params[0];
        $fallback = 1;                          # to clear a/p afterwards
    } else {
        if (defined($params[0])) {
            $scale = $params[0];
        } else {
            # We perform the computations below using accuracy only, not
            # precision, so when precision is given, we need to "convert" this
            # to accuracy. To do that, we need to know, at least approximately,
            # how many digits there will be in the final result.
            #
            #   log10(exp($x)) = log(exp($x)) / log(10) = $x / log(10)

            #$scale = 1 + int(log($ms) / log(10) + $es) - $params[1];
            my $ndig = $x -&gt; numify() / log(10);
            $scale = 1 + int($ndig) - $params[1];
        }
    }

    # Add extra digits to reduce the consequence of round-off errors in the
    # intermediate computations.

    $scale += 4;

    if (!$x -&gt; isa('Math::BigFloat')) {
        $x = Math::BigFloat -&gt; new($x);
        $class = ref($x);
    }

    # When user set globals, they would interfere with our calculation, so
    # disable them and later re-enable them.

    my $ab = $class -&gt; accuracy();
    my $pb = $class -&gt; precision();
    $class -&gt; accuracy(undef);
    $class -&gt; precision(undef);

    # Disabling upgrading and downgrading is no longer necessary to avoid an
    # infinite recursion, but it avoids unnecessary upgrading and downgrading in
    # the intermediate computations.

    my $upg = $class -&gt; upgrade();
    my $dng = $class -&gt; downgrade();
    $class -&gt; upgrade(undef);
    $class -&gt; downgrade(undef);

    # We also need to disable any set A or P on $x (_find_round_parameters took
    # them already into account), since these would interfere, too.

    $x-&gt;{accuracy} = undef;
    $x-&gt;{precision} = undef;

    my $x_orig = $x -&gt; copy();

    # We use the following Taylor series:

    #           x    x^2   x^3   x^4
    #  e = 1 + --- + --- + --- + --- ...
    #           1!    2!    3!    4!

    # The difference for each term is X and N, which would result in:
    # 2 copy, 2 mul, 2 add, 1 inc, 1 div operations per term

    # But it is faster to compute exp(1) and then raising it to the
    # given power, esp. if $x is really big and an integer because:

    #  * The numerator is always 1, making the computation faster
    #  * the series converges faster in the case of x == 1
    #  * We can also easily check when we have reached our limit: when the
    #    term to be added is smaller than "1E$scale", we can stop - f.i.
    #    scale == 5, and we have 1/40320, then we stop since 1/40320 &lt; 1E-5.
    #  * we can compute the *exact* result by simulating bigrat math:

    #  1   1    gcd(3, 4) = 1    1*24 + 1*6    5
    #  - + -                  = ---------- =  --
    #  6   24                      6*24       24

    # We do not compute the gcd() here, but simple do:
    #  1   1    1*24 + 1*6   30
    #  - + -  = --------- =  --
    #  6   24       6*24     144

    # In general:
    #  a   c    a*d + c*b         and note that c is always 1 and d = (b*f)
    #  - + -  = ---------
    #  b   d       b*d

    # This leads to:         which can be reduced by b to:
    #  a   1     a*b*f + b    a*f + 1
    #  - + -   = --------- =  -------
    #  b   b*f     b*b*f        b*f

    # The first terms in the series are:

    # 1     1    1    1    1    1     1     1     13700
    # -- + -- + -- + -- + -- + --- + --- + ---- = -----
    # 1     1    2    6   24   120   720   5040   5040

    # Note that we cannot simply reduce 13700/5040 to 685/252, but must keep
    # the numerator and the denominator!

    if ($scale &lt;= 75) {
        # set $x directly from a cached string form
        $x-&gt;{_m} = $LIB-&gt;_new("2718281828459045235360287471352662497757" .
                              "2470936999595749669676277240766303535476");
        $x-&gt;{sign} = '+';
        $x-&gt;{_es} = '-';
        $x-&gt;{_e} = $LIB-&gt;_new(79);
    } else {
        # compute A and B so that e = A / B.

        # After some terms we end up with this, so we use it as a starting
        # point:
        my $A = $LIB-&gt;_new("9093339520860578540197197" .
                           "0164779391644753259799242");
        my $F = $LIB-&gt;_new(42);
        my $step = 42;

        # Compute number of steps needed to get $A and $B sufficiently large.

        my $steps = _len_to_steps($scale - 4);
        #    print STDERR "# Doing $steps steps for ", $scale-4, " digits\n";

        while ($step++ &lt;= $steps) {
            # calculate $a * $f + 1
            $A = $LIB -&gt; _mul($A, $F);
            $A = $LIB -&gt; _inc($A);
            # increment f
            $F = $LIB -&gt; _inc($F);
        }

        # Compute $B as factorial of $steps (this is faster than doing it
        # manually)
        my $B = $LIB-&gt;_fac($LIB-&gt;_new($steps));

        #  print "A ", $LIB-&gt;_str($A), "\nB ", $LIB-&gt;_str($B), "\n";

        # compute A/B with $scale digits in the result (truncate, not round)
        $A = $LIB-&gt;_lsft($A, $LIB-&gt;_new($scale), 10);
        $A = $LIB-&gt;_div($A, $B);

        $x-&gt;{_m} = $A;
        $x-&gt;{sign} = '+';
        $x-&gt;{_es} = '-';
        $x-&gt;{_e} = $LIB-&gt;_new($scale);
    }

    # Now $x contains now an estimate of e, with some additional digits.

    if ($x_orig -&gt; is_one()) {

        # else just round the already computed result

        $x-&gt;{accuracy} = undef;
        $x-&gt;{precision} = undef;

        # shortcut to not run through _find_round_parameters again

        if (defined $params[0]) {
            $x = $x -&gt; bround($params[0], $params[2]); # then round accordingly
        } else {
            $x = $x -&gt; bfround($params[1], $params[2]); # then round accordingly
        }

    } else {

        # Use the fact exp(x) = exp(x/n)**n. In our case, n = 2**i for some
        # integer i. We use this to compute exp(y) where y = x / (2**i) and
        # 1 &lt;= |y| &lt; 2.
        #
        # The code below is similar to the code found in to_ieee754().

        # We need to find the base 2 exponent. First make an estimate of the
        # base 2 exponent, before adjusting it below. We could skip this
        # estimation and go straight to the while-loops below, but the loops
        # are slow, especially when the final exponent is far from zero and
        # even more so if the number of digits is large. This initial
        # estimation speeds up the computation dramatically.
        #
        #   log2($m * 10**$e) = log10($m + 10**$e) * log(10)/log(2)
        #                     = (log10($m) + $e) * log(10)/log(2)
        #                     = (log($m)/log(10) + $e) * log(10)/log(2)

        my ($m, $e) = $x_orig -&gt; nparts();
        my $ms = $m -&gt; numify();
        my $es = $e -&gt; numify();

        # We start off by initializing the exponent to zero and the mantissa to
        # the input value. Then we increase the mantissa and decrease the
        # exponent, or vice versa, until the mantissa is in the desired range
        # or we hit one of the limits for the exponent.

        my $mant = $x_orig -&gt; copy() -&gt; babs();
        my $expo;

        my $one  = $class -&gt; bone();
        my $two  = $class -&gt; new("2");
        my $half = $class -&gt; new("0.5");

        my $expo_est = (log(abs($ms))/log(10) + $es) * log(10)/log(2);
        $expo_est = int($expo_est);

        # Don't multiply by a number raised to a negative exponent. This will
        # cause a division, whose result is truncated to some fixed number of
        # digits. Instead, multiply by the inverse number raised to a positive
        # exponent.

        $expo = $class -&gt; new($expo_est);
        if ($expo_est &gt; 0) {
            $mant = $mant -&gt; bmul($half -&gt; copy() -&gt; bpow($expo));
        } elsif ($expo_est &lt; 0) {
            my $expo_abs = $expo -&gt; copy() -&gt; bneg();
            $mant = $mant -&gt; bmul($two -&gt; copy() -&gt; bpow($expo_abs));
        }

        # Final adjustment of the estimate above.

        while ($mant -&gt; bcmp($two) &gt;= 0) {      # $mant &lt;= $two
            $mant = $mant -&gt; bmul($half);
            $expo = $expo -&gt; binc();
        }

        while ($mant -&gt; bcmp($one) &lt; 0) {       # $mant &gt; $one
            $mant = $mant -&gt; bmul($two);
            $expo = $expo -&gt; bdec();
        }

        # Because of the upscaling, we need some additional digits.

        my $rescale = int($scale + abs($expo) * log(2) / log(10) + 1);
        $rescale = 4 if $rescale &lt; 4;

        $x = $x -&gt; bpow($mant, $rescale);
        my $pow2 = $two -&gt; bpow($expo, $rescale);
        $pow2 -&gt; bneg() if $x_orig -&gt; is_negative();

        # The bpow() below fails with the GMP and GMPz libraries if abs($pow2)
        # &gt;= 2**30 = 1073741824. With the Pari library, it fails already when
        # abs($pow) &gt;= 2**13 = 8192. With the Calc library, it is rediculously
        # slow when abs($pow2) is large. Fixme?

        croak "cannot compute bexp(); input value is too large"
          if $pow2 -&gt; copy() -&gt; babs() -&gt; bcmp("1073741824") &gt;= 0;

        $x = $x -&gt; bpow($pow2, $rescale);

        # Rounding parameters given as arguments currently don't override
        # instance variables, so accuracy (which is set in the computations
        # above) must be undefined before rounding. Fixme.

        $x-&gt;{accuracy} = undef;
        $x -&gt; round(@params);
    }

    if ($fallback) {
        # clear a/p after round, since user did not request it
        $x-&gt;{accuracy} = undef;
        $x-&gt;{precision} = undef;
    }

    # Restore globals. We need to do it like this, because setting one
    # undefines the other.

    if (defined $ab) {
        $class -&gt; accuracy($ab);
    } else {
        $class -&gt; precision($pb);
    }

    $class -&gt; upgrade($upg);
    $class -&gt; downgrade($dng);

    # If downgrading, remember to preserve the relevant instance parameters.
    # There should be a more elegant way to do this. Fixme.

    if ($downgrade &amp;&amp; $x -&gt; is_int()) {
        @r = ($x-&gt;{accuracy}, $x-&gt;{_r});
        my $tmp = $downgrade -&gt; new($x, @r);
        %$x = %$tmp;
        return bless $x, $downgrade;
    }

    $x;
}

sub bilog2 {
    croak "Method ", (caller(0))[3], "() not implemented yet";
}

sub bilog10 {
    croak "Method ", (caller(0))[3], "() not implemented yet";
}

sub bclog2 {
    croak "Method ", (caller(0))[3], "() not implemented yet";
}

sub bclog10 {
    croak "Method ", (caller(0))[3], "() not implemented yet";
}

sub bnok {
    # Calculate n over k (binomial coefficient or "choose" function) as integer.
    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x if $x-&gt;modify('bnok');

    return $x-&gt;bnan() if $x-&gt;is_nan() || $y-&gt;is_nan();
    return $x-&gt;bnan() if (($x-&gt;is_finite() &amp;&amp; !$x-&gt;is_int()) ||
                          ($y-&gt;is_finite() &amp;&amp; !$y-&gt;is_int()));

    my $xint = Math::BigInt -&gt; new($x -&gt; bsstr());
    my $yint = Math::BigInt -&gt; new($y -&gt; bsstr());
    $xint = $xint -&gt; bnok($yint);

    return $xint if defined $downgrade;

    my $xflt = Math::BigFloat -&gt; new($xint);

    $x-&gt;{_m}   = $xflt-&gt;{_m};
    $x-&gt;{_e}   = $xflt-&gt;{_e};
    $x-&gt;{_es}  = $xflt-&gt;{_es};
    $x-&gt;{sign} = $xflt-&gt;{sign};

    return $x;
}

sub bsin {
    # Calculate a sinus of x.
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    # First we apply range reduction to x. This is because if x is large, the
    # Taylor series converges slowly and requires higher accuracy in the
    # intermediate computation. The Taylor series is:
    #
    #                 x^3   x^5   x^7   x^9
    #    sin(x) = x - --- + --- - --- + --- ...
    #                  3!    5!    7!    9!

    return $x if $x -&gt; modify('bsin');

    return $x -&gt; bzero(@r) if $x -&gt; is_zero();
    return $x -&gt; bnan(@r)  if $x -&gt; is_nan() || $x -&gt; is_inf();

    # Get the rounding parameters, if any.

    my $fallback = 0;
    my ($scale, @params);
    ($x, @params) = $x -&gt; _find_round_parameters(@r);

    # Error in _find_round_parameters?

    return $x -&gt; bnan(@r) if $x -&gt; is_nan();

    # If no rounding parameters are given, use fallback.

    if (!@params) {
        $params[0] = $class -&gt; div_scale();     # fallback accuracy
        $params[1] = undef;                     # no precision
        $params[2] = $r[2];                     # rounding mode
        $scale = $params[0];
        $fallback = 1;                          # to clear a/p afterwards
    } else {
        if (defined($params[0])) {
            $scale = $params[0];
        } else {
            # We perform the computations below using accuracy only, not
            # precision, so when precision is given, we need to "convert" this
            # to accuracy.
            $scale = 1 - $params[1];
        }
    }

    # Add more digits to the scale if the magnitude of $x is large.

    my ($m, $e) = $x -&gt; nparts();
    $scale += $e if $x &gt;= 10;
    $scale = 4 if $scale &lt; 4;

    # When user set globals, they would interfere with our calculation, so
    # disable them and later re-enable them

    my $ab = $class -&gt; accuracy();
    my $pb = $class -&gt; precision();
    $class -&gt; accuracy(undef);
    $class -&gt; precision(undef);

    # Disabling upgrading and downgrading is no longer necessary to avoid an
    # infinite recursion, but it avoids unnecessary upgrading and downgrading in
    # the intermediate computations.

    my $upg = $class -&gt; upgrade();
    my $dng = $class -&gt; downgrade();
    $class -&gt; upgrade(undef);
    $class -&gt; downgrade(undef);

    # We also need to disable any set A or P on $x (_find_round_parameters took
    # them already into account), since these would interfere, too.

    $x-&gt;{accuracy} = undef;
    $x-&gt;{precision} = undef;

    my $sin_prev;       # the previous approximation of sin(x)
    my $sin;            # the current approximation of sin(x)

    while (1) {

        # Compute constants to the current scale.

        my $pi     = $class -&gt; bpi($scale);         # ðœ‹
        my $twopi  = $pi -&gt; copy() -&gt; bmul("2");    # 2ðœ‹
        my $halfpi = $pi -&gt; copy() -&gt; bmul("0.5");  # ðœ‹/2

        # Use the fact that sin(-x) = -sin(x) to reduce the range to the
        # interval to [0,âˆž).

        my $xsgn = $x &lt; 0 ? -1 : 1;
        my $x = $x -&gt; copy() -&gt; babs();

        # Use the fact that sin(2ðœ‹x) = sin(x) to reduce the range to the
        # interval to [0, 2ðœ‹).

        $x = $x -&gt; bmod($twopi, $scale);

        # Use the fact that sin(x+ðœ‹) = -sin(x) to reduce the range to the
        # interval to [0,ðœ‹).

        if ($x -&gt; bcmp($pi) &gt; 0) {
            $xsgn = -$xsgn;
            $x = $x -&gt; bsub($pi);
        }

        # Use the fact that sin(ðœ‹-x) = sin(x) to reduce the range to the
        # interval [0,ðœ‹/2).

        if ($x -&gt; bcmp($halfpi) &gt; 0) {
            $x = $x -&gt; bsub($pi) -&gt; bneg();     # ðœ‹ - x
        }

        my $tol = $class -&gt; new("1E-". ($scale-1));

        my $xsq  = $x -&gt; copy() -&gt; bmul($x, $scale) -&gt; bneg();
        my $term = $x -&gt; copy();
        my $fac  = $class -&gt; bone();
        my $n    = $class -&gt; bone();

        $sin = $x -&gt; copy();    # initialize sin(x) to the first term

        while (1) {
            $n -&gt; binc();
            $fac = $n -&gt; copy();
            $n -&gt; binc();
            $fac -&gt; bmul($n);

            $term -&gt; bmul($xsq, $scale) -&gt; bdiv($fac, $scale);

            $sin -&gt; badd($term, $scale);
            last if $term -&gt; copy() -&gt; babs() -&gt; bcmp($tol) &lt; 0;
        }

        $sin -&gt; bneg() if $xsgn &lt; 0;

        # Rounding parameters given as arguments currently don't override
        # instance variables, so accuracy (which is set in the computations
        # above) must be undefined before rounding. Fixme.

        $sin-&gt;{accuracy} = undef;
        $sin -&gt; round(@params);

        # Compare the current approximation of sin(x) with the previous one,
        # and if they are identical, we're done.

        if (defined $sin_prev) {
            last if $sin -&gt; bcmp($sin_prev) == 0;
        }

        # If the current approximation of sin(x) is different from the previous
        # approximation, double the scale (accuracy) and retry.

        $sin_prev = $sin;
        $scale *= 2;
    }

    # Assign the result to the invocand.

    %$x = %$sin;

    if ($fallback) {
        # clear a/p after round, since user did not request it
        $x-&gt;{accuracy} = undef;
        $x-&gt;{precision} = undef;
    }

    # Restore globals. We need to do it like this, because setting one
    # undefines the other.

    if (defined $ab) {
        $class -&gt; accuracy($ab);
    } else {
        $class -&gt; precision($pb);
    }

    $class -&gt; upgrade($upg);
    $class -&gt; downgrade($dng);

    # If downgrading, remember to preserve the relevant instance parameters.
    # There should be a more elegant way to do this. Fixme.

    if ($downgrade &amp;&amp; $x -&gt; is_int()) {
        @r = ($x-&gt;{accuracy}, $x-&gt;{_r});
        my $tmp = $downgrade -&gt; new($x, @r);
        %$x = %$tmp;
        return bless $x, $downgrade;
    }

    $x;
}

sub bcos {
    # Calculate a cosinus of x.
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    # Taylor:      x^2   x^4   x^6   x^8
    #    cos = 1 - --- + --- - --- + --- ...
    #               2!    4!    6!    8!

    # we need to limit the accuracy to protect against overflow
    my $fallback = 0;
    my ($scale, @params);
    ($x, @params) = $x-&gt;_find_round_parameters(@r);

    #         constant object       or error in _find_round_parameters?
    return $x if $x-&gt;modify('bcos') || $x-&gt;is_nan();
    return $x-&gt;bnan()   if $x-&gt;is_inf();
    return $x-&gt;bone(@r) if $x-&gt;is_zero();

    # no rounding at all, so must use fallback
    if (scalar @params == 0) {
        # simulate old behaviour
        $params[0] = $class-&gt;div_scale(); # and round to it as accuracy
        $params[1] = undef;               # disable P
        $scale = $params[0]+4;            # at least four more for proper round
        $params[2] = $r[2];               # round mode by caller or undef
        $fallback = 1;                    # to clear a/p afterwards
    } else {
        # the 4 below is empirical, and there might be cases where it is not
        # enough...
        $scale = abs($params[0] || $params[1]) + 4; # take whatever is defined
    }

    # When user set globals, they would interfere with our calculation, so
    # disable them and later re-enable them.

    my $ab = $class -&gt; accuracy();
    my $pb = $class -&gt; precision();
    $class -&gt; accuracy(undef);
    $class -&gt; precision(undef);

    # Disabling upgrading and downgrading is no longer necessary to avoid an
    # infinite recursion, but it avoids unnecessary upgrading and downgrading in
    # the intermediate computations.

    my $upg = $class -&gt; upgrade();
    my $dng = $class -&gt; downgrade();
    $class -&gt; upgrade(undef);
    $class -&gt; downgrade(undef);

    # We also need to disable any set A or P on $x (_find_round_parameters took
    # them already into account), since these would interfere, too.

    $x-&gt;{accuracy} = undef;
    $x-&gt;{precision} = undef;

    my $over = $x * $x;         # X ^ 2
    my $x2 = $over-&gt;copy();     # X ^ 2; difference between terms
    my $sign = 1;               # start with -=
    my $below = $class-&gt;new(2);
    my $factorial = $class-&gt;new(3);
    $x = $x-&gt;bone();
    $x-&gt;{accuracy} = undef;
    $x-&gt;{precision} = undef;

    my $limit = $class-&gt;new("1E-". ($scale-1));
    #my $steps = 0;
    while (3 &lt; 5) {
        # we calculate the next term, and add it to the last
        # when the next term is below our limit, it won't affect the outcome
        # anymore, so we stop:
        my $next = $over-&gt;copy()-&gt;bdiv($below, $scale);
        last if $next-&gt;bacmp($limit) &lt;= 0;

        if ($sign == 0) {
            $x = $x-&gt;badd($next);
        } else {
            $x = $x-&gt;bsub($next);
        }
        $sign = 1-$sign;        # alternate
        # calculate things for the next term
        $over = $over-&gt;bmul($x2);                       # $x*$x
        $below = $below-&gt;bmul($factorial);              # n*(n+1)
        $factorial = $factorial -&gt; binc();
        $below = $below-&gt;bmul($factorial);              # n*(n+1)
        $factorial = $factorial -&gt; binc();
    }

    # shortcut to not run through _find_round_parameters again
    if (defined $params[0]) {
        $x = $x-&gt;bround($params[0], $params[2]); # then round accordingly
    } else {
        $x = $x-&gt;bfround($params[1], $params[2]); # then round accordingly
    }
    if ($fallback) {
        # clear a/p after round, since user did not request it
        $x-&gt;{accuracy} = undef;
        $x-&gt;{precision} = undef;
    }

    # Restore globals. We need to do it like this, because setting one
    # undefines the other.

    if (defined $ab) {
        $class -&gt; accuracy($ab);
    } else {
        $class -&gt; precision($pb);
    }

    $class -&gt; upgrade($upg);
    $class -&gt; downgrade($dng);

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; $x -&gt; is_int();
    $x;
}

sub batan {
    # Calculate a arcus tangens of x.
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    # taylor:       x^3   x^5   x^7   x^9
    #    atan = x - --- + --- - --- + --- ...
    #                3     5     7     9

    return $x if $x-&gt;modify('batan');

    return $x -&gt; bnan(@r) if $x-&gt;is_nan();

    # We need to limit the accuracy to protect against overflow.

    my $fallback = 0;
    my ($scale, @params);
    ($x, @params) = $x-&gt;_find_round_parameters(@r);

    # Error in _find_round_parameters?

    return $x -&gt; bnan(@r) if $x-&gt;is_nan();

    if ($x-&gt;{sign} =~ /^[+-]inf\z/) {
        # +inf result is PI/2
        # -inf result is -PI/2
        # calculate PI/2
        my $pi = $class-&gt;bpi(@r);
        # modify $x in place
        $x-&gt;{_m} = $pi-&gt;{_m};
        $x-&gt;{_e} = $pi-&gt;{_e};
        $x-&gt;{_es} = $pi-&gt;{_es};
        # -y =&gt; -PI/2, +y =&gt; PI/2
        $x-&gt;{sign} = substr($x-&gt;{sign}, 0, 1); # "+inf" =&gt; "+"
        $x -&gt; {_m} = $LIB-&gt;_div($x-&gt;{_m}, $LIB-&gt;_new(2));
        return $x;
    }

    return $x-&gt;bzero(@r) if $x-&gt;is_zero();

    # no rounding at all, so must use fallback
    if (scalar @params == 0) {
        # simulate old behaviour
        $params[0] = $class-&gt;div_scale(); # and round to it as accuracy
        $params[1] = undef;               # disable P
        $scale = $params[0]+4;            # at least four more for proper round
        $params[2] = $r[2];               # round mode by caller or undef
        $fallback = 1;                    # to clear a/p afterwards
    } else {
        # the 4 below is empirical, and there might be cases where it is not
        # enough...
        $scale = abs($params[0] || $params[1]) + 4; # take whatever is defined
    }

    # 1 or -1 =&gt; PI/4
    # inlined is_one() &amp;&amp; is_one('-')
    if ($LIB-&gt;_is_one($x-&gt;{_m}) &amp;&amp; $LIB-&gt;_is_zero($x-&gt;{_e})) {
        my $pi = $class-&gt;bpi($scale - 3);
        # modify $x in place
        $x-&gt;{_m} = $pi-&gt;{_m};
        $x-&gt;{_e} = $pi-&gt;{_e};
        $x-&gt;{_es} = $pi-&gt;{_es};
        # leave the sign of $x alone (+1 =&gt; +PI/4, -1 =&gt; -PI/4)
        $x-&gt;{_m} = $LIB-&gt;_div($x-&gt;{_m}, $LIB-&gt;_new(4));
        return $x;
    }

    # This series is only valid if -1 &lt; x &lt; 1, so for other x we need to
    # calculate PI/2 - atan(1/x):
    my $pi = undef;
    if ($x-&gt;bacmp($x-&gt;copy()-&gt;bone) &gt;= 0) {
        # calculate PI/2
        $pi = $class-&gt;bpi($scale - 3);
        $pi-&gt;{_m} = $LIB-&gt;_div($pi-&gt;{_m}, $LIB-&gt;_new(2));
        # calculate 1/$x:
        my $x_copy = $x-&gt;copy();
        # modify $x in place
        $x = $x-&gt;bone();
        $x = $x-&gt;bdiv($x_copy, $scale);
    }

    my $fmul = 1;
    foreach (0 .. int($scale / 20)) {
        $fmul *= 2;
        $x = $x-&gt;bdiv($x-&gt;copy()-&gt;bmul($x)-&gt;binc()-&gt;bsqrt($scale + 4)-&gt;binc(),
                      $scale + 4);
    }

    # When user set globals, they would interfere with our calculation, so
    # disable them and later re-enable them.

    my $ab = $class -&gt; accuracy();
    my $pb = $class -&gt; precision();
    $class -&gt; accuracy(undef);
    $class -&gt; precision(undef);

    # Disabling upgrading and downgrading is no longer necessary to avoid an
    # infinite recursion, but it avoids unnecessary upgrading and downgrading in
    # the intermediate computations.

    my $upg = $class -&gt; upgrade();
    my $dng = $class -&gt; downgrade();
    $class -&gt; upgrade(undef);
    $class -&gt; downgrade(undef);

    # We also need to disable any set A or P on $x (_find_round_parameters took
    # them already into account), since these would interfere, too.

    $x-&gt;{accuracy} = undef;
    $x-&gt;{precision} = undef;

    my $over = $x * $x;   # X ^ 2
    my $x2 = $over-&gt;copy();  # X ^ 2; difference between terms
    $over = $over-&gt;bmul($x);         # X ^ 3 as starting value
    my $sign = 1;               # start with -=
    my $below = $class-&gt;new(3);
    my $two = $class-&gt;new(2);
    $x-&gt;{accuracy} = undef;
    $x-&gt;{precision} = undef;

    my $limit = $class-&gt;new("1E-". ($scale-1));
    #my $steps = 0;
    while (1) {
        # We calculate the next term, and add it to the last. When the next
        # term is below our limit, it won't affect the outcome anymore, so we
        # stop:
        my $next = $over-&gt;copy()-&gt;bdiv($below, $scale);
        last if $next-&gt;bacmp($limit) &lt;= 0;

        if ($sign == 0) {
            $x = $x-&gt;badd($next);
        } else {
            $x = $x-&gt;bsub($next);
        }
        $sign = 1-$sign;        # alternatex
        # calculate things for the next term
        $over = $over-&gt;bmul($x2);    # $x*$x
        $below = $below-&gt;badd($two);     # n += 2
    }
    $x = $x-&gt;bmul($fmul);

    if (defined $pi) {
        my $x_copy = $x-&gt;copy();
        # modify $x in place
        $x-&gt;{_m} = $pi-&gt;{_m};
        $x-&gt;{_e} = $pi-&gt;{_e};
        $x-&gt;{_es} = $pi-&gt;{_es};
        # PI/2 - $x
        $x = $x-&gt;bsub($x_copy);
    }

    # Shortcut to not run through _find_round_parameters again.
    if (defined $params[0]) {
        $x = $x-&gt;bround($params[0], $params[2]); # then round accordingly
    } else {
        $x = $x-&gt;bfround($params[1], $params[2]); # then round accordingly
    }
    if ($fallback) {
        # Clear a/p after round, since user did not request it.
        $x-&gt;{accuracy} = undef;
        $x-&gt;{precision} = undef;
    }

    # Restore globals. We need to do it like this, because setting one
    # undefines the other.

    if (defined $ab) {
        $class -&gt; accuracy($ab);
    } else {
        $class -&gt; precision($pb);
    }

    $class -&gt; upgrade($upg);
    $class -&gt; downgrade($dng);

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; ($x -&gt; is_int() || $x -&gt; is_inf());
    $x;
}

sub batan2 {
    # $y -&gt; batan2($x) returns the arcus tangens of $y / $x.

    # Set up parameters.
    my ($class, $y, $x, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    # Quick exit if $y is read-only.
    return $y if $y -&gt; modify('batan2');

    # Handle all NaN cases.
    return $y -&gt; bnan() if $x-&gt;{sign} eq $nan || $y-&gt;{sign} eq $nan;

    # We need to limit the accuracy to protect against overflow.
    my $fallback = 0;
    my ($scale, @params);
    ($y, @params) = $y -&gt; _find_round_parameters(@r);

    # Error in _find_round_parameters?
    return $y if $y-&gt;is_nan();

    # No rounding at all, so must use fallback.
    if (scalar @params == 0) {
        # Simulate old behaviour
        $params[0] = $class -&gt; div_scale(); # and round to it as accuracy
        $params[1] = undef;                 # disable P
        $scale = $params[0] + 4; # at least four more for proper round
        $params[2] = $r[2];      # round mode by caller or undef
        $fallback = 1;           # to clear a/p afterwards
    } else {
        # The 4 below is empirical, and there might be cases where it is not
        # enough ...
        $scale = abs($params[0] || $params[1]) + 4; # take whatever is defined
    }

    if ($x -&gt; is_inf("+")) {                          # x = inf
        if ($y -&gt; is_inf("+")) {                      #    y = inf
            $y = $y -&gt; bpi($scale) -&gt; bmul("0.25");   #       pi/4
        } elsif ($y -&gt; is_inf("-")) {                 #    y = -inf
            $y = $y -&gt; bpi($scale) -&gt; bmul("-0.25");  #       -pi/4
        } else {                                      #    -inf &lt; y &lt; inf
            return $y -&gt; bzero(@r);                   #       0
        }
    } elsif ($x -&gt; is_inf("-")) {                     # x = -inf
        if ($y -&gt; is_inf("+")) {                      #    y = inf
            $y = $y -&gt; bpi($scale) -&gt; bmul("0.75");   #       3/4 pi
        } elsif ($y -&gt; is_inf("-")) {                 #    y = -inf
            $y = $y -&gt; bpi($scale) -&gt; bmul("-0.75");  #       -3/4 pi
        } elsif ($y &gt;= 0) {                           #    y &gt;= 0
            $y = $y -&gt; bpi($scale);                   #       pi
        } else {                                      #    y &lt; 0
            $y = $y -&gt; bpi($scale) -&gt; bneg();         #       -pi
        }
    } elsif ($x &gt; 0) {                                    # 0 &lt; x &lt; inf
        if ($y -&gt; is_inf("+")) {                          #    y = inf
            $y = $y -&gt; bpi($scale) -&gt; bmul("0.5");        #       pi/2
        } elsif ($y -&gt; is_inf("-")) {                     #    y = -inf
            $y = $y -&gt; bpi($scale) -&gt; bmul("-0.5");       #       -pi/2
        } else {                                          #   -inf &lt; y &lt; inf
            $y = $y -&gt; bdiv($x, $scale) -&gt; batan($scale); #       atan(y/x)
        }
    } elsif ($x &lt; 0) {                                # -inf &lt; x &lt; 0
        my $pi = $class -&gt; bpi($scale);
        if ($y &gt;= 0) {                                #    y &gt;= 0
            $y = $y -&gt; bdiv($x, $scale) -&gt; batan()    #       atan(y/x) + pi
               -&gt; badd($pi);
        } else {                                      #    y &lt; 0
            $y = $y -&gt; bdiv($x, $scale) -&gt; batan()    #       atan(y/x) - pi
               -&gt; bsub($pi);
        }
    } else {                                          # x = 0
        if ($y &gt; 0) {                                 #    y &gt; 0
            $y = $y -&gt; bpi($scale) -&gt; bmul("0.5");    #       pi/2
        } elsif ($y &lt; 0) {                            #    y &lt; 0
            $y = $y -&gt; bpi($scale) -&gt; bmul("-0.5");   #       -pi/2
        } else {                                      #    y = 0
            return $y -&gt; bzero(@r);                   #       0
        }
    }

    $y = $y -&gt; round(@r);

    if ($fallback) {
        $y-&gt;{accuracy} = undef;
        $y-&gt;{precision} = undef;
    }

    return $y;
}

sub bsqrt {
    # calculate square root
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bsqrt');

    # Handle trivial cases.

    return $x -&gt; bnan(@r)      if $x-&gt;is_nan();
    return $x -&gt; binf("+", @r) if $x-&gt;{sign} eq '+inf';
    return $x -&gt; round(@r)     if $x-&gt;is_zero() || $x-&gt;is_one();

    # We don't support complex numbers.

    if ($x -&gt; is_neg()) {
        return $upgrade -&gt; bsqrt($x, @r) if defined($upgrade);
        return $x -&gt; bnan(@r);
    }

    # we need to limit the accuracy to protect against overflow
    my $fallback = 0;
    my (@params, $scale);
    ($x, @params) = $x-&gt;_find_round_parameters(@r);

    # error in _find_round_parameters?
    return $x -&gt; bnan(@r) if $x-&gt;is_nan();

    # no rounding at all, so must use fallback
    if (scalar @params == 0) {
        # simulate old behaviour
        $params[0] = $class-&gt;div_scale(); # and round to it as accuracy
        $scale = $params[0]+4;            # at least four more for proper round
        $params[2] = $r[2];               # round mode by caller or undef
        $fallback = 1;                    # to clear a/p afterwards
    } else {
        # the 4 below is empirical, and there might be cases where it is not
        # enough...
        $scale = abs($params[0] || $params[1]) + 4; # take whatever is defined
    }

    # Shift the significand left or right to get the desired number of digits,
    # which is 2*$scale with possibly one extra digit to ensure that the
    # exponent is an even number.

    my $l = $LIB -&gt; _len($x-&gt;{_m});
    my $n = 2 * $scale - $l;                    # how much should we shift?
    $n++ if ($l % 2 xor $LIB -&gt; _is_odd($x-&gt;{_e}));
    my ($na, $ns) = $n &lt; 0 ? (abs($n), "-") : ($n, "+");
    $na = $LIB -&gt; _new($na);

    $x-&gt;{_m} = $ns eq "+" ? $LIB -&gt; _lsft($x-&gt;{_m}, $na, 10)
                          : $LIB -&gt; _rsft($x-&gt;{_m}, $na, 10);

    $x-&gt;{_m} = $LIB -&gt; _sqrt($x-&gt;{_m});

    # Adjust the exponent by the amount that we shifted the significand. The
    # square root of the exponent is simply half of it: sqrt(10^(2*a)) = 10^a.

    ($x-&gt;{_e}, $x-&gt;{_es}) = $LIB -&gt; _ssub($x-&gt;{_e}, $x-&gt;{_es}, $na, $ns);
    $x-&gt;{_e} = $LIB -&gt; _div($x-&gt;{_e}, $LIB -&gt; _new("2"));

    # Normalize to get rid of any trailing zeros in the significand.

    $x -&gt; bnorm();

    # shortcut to not run through _find_round_parameters again
    if (defined $params[0]) {
        $x = $x-&gt;bround($params[0], $params[2]); # then round accordingly
    } else {
        $x = $x-&gt;bfround($params[1], $params[2]); # then round accordingly
    }

    if ($fallback) {
        # clear a/p after round, since user did not request it
        $x-&gt;{accuracy} = undef;
        $x-&gt;{precision} = undef;
    }

    return $downgrade -&gt; new($x, @r)
      if defined($downgrade) &amp;&amp; $x -&gt; is_int();
    $x;
}

sub broot {
    # calculate $y'th root of $x

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x-&gt;modify('broot');

    # Handle trivial cases.

    return $x -&gt; bnan(@r) if $x-&gt;is_nan() || $y-&gt;is_nan();

    if ($x -&gt; is_neg()) {
        # -27 ** (1/3) = -3
        return $x -&gt; broot($y -&gt; copy() -&gt; bneg(), @r) -&gt; bneg()
          if $x -&gt; is_int() &amp;&amp; $y -&gt; is_int() &amp;&amp; $y -&gt; is_neg();
        return $upgrade -&gt; broot($x, $y, @r) if defined $upgrade;
        return $x -&gt; bnan(@r);
    }

    # NaN handling: $x ** 1/0, x or y NaN, or y inf/-inf or y == 0
    return $x-&gt;bnan() if $x-&gt;{sign} !~ /^\+/ || $y-&gt;is_zero() ||
      $y-&gt;{sign} !~ /^\+$/;

    return $x if $x-&gt;is_zero() || $x-&gt;is_one() || $x-&gt;is_inf() || $y-&gt;is_one();

    # we need to limit the accuracy to protect against overflow
    my $fallback = 0;
    my (@params, $scale);
    ($x, @params) = $x-&gt;_find_round_parameters(@r);

    return $x if $x-&gt;is_nan();  # error in _find_round_parameters?

    # no rounding at all, so must use fallback
    if (scalar @params == 0) {
        # simulate old behaviour
        $params[0] = $class-&gt;div_scale(); # and round to it as accuracy
        $scale = $params[0]+4;            # at least four more for proper round
        $params[2] = $r[2];               # round mode by caller or undef
        $fallback = 1;                    # to clear a/p afterwards
    } else {
        # the 4 below is empirical, and there might be cases where it is not
        # enough...
        $scale = abs($params[0] || $params[1]) + 4; # take whatever is defined
    }

    # When user set globals, they would interfere with our calculation, so
    # disable them and later re-enable them.

    my $ab = $class -&gt; accuracy();
    my $pb = $class -&gt; precision();
    $class -&gt; accuracy(undef);
    $class -&gt; precision(undef);

    # Disabling upgrading and downgrading is no longer necessary to avoid an
    # infinite recursion, but it avoids unnecessary upgrading and downgrading in
    # the intermediate computations.

    my $upg = $class -&gt; upgrade();
    my $dng = $class -&gt; downgrade();
    $class -&gt; upgrade(undef);
    $class -&gt; downgrade(undef);

    # We also need to disable any set A or P on $x (_find_round_parameters took
    # them already into account), since these would interfere, too.

    $x-&gt;{accuracy} = undef;
    $x-&gt;{precision} = undef;

    # remember sign and make $x positive, since -4 ** (1/2) =&gt; -2
    my $sign = 0;
    $sign = 1 if $x-&gt;{sign} eq '-';
    $x-&gt;{sign} = '+';

    my $is_two = 0;
    if ($y-&gt;isa('Math::BigFloat')) {
        $is_two = $y-&gt;{sign} eq '+' &amp;&amp; $LIB-&gt;_is_two($y-&gt;{_m})
                    &amp;&amp; $LIB-&gt;_is_zero($y-&gt;{_e});
    } else {
        $is_two = $y == 2;
    }

    # normal square root if $y == 2:
    if ($is_two) {
        $x = $x-&gt;bsqrt($scale+4);
    } elsif ($y-&gt;is_one('-')) {
        # $x ** -1 =&gt; 1/$x
        my $u = $class-&gt;bone()-&gt;bdiv($x, $scale);
        # copy private parts over
        $x-&gt;{_m} = $u-&gt;{_m};
        $x-&gt;{_e} = $u-&gt;{_e};
        $x-&gt;{_es} = $u-&gt;{_es};
    } else {
        # calculate the broot() as integer result first, and if it fits, return
        # it rightaway (but only if $x and $y are integer):

        my $done = 0;           # not yet
        if ($y-&gt;is_int() &amp;&amp; $x-&gt;is_int()) {
            my $i = $LIB-&gt;_copy($x-&gt;{_m});
            $i = $LIB-&gt;_lsft($i, $x-&gt;{_e}, 10) unless $LIB-&gt;_is_zero($x-&gt;{_e});
            my $int = Math::BigInt-&gt;bzero();
            $int-&gt;{value} = $i;
            $int = $int-&gt;broot($y-&gt;as_number());
            # if ($exact)
            if ($int-&gt;copy()-&gt;bpow($y) == $x) {
                # found result, return it
                $x-&gt;{_m} = $int-&gt;{value};
                $x-&gt;{_e} = $LIB-&gt;_zero();
                $x-&gt;{_es} = '+';
                $x = $x-&gt;bnorm();
                $done = 1;
            }
        }
        if ($done == 0) {
            my $u = $class-&gt;bone()-&gt;bdiv($y, $scale+4);
            $u-&gt;{accuracy} = undef;
            $u-&gt;{precision} = undef;
            $x = $x-&gt;bpow($u, $scale+4);            # el cheapo
        }
    }
    $x = $x-&gt;bneg() if $sign == 1;

    # shortcut to not run through _find_round_parameters again
    if (defined $params[0]) {
        $x = $x-&gt;bround($params[0], $params[2]); # then round accordingly
    } else {
        $x = $x-&gt;bfround($params[1], $params[2]); # then round accordingly
    }
    if ($fallback) {
        # clear a/p after round, since user did not request it
        $x-&gt;{accuracy} = undef;
        $x-&gt;{precision} = undef;
    }

    # Restore globals. We need to do it like this, because setting one
    # undefines the other.

    if (defined $ab) {
        $class -&gt; accuracy($ab);
    } else {
        $class -&gt; precision($pb);
    }

    $class -&gt; upgrade($upg);
    $class -&gt; downgrade($dng);

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; ($x -&gt; is_int() || $x -&gt; is_inf());
    $x;
}

sub bfac {
    # (BFLOAT or num_str, BFLOAT or num_str) return BFLOAT
    # compute factorial number, modifies first argument

    # set up parameters
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    # inf =&gt; inf
    return $x if $x-&gt;modify('bfac');

    return $x -&gt; bnan(@r)      if $x-&gt;is_nan()  || $x-&gt;is_inf("-");
    return $x -&gt; binf("+", @r) if $x-&gt;is_inf("+");
    return $x -&gt; bone(@r)      if $x-&gt;is_zero() || $x-&gt;is_one();

    if ($x -&gt; is_neg() || !$x -&gt; is_int()) {
        return $upgrade -&gt; bfac($x, @r) if defined($upgrade);
        return $x -&gt; bnan(@r);
    }

    if (! $LIB-&gt;_is_zero($x-&gt;{_e})) {
        $x-&gt;{_m} = $LIB-&gt;_lsft($x-&gt;{_m}, $x-&gt;{_e}, 10); # change 12e1 to 120e0
        $x-&gt;{_e} = $LIB-&gt;_zero();           # normalize
        $x-&gt;{_es} = '+';
    }
    $x-&gt;{_m} = $LIB-&gt;_fac($x-&gt;{_m});       # calculate factorial

    $x = $x-&gt;bnorm()-&gt;round(@r);     # norm again and round result

    return $downgrade -&gt; new($x -&gt; bdstr(), @r) if defined($downgrade)
      &amp;&amp; ($x -&gt; is_int() || $x -&gt; is_inf());
    $x;
}

sub bdfac {
    # compute double factorial

    # set up parameters
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bdfac');

    return $x -&gt; bnan(@r)      if $x-&gt;is_nan()  || $x-&gt;is_inf("-");
    return $x -&gt; binf("+", @r) if $x-&gt;is_inf("+");

    if ($x &lt;= -2 || !$x -&gt; is_int()) {
        return $upgrade -&gt; bdfac($x, @r) if defined($upgrade);
        return $x -&gt; bnan(@r);
    }

    return $x-&gt;bone() if $x &lt;= 1;

    croak("bdfac() requires a newer version of the $LIB library.")
        unless $LIB-&gt;can('_dfac');

    if (! $LIB-&gt;_is_zero($x-&gt;{_e})) {
        $x-&gt;{_m} = $LIB-&gt;_lsft($x-&gt;{_m}, $x-&gt;{_e}, 10); # change 12e1 to 120e0
        $x-&gt;{_e} = $LIB-&gt;_zero();           # normalize
        $x-&gt;{_es} = '+';
    }
    $x-&gt;{_m} = $LIB-&gt;_dfac($x-&gt;{_m});       # calculate factorial

    $x = $x-&gt;bnorm()-&gt;round(@r);     # norm again and round result

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; $x -&gt; is_int();
    return $x;
}

sub btfac {
    # compute triple factorial

    # set up parameters
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('btfac');

    return $x -&gt; bnan(@r)      if $x-&gt;is_nan()  || $x-&gt;is_inf("-");
    return $x -&gt; binf("+", @r) if $x-&gt;is_inf("+");

    if ($x &lt;= -3 || !$x -&gt; is_int()) {
        return $upgrade -&gt; btfac($x, @r) if defined($upgrade);
        return $x -&gt; bnan(@r);
    }

    my $k = $class -&gt; new("3");
    return $x-&gt;bnan(@r) if $x &lt;= -$k;

    my $one = $class -&gt; bone();
    return $x-&gt;bone(@r) if $x &lt;= $one;

    my $f = $x -&gt; copy();
    while ($f -&gt; bsub($k) &gt; $one) {
        $x = $x -&gt; bmul($f);
    }

    $x = $x-&gt;round(@r);

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; $x -&gt; is_int();
    return $x;
}

sub bmfac {
    my ($class, $x, $k, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x-&gt;modify('bmfac');

    return $x -&gt; bnan(@r) if $x-&gt;is_nan() || $x-&gt;is_inf("-") || !$k-&gt;is_pos();
    return $x -&gt; binf("+", @r) if $x-&gt;is_inf("+");

    if ($x &lt;= -$k || !$x -&gt; is_int() ||
        ($k -&gt; is_finite() &amp;&amp; !$k -&gt; is_int()))
    {
        return $upgrade -&gt; bmfac($x, $k, @r) if defined($upgrade);
        return $x -&gt; bnan(@r);
    }

    my $one = $class -&gt; bone();
    return $x-&gt;bone(@r) if $x &lt;= $one;

    my $f = $x -&gt; copy();
    while ($f -&gt; bsub($k) &gt; $one) {
        $x = $x -&gt; bmul($f);
    }

    $x = $x-&gt;round(@r);

    return $downgrade -&gt; new($x -&gt; bdstr(), @r)
      if defined($downgrade) &amp;&amp; $x -&gt; is_int();
    return $x;
}

sub blsft {
    # shift left by $y in base $b, i.e., multiply by $b ** $y

    # set up parameters
    my ($class, $x, $y, $b, @r)
      = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1]) &amp;&amp; ref($_[1]) eq ref($_[2])
      ? (ref($_[0]), @_)
      : objectify(2, @_);

    return $x if $x -&gt; modify('blsft');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan() || $y -&gt; is_nan();

    $b = 2 if !defined $b;
    $b = $class -&gt; new($b)
      unless defined(blessed($b)) &amp;&amp; $b -&gt; isa(__PACKAGE__);
    return $x -&gt; bnan(@r) if $b -&gt; is_nan();

    # There needs to be more checking for special cases here. Fixme!

    # shift by a negative amount?
    return $x -&gt; brsft($y -&gt; copy() -&gt; babs(), $b) if $y -&gt; {sign} =~ /^-/;

    $x = $x -&gt; bmul($b -&gt; bpow($y), $r[0], $r[1], $r[2], $y);

    return $downgrade -&gt; new($x -&gt; bdstr(), @r) if defined($downgrade)
      &amp;&amp; ($x -&gt; is_int() || $x -&gt; is_inf() || $x -&gt; is_nan());
    return $x;
}

sub brsft {
    # shift right by $y in base $b, i.e., divide by $b ** $y

    # set up parameters
    my ($class, $x, $y, $b, @r)
      = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1]) &amp;&amp; ref($_[1]) eq ref($_[2])
      ? (ref($_[0]), @_)
      : objectify(2, @_);

    return $x if $x -&gt; modify('brsft');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan() || $y -&gt; is_nan();

    # There needs to be more checking for special cases here. Fixme!

    $b = 2 if !defined $b;
    $b = $class -&gt; new($b)
      unless defined(blessed($b)) &amp;&amp; $b -&gt; isa(__PACKAGE__);
    return $x -&gt; bnan(@r) if $b -&gt; is_nan();

    # shift by a negative amount?
    return $x -&gt; blsft($y -&gt; copy() -&gt; babs(), $b) if $y -&gt; {sign} =~ /^-/;

    # call bdiv()
    $x = $x -&gt; bdiv($b -&gt; bpow($y), $r[0], $r[1], $r[2], $y);

    return $downgrade -&gt; new($x -&gt; bdstr(), @r) if defined($downgrade)
      &amp;&amp; ($x -&gt; is_int() || $x -&gt; is_inf() || $x -&gt; is_nan());
    return $x;
}

###############################################################################
# Bitwise methods
###############################################################################

# Bitwise left shift.

sub bblsft {
    # We don't call objectify(), because the bitwise methods should not
    # upgrade/downgrade, even when upgrading/downgrading is enabled.

    my ($class, $x, $y, @r) = ref($_[0]) ? (ref($_[0]), @_) : @_;

    my $xint = Math::BigInt -&gt; bblsft($x, $y, @r);

    # Temporarily disable downgrading.

    my $dng = $class -&gt; downgrade();
    $class -&gt; downgrade(undef);

    # convert to our class without downgrading.

    my $xflt = $class -&gt; new($xint);

    # Reset downgrading.

    $class -&gt; downgrade($dng);

    # If we are called as a class method, the first operand might not be an
    # object of this class, so check.

    if (defined(blessed($x)) &amp;&amp; $x -&gt; isa(__PACKAGE__)) {
        $x -&gt; {sign} = $xflt -&gt; {sign};
        $x -&gt; {_m}   = $xflt -&gt; {_m};
        $x -&gt; {_es}  = $xflt -&gt; {_es};
        $x -&gt; {_e}   = $xflt -&gt; {_e};
    } else {
        $x = $xflt;
    }

    # Now we might downgrade.

    return $downgrade -&gt; new($x) if defined($downgrade);
    $x -&gt; round(@r);
}

# Bitwise right shift.

sub bbrsft {
    # We don't call objectify(), because the bitwise methods should not
    # upgrade/downgrade, even when upgrading/downgrading is enabled.

    my ($class, $x, $y, @r) = ref($_[0]) ? (ref($_[0]), @_) : @_;

    my $xint = Math::BigInt -&gt; bbrsft($x, $y, @r);

    # Temporarily disable downgrading.

    my $dng = $class -&gt; downgrade();
    $class -&gt; downgrade(undef);

    # Convert to our class without downgrading.

    my $xflt = $class -&gt; new($xint);

    # Reset downgrading.

    $class -&gt; downgrade($dng);

    # If we are called as a class method, the first operand might not be an
    # object of this class, so check.

    if (defined(blessed($x)) &amp;&amp; $x -&gt; isa(__PACKAGE__)) {
        $x -&gt; {sign} = $xflt -&gt; {sign};
        $x -&gt; {_m}   = $xflt -&gt; {_m};
        $x -&gt; {_es}  = $xflt -&gt; {_es};
        $x -&gt; {_e}   = $xflt -&gt; {_e};
    } else {
        $x = $xflt;
    }

    # Now we might downgrade.

    return $downgrade -&gt; new($x) if defined($downgrade);
    $x -&gt; round(@r);
}

sub band {
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return if $x -&gt; modify('band');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan() || $y -&gt; is_nan();

    my $xint = $x -&gt; as_int();          # to Math::BigInt
    my $yint = $y -&gt; as_int();          # to Math::BigInt

    $xint = $xint -&gt; band($yint);

    return $xint -&gt; round(@r) if defined $downgrade;

    my $xflt = $class -&gt; new($xint);    # back to Math::BigFloat
    $x -&gt; {sign} = $xflt -&gt; {sign};
    $x -&gt; {_m}   = $xflt -&gt; {_m};
    $x -&gt; {_es}  = $xflt -&gt; {_es};
    $x -&gt; {_e}   = $xflt -&gt; {_e};

    return $x -&gt; round(@r);
}

sub bior {
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return if $x -&gt; modify('bior');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan() || $y -&gt; is_nan();

    my $xint = $x -&gt; as_int();          # to Math::BigInt
    my $yint = $y -&gt; as_int();          # to Math::BigInt

    $xint = $xint -&gt; bior($yint);

    return $xint -&gt; round(@r) if defined $downgrade;

    my $xflt = $class -&gt; new($xint);    # back to Math::BigFloat
    $x -&gt; {sign} = $xflt -&gt; {sign};
    $x -&gt; {_m}   = $xflt -&gt; {_m};
    $x -&gt; {_es}  = $xflt -&gt; {_es};
    $x -&gt; {_e}   = $xflt -&gt; {_e};

    return $x -&gt; round(@r);
}

sub bxor {
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return if $x -&gt; modify('bxor');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan() || $y -&gt; is_nan();

    my $xint = $x -&gt; as_int();          # to Math::BigInt
    my $yint = $y -&gt; as_int();          # to Math::BigInt

    $xint = $xint -&gt; bxor($yint);

    return $xint -&gt; round(@r) if defined $downgrade;

    my $xflt = $class -&gt; new($xint);    # back to Math::BigFloat
    $x -&gt; {sign} = $xflt -&gt; {sign};
    $x -&gt; {_m}   = $xflt -&gt; {_m};
    $x -&gt; {_es}  = $xflt -&gt; {_es};
    $x -&gt; {_e}   = $xflt -&gt; {_e};

    return $x -&gt; round(@r);
}

sub bnot {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return if $x -&gt; modify('bnot');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan();

    my $xint = $x -&gt; as_int();          # to Math::BigInt
    $xint = $xint -&gt; bnot();

    return $xint -&gt; round(@r) if defined $downgrade;

    my $xflt = $class -&gt; new($xint);    # back to Math::BigFloat
    $x -&gt; {sign} = $xflt -&gt; {sign};
    $x -&gt; {_m}   = $xflt -&gt; {_m};
    $x -&gt; {_es}  = $xflt -&gt; {_es};
    $x -&gt; {_e}   = $xflt -&gt; {_e};

    return $x -&gt; round(@r);
}

###############################################################################
# Rounding methods
###############################################################################

sub bround {
    # accuracy: preserve $N digits, and overwrite the rest with 0's

    my ($class, $x, @a) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    if (($a[0] || 0) &lt; 0) {
        croak('bround() needs positive accuracy');
    }

    return $x if $x-&gt;modify('bround');

    my ($scale, $mode) = $x-&gt;_scale_a(@a);
    if (!defined $scale) {         # no-op
        return $downgrade -&gt; new($x) if defined($downgrade)
          &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
        return $x;
    }

    # Scale is now either $x-&gt;{accuracy}, $accuracy, or the input argument. Test
    # whether $x already has lower accuracy, do nothing in this case but do
    # round if the accuracy is the same, since a math operation might want to
    # round a number with A=5 to 5 digits afterwards again

    if (defined $x-&gt;{accuracy} &amp;&amp; $x-&gt;{accuracy} &lt; $scale) {
        return $downgrade -&gt; new($x) if defined($downgrade)
          &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
        return $x;
    }

    # scale &lt; 0 makes no sense
    # scale == 0 =&gt; keep all digits
    # never round a +-inf, NaN

    if ($scale &lt;= 0 || $x-&gt;{sign} !~ /^[+-]$/) {
        return $downgrade -&gt; new($x) if defined($downgrade)
          &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
        return $x;
    }

    # 1: never round a 0
    # 2: if we should keep more digits than the mantissa has, do nothing
    if ($x-&gt;is_zero() || $LIB-&gt;_len($x-&gt;{_m}) &lt;= $scale) {
        $x-&gt;{accuracy} = $scale if !defined $x-&gt;{accuracy} || $x-&gt;{accuracy} &gt; $scale;
        return $downgrade -&gt; new($x) if defined($downgrade)
          &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
        return $x;
    }

    # pass sign to bround for '+inf' and '-inf' rounding modes
    my $m = bless { sign =&gt; $x-&gt;{sign}, value =&gt; $x-&gt;{_m} }, 'Math::BigInt';

    $m = $m-&gt;bround($scale, $mode);     # round mantissa
    $x-&gt;{_m} = $m-&gt;{value};             # get our mantissa back
    $x-&gt;{accuracy} = $scale;                  # remember rounding
    $x-&gt;{precision} = undef;                   # and clear P

    # bnorm() downgrades if necessary, so no need to check whether to downgrade.
    $x-&gt;bnorm();                # del trailing zeros gen. by bround()
}

sub bfround {
    # precision: round to the $Nth digit left (+$n) or right (-$n) from the '.'
    # $n == 0 means round to integer
    # expects and returns normalized numbers!

    my ($class, $x, @p) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bfround'); # no-op

    my ($scale, $mode) = $x-&gt;_scale_p(@p);
    if (!defined $scale) {
        return $downgrade -&gt; new($x) if defined($downgrade)
          &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
        return $x;
    }

    # never round a 0, +-inf, NaN

    if ($x-&gt;is_zero()) {
        $x-&gt;{precision} = $scale if !defined $x-&gt;{precision} || $x-&gt;{precision} &lt; $scale; # -3 &lt; -2
        return $downgrade -&gt; new($x) if defined($downgrade)
          &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
        return $x;
    }

    if ($x-&gt;{sign} !~ /^[+-]$/) {
        return $downgrade -&gt; new($x) if defined($downgrade)
          &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
        return $x;
    }

    # don't round if x already has lower precision
    if (defined $x-&gt;{precision} &amp;&amp; $x-&gt;{precision} &lt; 0 &amp;&amp; $scale &lt; $x-&gt;{precision}) {
        return $downgrade -&gt; new($x) if defined($downgrade)
          &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
        return $x;
    }

    $x-&gt;{precision} = $scale;          # remember round in any case
    $x-&gt;{accuracy} = undef;           # and clear A
    if ($scale &lt; 0) {
        # round right from the '.'

        if ($x-&gt;{_es} eq '+') { # e &gt;= 0 =&gt; nothing to round
            return $downgrade -&gt; new($x) if defined($downgrade)
              &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
            return $x;
        }

        $scale = -$scale;           # positive for simplicity
        my $len = $LIB-&gt;_len($x-&gt;{_m}); # length of mantissa

        # the following poses a restriction on _e, but if _e is bigger than a
        # scalar, you got other problems (memory etc) anyway
        my $dad = -(0+ ($x-&gt;{_es}.$LIB-&gt;_num($x-&gt;{_e}))); # digits after dot
        my $zad = 0;                                      # zeros after dot
        $zad = $dad - $len if (-$dad &lt; -$len); # for 0.00..00xxx style

        # print "scale $scale dad $dad zad $zad len $len\n";
        # number  bsstr   len zad dad
        # 0.123   123e-3    3   0 3
        # 0.0123  123e-4    3   1 4
        # 0.001   1e-3      1   2 3
        # 1.23    123e-2    3   0 2
        # 1.2345  12345e-4  5   0 4

        # do not round after/right of the $dad

        if ($scale &gt; $dad) { # 0.123, scale &gt;= 3 =&gt; exit
            return $downgrade -&gt; new($x) if defined($downgrade)
              &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
            return $x;
        }

        # round to zero if rounding inside the $zad, but not for last zero like:
        # 0.0065, scale -2, round last '0' with following '65' (scale == zad
        # case)
        if ($scale &lt; $zad) {
            return $downgrade -&gt; new($x) if defined($downgrade)
              &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
            return $x-&gt;bzero();
        }

        if ($scale == $zad) {    # for 0.006, scale -3 and trunc
            $scale = -$len;
        } else {
            # adjust round-point to be inside mantissa
            if ($zad != 0) {
                $scale = $scale-$zad;
            } else {
                my $dbd = $len - $dad;
                $dbd = 0 if $dbd &lt; 0; # digits before dot
                $scale = $dbd+$scale;
            }
        }
    } else {
        # round left from the '.'

        # 123 =&gt; 100 means length(123) = 3 - $scale (2) =&gt; 1

        my $dbt = $LIB-&gt;_len($x-&gt;{_m});
        # digits before dot
        my $dbd = $dbt + ($x-&gt;{_es} . $LIB-&gt;_num($x-&gt;{_e}));
        # should be the same, so treat it as this
        $scale = 1 if $scale == 0;
        # shortcut if already integer
        if ($scale == 1 &amp;&amp; $dbt &lt;= $dbd) {
            return $downgrade -&gt; new($x) if defined($downgrade)
              &amp;&amp; ($x-&gt;is_int() || $x-&gt;is_inf() || $x-&gt;is_nan());
            return $x;
        }
        # maximum digits before dot
        ++$dbd;

        if ($scale &gt; $dbd) {
            # not enough digits before dot, so round to zero
            return $downgrade -&gt; new($x) if defined($downgrade);
            return $x-&gt;bzero;
        } elsif ($scale == $dbd) {
            # maximum
            $scale = -$dbt;
        } else {
            $scale = $dbd - $scale;
        }
    }

    # pass sign to bround for rounding modes '+inf' and '-inf'
    my $m = bless { sign =&gt; $x-&gt;{sign}, value =&gt; $x-&gt;{_m} }, 'Math::BigInt';
    $m = $m-&gt;bround($scale, $mode);
    $x-&gt;{_m} = $m-&gt;{value};     # get our mantissa back

    # bnorm() downgrades if necessary, so no need to check whether to downgrade.
    $x-&gt;bnorm();
}

sub bfloor {
    # round towards minus infinity
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bfloor');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan();

    if ($x-&gt;{sign} =~ /^[+-]$/) {
        # if $x has digits after dot, remove them
        if ($x-&gt;{_es} eq '-') {
            $x-&gt;{_m} = $LIB-&gt;_rsft($x-&gt;{_m}, $x-&gt;{_e}, 10);
            $x-&gt;{_e} = $LIB-&gt;_zero();
            $x-&gt;{_es} = '+';
            # increment if negative
            $x-&gt;{_m} = $LIB-&gt;_inc($x-&gt;{_m}) if $x-&gt;{sign} eq '-';
        }
        $x = $x-&gt;round(@r);
    }
    return $downgrade -&gt; new($x -&gt; bdstr(), @r) if defined($downgrade);
    return $x;
}

sub bceil {
    # round towards plus infinity
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bceil');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan();

    # if $x has digits after dot, remove them
    if ($x-&gt;{sign} =~ /^[+-]$/) {
        if ($x-&gt;{_es} eq '-') {
            $x-&gt;{_m} = $LIB-&gt;_rsft($x-&gt;{_m}, $x-&gt;{_e}, 10);
            $x-&gt;{_e} = $LIB-&gt;_zero();
            $x-&gt;{_es} = '+';
            if ($x-&gt;{sign} eq '+') {
                $x-&gt;{_m} = $LIB-&gt;_inc($x-&gt;{_m});        # increment if positive
            } else {
                $x-&gt;{sign} = '+' if $LIB-&gt;_is_zero($x-&gt;{_m});   # avoid -0
            }
        }
        $x = $x-&gt;round(@r);
    }

    return $downgrade -&gt; new($x -&gt; bdstr(), @r) if defined($downgrade);
    return $x;
}

sub bint {
    # round towards zero
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bint');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan();

    if ($x-&gt;{sign} =~ /^[+-]$/) {
        # if $x has digits after the decimal point
        if ($x-&gt;{_es} eq '-') {
            $x-&gt;{_m} = $LIB-&gt;_rsft($x-&gt;{_m}, $x-&gt;{_e}, 10); # remove frac part
            $x-&gt;{_e} = $LIB-&gt;_zero();                       # truncate/normalize
            $x-&gt;{_es} = '+';                                # abs e
            $x-&gt;{sign} = '+' if $LIB-&gt;_is_zero($x-&gt;{_m});   # avoid -0
        }
        $x = $x-&gt;round(@r);
    }

    return $downgrade -&gt; new($x -&gt; bdstr(), @r) if defined($downgrade);
    return $x;
}

###############################################################################
# Other mathematical methods
###############################################################################

sub bgcd {
    # (BINT or num_str, BINT or num_str) return BINT
    # does not modify arguments, but returns new object

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my ($class, @args) = objectify(0, @_);

    my $x = shift @args;
    $x = defined(blessed($x)) &amp;&amp; $x -&gt; isa(__PACKAGE__) ? $x -&gt; copy()
                                                        : $class -&gt; new($x);
    return $class-&gt;bnan() unless $x -&gt; is_int();

    while (@args) {
        my $y = shift @args;
        $y = $class-&gt;new($y)
          unless defined(blessed($y)) &amp;&amp; $y -&gt; isa(__PACKAGE__);
        return $class-&gt;bnan() unless $y -&gt; is_int();

        # greatest common divisor
        while (! $y-&gt;is_zero()) {
            ($x, $y) = ($y-&gt;copy(), $x-&gt;copy()-&gt;bmod($y));
        }

        last if $x -&gt; is_one();
    }
    $x = $x -&gt; babs();

    return $downgrade -&gt; new($x)
      if defined $downgrade &amp;&amp; $x-&gt;is_int();
    return $x;
}

sub blcm {
    # (BFLOAT or num_str, BFLOAT or num_str) return BFLOAT
    # does not modify arguments, but returns new object
    # Least Common Multiple

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my ($class, @args) = objectify(0, @_);

    my $x = shift @args;
    $x = defined(blessed($x)) &amp;&amp; $x -&gt; isa(__PACKAGE__) ? $x -&gt; copy()
                                                        : $class -&gt; new($x);
    return $class-&gt;bnan() if $x-&gt;{sign} !~ /^[+-]$/;    # x NaN?

    while (@args) {
        my $y = shift @args;
        $y = $class -&gt; new($y)
          unless defined(blessed($y)) &amp;&amp; $y -&gt; isa(__PACKAGE__);
        return $x-&gt;bnan() unless $y -&gt; is_int();
        my $gcd = $x -&gt; bgcd($y);
        $x = $x -&gt; bdiv($gcd) -&gt; bmul($y);
    }

    $x = $x -&gt; babs();

    return $downgrade -&gt; new($x)
      if defined $downgrade &amp;&amp; $x-&gt;is_int();
    return $x;
}

###############################################################################
# Object property methods
###############################################################################

sub length {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return 1 if $LIB-&gt;_is_zero($x-&gt;{_m});

    my $len = $LIB-&gt;_len($x-&gt;{_m});
    $len += $LIB-&gt;_num($x-&gt;{_e}) if $x-&gt;{_es} eq '+';
    if (wantarray()) {
        my $t = 0;
        $t = $LIB-&gt;_num($x-&gt;{_e}) if $x-&gt;{_es} eq '-';
        return ($len, $t);
    }
    $len;
}

sub mantissa {
    # return a copy of the mantissa
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    # The following line causes a lot of noise in the test suits for
    # the Math-BigRat and bignum distributions. Fixme!
    #carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x -&gt; bnan(@r) if $x -&gt; is_nan();

    if ($x-&gt;{sign} !~ /^[+-]$/) {
        my $s = $x-&gt;{sign};
        $s =~ s/^\+//;
        return Math::BigInt-&gt;new($s, undef, undef); # -inf, +inf =&gt; +inf
    }
    my $m = Math::BigInt-&gt;new($LIB-&gt;_str($x-&gt;{_m}), undef, undef);
    $m = $m-&gt;bneg() if $x-&gt;{sign} eq '-';
    $m;
}

sub exponent {
    # return a copy of the exponent
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    # The following line causes a lot of noise in the test suits for
    # the Math-BigRat and bignum distributions. Fixme!
    #carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x -&gt; bnan(@r) if $x -&gt; is_nan();

    if ($x-&gt;{sign} !~ /^[+-]$/) {
        my $s = $x-&gt;{sign};
        $s =~ s/^[+-]//;
        return Math::BigInt-&gt;new($s, undef, undef); # -inf, +inf =&gt; +inf
    }
    Math::BigInt-&gt;new($x-&gt;{_es} . $LIB-&gt;_str($x-&gt;{_e}), undef, undef);
}

sub parts {
    # return a copy of both the exponent and the mantissa
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    if ($x-&gt;{sign} !~ /^[+-]$/) {
        my $s = $x-&gt;{sign};
        $s =~ s/^\+//;
        my $se = $s;
        $se =~ s/^-//;
        # +inf =&gt; inf and -inf, +inf =&gt; inf
        return ($class-&gt;new($s), $class-&gt;new($se));
    }
    my $m = Math::BigInt-&gt;bzero();
    $m-&gt;{value} = $LIB-&gt;_copy($x-&gt;{_m});
    $m = $m-&gt;bneg() if $x-&gt;{sign} eq '-';
    ($m, Math::BigInt-&gt;new($x-&gt;{_es} . $LIB-&gt;_num($x-&gt;{_e})));
}

# Parts used for scientific notation with significand/mantissa and exponent as
# integers. E.g., "12345.6789" is returned as "123456789" (mantissa) and "-4"
# (exponent).

sub sparts {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Not-a-number.

    if ($x -&gt; is_nan()) {
        my $mant = $class -&gt; bnan();            # mantissa
        return $mant unless wantarray;          # scalar context
        my $expo = $class -&gt; bnan();            # exponent
        return ($mant, $expo);                  # list context
    }

    # Infinity.

    if ($x -&gt; is_inf()) {
        my $mant = $class -&gt; binf($x-&gt;{sign});  # mantissa
        return $mant unless wantarray;          # scalar context
        my $expo = $class -&gt; binf('+');         # exponent
        return ($mant, $expo);                  # list context
    }

    # Finite number.

    my $mant = $class -&gt; new($x);
    $mant-&gt;{_es} = '+';
    $mant-&gt;{_e}  = $LIB-&gt;_zero();
    $mant = $downgrade -&gt; new($mant) if defined $downgrade;
    return $mant unless wantarray;

    my $expo = $class -&gt; new($x -&gt; {_es} . $LIB-&gt;_str($x -&gt; {_e}));
    $expo = $downgrade -&gt; new($expo) if defined $downgrade;
    return ($mant, $expo);
}

# Parts used for normalized notation with significand/mantissa as either 0 or a
# number in the semi-open interval [1,10). E.g., "12345.6789" is returned as
# "1.23456789" and "4".

sub nparts {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Not-a-number and Infinity.

    return $x -&gt; sparts() if $x -&gt; is_nan() || $x -&gt; is_inf();

    # Finite number.

    my ($mant, $expo) = $x -&gt; sparts();

    if ($mant -&gt; bcmp(0)) {
        my ($ndigtot, $ndigfrac) = $mant -&gt; length();
        my $expo10adj = $ndigtot - $ndigfrac - 1;

        if ($expo10adj &gt; 0) {          # if mantissa is not an integer
            $mant = $mant -&gt; brsft($expo10adj, 10);
            return $mant unless wantarray;
            $expo = $expo -&gt; badd($expo10adj);
            return ($mant, $expo);
        }
    }

    return $mant unless wantarray;
    return ($mant, $expo);
}

# Parts used for engineering notation with significand/mantissa as either 0 or a
# number in the semi-open interval [1,1000) and the exponent is a multiple of 3.
# E.g., "12345.6789" is returned as "12.3456789" and "3".

sub eparts {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Not-a-number and Infinity.

    return $x -&gt; sparts() if $x -&gt; is_nan() || $x -&gt; is_inf();

    # Finite number.

    my ($mant, $expo) = $x -&gt; nparts();

    my $c = $expo -&gt; copy() -&gt; bmod(3);
    $mant = $mant -&gt; blsft($c, 10);
    return $mant unless wantarray;

    $expo = $expo -&gt; bsub($c);
    return ($mant, $expo);
}

# Parts used for decimal notation, e.g., "12345.6789" is returned as "12345"
# (integer part) and "0.6789" (fraction part).

sub dparts {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Not-a-number.

    if ($x -&gt; is_nan()) {
        my $int = $class -&gt; bnan();
        return $int unless wantarray;
        my $frc = $class -&gt; bzero();    # or NaN?
        return ($int, $frc);
    }

    # Infinity.

    if ($x -&gt; is_inf()) {
        my $int = $class -&gt; binf($x-&gt;{sign});
        return $int unless wantarray;
        my $frc = $class -&gt; bzero();
        return ($int, $frc);
    }

    # Finite number.

    my $int = $x -&gt; copy();
    my $frc;

    # If the input is an integer.

    if ($int-&gt;{_es} eq '+') {
        $frc = $class -&gt; bzero();
    }

    # If the input has a fraction part

    else {
        $int-&gt;{_m} = $LIB -&gt; _rsft($int-&gt;{_m}, $int-&gt;{_e}, 10);
        $int-&gt;{_e} = $LIB -&gt; _zero();
        $int-&gt;{_es} = '+';
        $int-&gt;{sign} = '+' if $LIB-&gt;_is_zero($int-&gt;{_m});   # avoid -0
        return $int unless wantarray;
        $frc = $x -&gt; copy() -&gt; bsub($int);
        return ($int, $frc);
    }

    $int = $downgrade -&gt; new($int) if defined $downgrade;
    return $int unless wantarray;
    return $int, $frc;
}

# Fractional parts with the numerator and denominator as integers. E.g.,
# "123.4375" is returned as "1975" and "16".

sub fparts {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # NaN =&gt; NaN/NaN

    if ($x -&gt; is_nan()) {
        return $class -&gt; bnan() unless wantarray;
        return $class -&gt; bnan(), $class -&gt; bnan();
    }

    # Â±Inf =&gt; Â±Inf/1

    if ($x -&gt; is_inf()) {
        my $numer = $class -&gt; binf($x-&gt;{sign});
        return $numer unless wantarray;
        my $denom = $class -&gt; bone();
        return $numer, $denom;
    }

    # Finite number.

    # If we get here, we know that the output is an integer.

    $class = $downgrade if defined $downgrade;

    my @flt_parts = ($x-&gt;{sign}, $x-&gt;{_m}, $x-&gt;{_es}, $x-&gt;{_e});
    my @rat_parts = $class -&gt; _flt_lib_parts_to_rat_lib_parts(@flt_parts);
    my $num = $class -&gt; new($LIB -&gt; _str($rat_parts[1]));
    my $den = $class -&gt; new($LIB -&gt; _str($rat_parts[2]));
    $num = $num -&gt; bneg() if $rat_parts[0] eq "-";
    return $num unless wantarray;
    return $num, $den;
}

# Given "123.4375", returns "1975", since "123.4375" is "1975/16".

sub numerator {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $class -&gt; bnan()             if $x -&gt; is_nan();
    return $class -&gt; binf($x -&gt; sign()) if $x -&gt; is_inf();
    return $class -&gt; bzero()            if $x -&gt; is_zero();

    # If we get here, we know that the output is an integer.

    $class = $downgrade if defined $downgrade;

    if ($x -&gt; {_es} eq '-') {                   # exponent &lt; 0
        my $numer_lib = $LIB -&gt; _copy($x -&gt; {_m});
        my $denom_lib = $LIB -&gt; _1ex($x -&gt; {_e});
        my $gcd_lib = $LIB -&gt; _gcd($LIB -&gt; _copy($numer_lib), $denom_lib);
        $numer_lib = $LIB -&gt; _div($numer_lib, $gcd_lib);
        return $class -&gt; new($x -&gt; {sign} . $LIB -&gt; _str($numer_lib));
    }

    elsif (! $LIB -&gt; _is_zero($x -&gt; {_e})) {    # exponent &gt; 0
        my $numer_lib = $LIB -&gt; _copy($x -&gt; {_m});
        $numer_lib = $LIB -&gt; _lsft($numer_lib, $x -&gt; {_e}, 10);
        return $class -&gt; new($x -&gt; {sign} . $LIB -&gt; _str($numer_lib));
    }

    else {                                      # exponent = 0
        return $class -&gt; new($x -&gt; {sign} . $LIB -&gt; _str($x -&gt; {_m}));
    }
}

# Given "123.4375", returns "16", since "123.4375" is "1975/16".

sub denominator {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $class -&gt; bnan() if $x -&gt; is_nan();

    # If we get here, we know that the output is an integer.

    $class = $downgrade if defined $downgrade;

    if ($x -&gt; {_es} eq '-') {                   # exponent &lt; 0
        my $numer_lib = $LIB -&gt; _copy($x -&gt; {_m});
        my $denom_lib = $LIB -&gt; _1ex($x -&gt; {_e});
        my $gcd_lib = $LIB -&gt; _gcd($LIB -&gt; _copy($numer_lib), $denom_lib);
        $denom_lib = $LIB -&gt; _div($denom_lib, $gcd_lib);
        return $class -&gt; new($LIB -&gt; _str($denom_lib));
    }

    else {                                      # exponent &gt;= 0
        return $class -&gt; bone();
    }
}

###############################################################################
# String conversion methods
###############################################################################

sub bstr {
    # (ref to BFLOAT or num_str) return num_str
    # Convert number from internal format to (non-scientific) string format.
    # internal format is always normalized (no leading zeros, "-0" =&gt; "+0")
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Finite number

    my $es = '0';
    my $len = 1;
    my $cad = 0;
    my $dot = '.';

    # $x is zero?
    my $not_zero = !($x-&gt;{sign} eq '+' &amp;&amp; $LIB-&gt;_is_zero($x-&gt;{_m}));
    if ($not_zero) {
        $es = $LIB-&gt;_str($x-&gt;{_m});
        $len = CORE::length($es);
        my $e = $LIB-&gt;_num($x-&gt;{_e});
        $e = -$e if $x-&gt;{_es} eq '-';
        if ($e &lt; 0) {
            $dot = '';
            # if _e is bigger than a scalar, the following will blow your memory
            if ($e &lt;= -$len) {
                my $r = abs($e) - $len;
                $es = '0.'. ('0' x $r) . $es;
                $cad = -($len+$r);
            } else {
                substr($es, $e, 0) = '.';
                $cad = $LIB-&gt;_num($x-&gt;{_e});
                $cad = -$cad if $x-&gt;{_es} eq '-';
            }
        } elsif ($e &gt; 0) {
            # expand with zeros
            $es .= '0' x $e;
            $len += $e;
            $cad = 0;
        }
    }                           # if not zero

    $es = '-'.$es if $x-&gt;{sign} eq '-';
    # if set accuracy or precision, pad with zeros on the right side
    if ((defined $x-&gt;{accuracy}) &amp;&amp; ($not_zero)) {
        # 123400 =&gt; 6, 0.1234 =&gt; 4, 0.001234 =&gt; 4
        my $zeros = $x-&gt;{accuracy} - $cad; # cad == 0 =&gt; 12340
        $zeros = $x-&gt;{accuracy} - $len if $cad != $len;
        $es .= $dot.'0' x $zeros if $zeros &gt; 0;
    } elsif ((($x-&gt;{precision} || 0) &lt; 0)) {
        # 123400 =&gt; 6, 0.1234 =&gt; 4, 0.001234 =&gt; 6
        my $zeros = -$x-&gt;{precision} + $cad;
        $es .= $dot.'0' x $zeros if $zeros &gt; 0;
    }
    $es;
}

# Decimal notation, e.g., "12345.6789" (no exponent).

sub bdstr {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; bdstr($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    my $mant = $LIB-&gt;_str($x-&gt;{_m});
    my $esgn = $x-&gt;{_es};
    my $eabs = $LIB -&gt; _num($x-&gt;{_e});

    my $uintmax = ~0;

    my $str = $mant;
    if ($esgn eq '+') {

        croak("The absolute value of the exponent is too large")
          if $eabs &gt; $uintmax;

        $str .= "0" x $eabs;

    } else {
        my $mlen = CORE::length($mant);
        my $c = $mlen - $eabs;

        my $intmax = ($uintmax - 1) / 2;
        croak("The absolute value of the exponent is too large")
          if (1 - $c) &gt; $intmax;

        $str = "0" x (1 - $c) . $str if $c &lt;= 0;
        substr($str, -$eabs, 0) = '.';
    }

    return $x-&gt;{sign} eq '-' ? '-' . $str : $str;
}

# Scientific notation with significand/mantissa and exponent as integers, e.g.,
# "12345.6789" is written as "123456789e-4".

sub bsstr {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; bsstr($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    ($x-&gt;{sign} eq '-' ? '-' : '') . $LIB-&gt;_str($x-&gt;{_m})
      . 'e' . $x-&gt;{_es} . $LIB-&gt;_str($x-&gt;{_e});
}

# Normalized notation, e.g., "12345.6789" is written as "1.23456789e+4".

sub bnstr {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; bnstr($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    my $str = $x-&gt;{sign} eq '-' ? '-' : '';

    # Get the mantissa and the length of the mantissa.

    my $mant = $LIB-&gt;_str($x-&gt;{_m});
    my $mantlen = CORE::length($mant);

    if ($mantlen == 1) {

        # Not decimal point when the mantissa has length one, i.e., return the
        # number 2 as the string "2", not "2.".

        $str .= $mant . 'e' . $x-&gt;{_es} . $LIB-&gt;_str($x-&gt;{_e});

    } else {

        # Compute new exponent where the original exponent is adjusted by the
        # length of the mantissa minus one (because the decimal point is after
        # one digit).

        my ($eabs, $esgn) = $LIB -&gt; _sadd($LIB -&gt; _copy($x-&gt;{_e}), $x-&gt;{_es},
                                      $LIB -&gt; _new($mantlen - 1), "+");
        substr $mant, 1, 0, ".";
        $str .= $mant . 'e' . $esgn . $LIB-&gt;_str($eabs);

    }

    return $str;
}

# Engineering notation, e.g., "12345.6789" is written as "12.3456789e+3".

sub bestr {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; bestr($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    my $str = $x-&gt;{sign} eq '-' ? '-' : '';

    # Get the mantissa, the length of the mantissa, and adjust the exponent by
    # the length of the mantissa minus 1 (because the dot is after one digit).

    my $mant = $LIB-&gt;_str($x-&gt;{_m});
    my $mantlen = CORE::length($mant);
    my ($eabs, $esgn) = $LIB -&gt; _sadd($LIB -&gt; _copy($x-&gt;{_e}), $x-&gt;{_es},
                                  $LIB -&gt; _new($mantlen - 1), "+");

    my $dotpos = 1;
    my $mod = $LIB -&gt; _mod($LIB -&gt; _copy($eabs), $LIB -&gt; _new("3"));
    unless ($LIB -&gt; _is_zero($mod)) {
        if ($esgn eq '+') {
            $eabs = $LIB -&gt; _sub($eabs, $mod);
            $dotpos += $LIB -&gt; _num($mod);
        } else {
            my $delta = $LIB -&gt; _sub($LIB -&gt; _new("3"), $mod);
            $eabs = $LIB -&gt; _add($eabs, $delta);
            $dotpos += $LIB -&gt; _num($delta);
        }
    }

    if ($dotpos &lt; $mantlen) {
        substr $mant, $dotpos, 0, ".";
    } elsif ($dotpos &gt; $mantlen) {
        $mant .= "0" x ($dotpos - $mantlen);
    }

    $str .= $mant . 'e' . $esgn . $LIB-&gt;_str($eabs);

    return $str;
}

# Fractional notation, e.g., "123.4375" is written as "1975/16".

sub bfstr {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), $_[0]) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; bfstr($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    my $str = $x-&gt;{sign} eq '-' ? '-' : '';

    if ($x-&gt;{_es} eq '+') {
        $str .= $LIB -&gt; _str($x-&gt;{_m}) . ("0" x $LIB -&gt; _num($x-&gt;{_e}));
    } else {
        my @flt_parts = ($x-&gt;{sign}, $x-&gt;{_m}, $x-&gt;{_es}, $x-&gt;{_e});
        my @rat_parts = $class -&gt; _flt_lib_parts_to_rat_lib_parts(@flt_parts);
        $str = $LIB -&gt; _str($rat_parts[1]) . "/" . $LIB -&gt; _str($rat_parts[2]);
        $str = "-" . $str if $rat_parts[0] eq "-";
    }

    return $str;
}

sub to_hex {
    # return number as hexadecimal string (only for integers defined)
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), $_[0]) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; to_hex($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    return '0' if $x-&gt;is_zero();

    return $nan if $x-&gt;{_es} ne '+';    # how to do 1e-1 in hex?

    my $z = $LIB-&gt;_copy($x-&gt;{_m});
    if (! $LIB-&gt;_is_zero($x-&gt;{_e})) {   # &gt; 0
        $z = $LIB-&gt;_lsft($z, $x-&gt;{_e}, 10);
    }
    my $str = $LIB-&gt;_to_hex($z);
    return $x-&gt;{sign} eq '-' ? "-$str" : $str;
}

sub to_oct {
    # return number as octal digit string (only for integers defined)
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), $_[0]) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; to_oct($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    return '0' if $x-&gt;is_zero();

    return $nan if $x-&gt;{_es} ne '+';    # how to do 1e-1 in octal?

    my $z = $LIB-&gt;_copy($x-&gt;{_m});
    if (! $LIB-&gt;_is_zero($x-&gt;{_e})) {   # &gt; 0
        $z = $LIB-&gt;_lsft($z, $x-&gt;{_e}, 10);
    }
    my $str = $LIB-&gt;_to_oct($z);
    return $x-&gt;{sign} eq '-' ? "-$str" : $str;
}

sub to_bin {
    # return number as binary digit string (only for integers defined)
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), $_[0]) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; to_bin($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    return '0' if $x-&gt;is_zero();

    return $nan if $x-&gt;{_es} ne '+';    # how to do 1e-1 in binary?

    my $z = $LIB-&gt;_copy($x-&gt;{_m});
    if (! $LIB-&gt;_is_zero($x-&gt;{_e})) {   # &gt; 0
        $z = $LIB-&gt;_lsft($z, $x-&gt;{_e}, 10);
    }
    my $str = $LIB-&gt;_to_bin($z);
    return $x-&gt;{sign} eq '-' ? "-$str" : $str;
}

sub to_ieee754 {
    my ($class, $x, $format, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    my $enc;            # significand encoding (applies only to decimal)
    my $k;              # storage width in bits
    my $b;              # base

    if ($format =~ /^binary(\d+)\z/) {
        $k = $1;
        $b = 2;
    } elsif ($format =~ /^decimal(\d+)(dpd|bcd)?\z/) {
        $k = $1;
        $b = 10;
        $enc = $2 || 'dpd';     # default is dencely-packed decimals (DPD)
    } elsif ($format eq 'half') {
        $k = 16;
        $b = 2;
    } elsif ($format eq 'single') {
        $k = 32;
        $b = 2;
    } elsif ($format eq 'double') {
        $k = 64;
        $b = 2;
    } elsif ($format eq 'quadruple') {
        $k = 128;
        $b = 2;
    } elsif ($format eq 'octuple') {
        $k = 256;
        $b = 2;
    } elsif ($format eq 'sexdecuple') {
        $k = 512;
        $b = 2;
    }

    if ($b == 2) {

        # Get the parameters for this format.

        my $p;                      # precision (in bits)
        my $t;                      # number of bits in significand
        my $w;                      # number of bits in exponent

        if ($k == 16) {             # binary16 (half-precision)
            $p = 11;
            $t = 10;
            $w =  5;
        } elsif ($k == 32) {        # binary32 (single-precision)
            $p = 24;
            $t = 23;
            $w =  8;
        } elsif ($k == 64) {        # binary64 (double-precision)
            $p = 53;
            $t = 52;
            $w = 11;
        } else {                    # binaryN (quadruple-precition and above)
            if ($k &lt; 128 || $k != 32 * sprintf('%.0f', $k / 32)) {
                croak "Number of bits must be 16, 32, 64, or &gt;= 128 and",
                  " a multiple of 32";
            }
            $p = $k - sprintf('%.0f', 4 * log($k) / log(2)) + 13;
            $t = $p - 1;
            $w = $k - $t - 1;
        }

        # The maximum exponent, minimum exponent, and exponent bias.

        my $emax = $class -&gt; new(2) -&gt; bpow($w - 1) -&gt; bdec();
        my $emin = 1 - $emax;
        my $bias = $emax;

        # Get numerical sign, exponent, and mantissa/significand for bit
        # string.

        my $sign = 0;
        my $expo;
        my $mant;

        if ($x -&gt; is_nan()) {                   # nan
            $sign = 1;
            $expo = $emax -&gt; copy() -&gt; binc();
            $mant = $class -&gt; new(2) -&gt; bpow($t - 1);
        } elsif ($x -&gt; is_inf()) {              # inf
            $sign = 1 if $x -&gt; is_neg();
            $expo = $emax -&gt; copy() -&gt; binc();
            $mant = $class -&gt; bzero();
        } elsif ($x -&gt; is_zero()) {             # zero
            $expo = $emin -&gt; copy() -&gt; bdec();
            $mant = $class -&gt; bzero();
        } else {                                # normal and subnormal

            $sign = 1 if $x -&gt; is_neg();

            # Now we need to compute the mantissa and exponent in base $b.

            my $binv = $class -&gt; new("0.5");
            my $b    = $class -&gt; new(2);
            my $one  = $class -&gt; bone();

            # We start off by initializing the exponent to zero and the
            # mantissa to the input value. Then we increase the mantissa and
            # decrease the exponent, or vice versa, until the mantissa is in
            # the desired range or we hit one of the limits for the exponent.

            $mant = $x -&gt; copy() -&gt; babs();

            # We need to find the base 2 exponent. First make an estimate of
            # the base 2 exponent, before adjusting it below. We could skip
            # this estimation and go straight to the while-loops below, but the
            # loops are slow, especially when the final exponent is far from
            # zero and even more so if the number of digits is large. This
            # initial estimation speeds up the computation dramatically.
            #
            #   log2($m * 10**$e) = log10($m + 10**$e) * log(10)/log(2)
            #                     = (log10($m) + $e) * log(10)/log(2)
            #                     = (log($m)/log(10) + $e) * log(10)/log(2)

            my ($m, $e) = $x -&gt; nparts();
            my $ms = $m -&gt; numify();
            my $es = $e -&gt; numify();

            my $expo_est = (log(abs($ms))/log(10) + $es) * log(10)/log(2);
            $expo_est = int($expo_est);

            # Limit the exponent.

            if ($expo_est &gt; $emax) {
                $expo_est = $emax;
            } elsif ($expo_est &lt; $emin) {
                $expo_est = $emin;
            }

            # Don't multiply by a number raised to a negative exponent. This
            # will cause a division, whose result is truncated to some fixed
            # number of digits. Instead, multiply by the inverse number raised
            # to a positive exponent.

            $expo = $class -&gt; new($expo_est);
            if ($expo_est &gt; 0) {
                $mant = $mant -&gt; bmul($binv -&gt; copy() -&gt; bpow($expo));
            } elsif ($expo_est &lt; 0) {
                my $expo_abs = $expo -&gt; copy() -&gt; bneg();
                $mant = $mant -&gt; bmul($b -&gt; copy() -&gt; bpow($expo_abs));
            }

            # Final adjustment of the estimate above.

            while ($mant &gt;= $b &amp;&amp; $expo &lt;= $emax) {
                $mant = $mant -&gt; bmul($binv);
                $expo = $expo -&gt; binc();
            }

            while ($mant &lt; $one &amp;&amp; $expo &gt;= $emin) {
                $mant = $mant -&gt; bmul($b);
                $expo = $expo -&gt; bdec();
            }

            # This is when the magnitude is larger than what can be represented
            # in this format. Encode as infinity.

            if ($expo &gt; $emax) {
                $mant = $class -&gt; bzero();
                $expo = $emax -&gt; copy() -&gt; binc();
            }

            # This is when the magnitude is so small that the number is encoded
            # as a subnormal number.
            #
            # If the magnitude is smaller than that of the smallest subnormal
            # number, and rounded downwards, it is encoded as zero. This works
            # transparently and does not need to be treated as a special case.
            #
            # If the number is between the largest subnormal number and the
            # smallest normal number, and the value is rounded upwards, the
            # value must be encoded as a normal number. This must be treated as
            # a special case.

            elsif ($expo &lt; $emin) {

                # Scale up the mantissa (significand), and round to integer.

                my $const = $class -&gt; new($b) -&gt; bpow($t - 1);
                $mant = $mant -&gt; bmul($const);
                $mant = $mant -&gt; bfround(0);

                # If the mantissa overflowed, encode as the smallest normal
                # number.

                if ($mant == $const -&gt; bmul($b)) {
                    $mant = $mant -&gt; bzero();
                    $expo = $expo -&gt; binc();
                }
            }

            # This is when the magnitude is within the range of what can be
            # encoded as a normal number.

            else {

                # Remove implicit leading bit, scale up the mantissa
                # (significand) to an integer, and round.

                $mant = $mant -&gt; bdec();
                my $const = $class -&gt; new($b) -&gt; bpow($t);
                $mant = $mant -&gt; bmul($const) -&gt; bfround(0);

                # If the mantissa overflowed, encode as the next larger value.
                # This works correctly also when the next larger value is
                # infinity.

                if ($mant == $const) {
                    $mant = $mant -&gt; bzero();
                    $expo = $expo -&gt; binc();
                }
            }
        }

        $expo = $expo -&gt; badd($bias);           # add bias

        my $signbit = "$sign";

        my $mantbits = $mant -&gt; to_bin();
        $mantbits = ("0" x ($t - CORE::length($mantbits))) . $mantbits;

        my $expobits = $expo -&gt; to_bin();
        $expobits = ("0" x ($w - CORE::length($expobits))) . $expobits;

        my $bin = $signbit . $expobits . $mantbits;
        return pack "B*", $bin;
    }

    croak("The format '$format' is not yet supported.");
}

sub as_hex {
    # return number as hexadecimal string (only for integers defined)

    my (undef, $x, @r) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x-&gt;bstr() if $x-&gt;{sign} !~ /^[+-]$/; # inf, nan etc
    return '0x0' if $x-&gt;is_zero();

    return $nan if $x-&gt;{_es} ne '+';    # how to do 1e-1 in hex?

    my $z = $LIB-&gt;_copy($x-&gt;{_m});
    if (! $LIB-&gt;_is_zero($x-&gt;{_e})) {   # &gt; 0
        $z = $LIB-&gt;_lsft($z, $x-&gt;{_e}, 10);
    }
    my $str = $LIB-&gt;_as_hex($z);
    return $x-&gt;{sign} eq '-' ? "-$str" : $str;
}

sub as_oct {
    # return number as octal digit string (only for integers defined)

    my (undef, $x, @r) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x-&gt;bstr() if $x-&gt;{sign} !~ /^[+-]$/; # inf, nan etc
    return '00' if $x-&gt;is_zero();

    return $nan if $x-&gt;{_es} ne '+';    # how to do 1e-1 in octal?

    my $z = $LIB-&gt;_copy($x-&gt;{_m});
    if (! $LIB-&gt;_is_zero($x-&gt;{_e})) {   # &gt; 0
        $z = $LIB-&gt;_lsft($z, $x-&gt;{_e}, 10);
    }
    my $str = $LIB-&gt;_as_oct($z);
    return $x-&gt;{sign} eq '-' ? "-$str" : $str;
}

sub as_bin {
    # return number as binary digit string (only for integers defined)

    my (undef, $x, @r) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x-&gt;bstr() if $x-&gt;{sign} !~ /^[+-]$/; # inf, nan etc
    return '0b0' if $x-&gt;is_zero();

    return $nan if $x-&gt;{_es} ne '+';    # how to do 1e-1 in binary?

    my $z = $LIB-&gt;_copy($x-&gt;{_m});
    if (! $LIB-&gt;_is_zero($x-&gt;{_e})) {   # &gt; 0
        $z = $LIB-&gt;_lsft($z, $x-&gt;{_e}, 10);
    }
    my $str = $LIB-&gt;_as_bin($z);
    return $x-&gt;{sign} eq '-' ? "-$str" : $str;
}

sub numify {
    # Make a Perl scalar number from a Math::BigFloat object.

    my (undef, $x, @r) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    if ($x -&gt; is_nan()) {
        require Math::Complex;
        my $inf = $Math::Complex::Inf;
        return $inf - $inf;
    }

    if ($x -&gt; is_inf()) {
        require Math::Complex;
        my $inf = $Math::Complex::Inf;
        return $x -&gt; is_negative() ? -$inf : $inf;
    }

    # Create a string and let Perl's atoi()/atof() handle the rest.

    return 0 + $x -&gt; bnstr();
}

###############################################################################
# Private methods and functions.
###############################################################################

sub import {
    my $class = shift;
    $IMPORT++;                  # remember we did import()
    my @a;                      # unrecognized arguments

    my @import = ();

    while (@_) {
        my $param = shift;

        # Enable overloading of constants.

        if ($param eq ':constant') {
            overload::constant

                integer =&gt; sub {
                    $class -&gt; new(shift);
                },

                float   =&gt; sub {
                    $class -&gt; new(shift);
                },

                binary  =&gt; sub {
                    # E.g., a literal 0377 shall result in an object whose value
                    # is decimal 255, but new("0377") returns decimal 377.
                    return $class -&gt; from_oct($_[0]) if $_[0] =~ /^0_*[0-7]/;
                    $class -&gt; new(shift);
                };
            next;
        }

        # Upgrading.

        if ($param eq 'upgrade') {
            $class -&gt; upgrade(shift);
            next;
        }

        # Downgrading.

        if ($param eq 'downgrade') {
            $class -&gt; downgrade(shift);
            next;
        }

        # Accuracy.

        if ($param eq 'accuracy') {
            $class -&gt; accuracy(shift);
            next;
        }

        # Precision.

        if ($param eq 'precision') {
            $class -&gt; precision(shift);
            next;
        }

        # Rounding mode.

        if ($param eq 'round_mode') {
            $class -&gt; round_mode(shift);
            next;
        }

        # Fall-back accuracy.

        if ($param eq 'div_scale') {
            $class -&gt; div_scale(shift);
            next;
        }

        # Backend library.

        if ($param =~ /^(lib|try|only)\z/) {
            push @import, $param;
            push @import, shift() if @_;
            next;
        }

        if ($param eq 'with') {
            # alternative class for our private parts()
            # XXX: no longer supported
            # $LIB = shift() || 'Calc';
            # carp "'with' is no longer supported, use 'lib', 'try', or 'only'";
            shift;
            next;
        }

        # Unrecognized parameter.

        push @a, $param;
    }

    Math::BigInt -&gt; import(@import);

    # find out which library was actually loaded
    $LIB = Math::BigInt -&gt; config('lib');

    $class -&gt; SUPER::import(@a);                        # for subclasses
    $class -&gt; export_to_level(1, $class, @a) if @a;     # need this, too
}

sub _len_to_steps {
    # Given D (digits in decimal), compute N so that N! (N factorial) is
    # at least D digits long. D should be at least 50.
    my $d = shift;

    # two constants for the Ramanujan estimate of ln(N!)
    my $lg2 = log(2 * 3.14159265) / 2;
    my $lg10 = log(10);

    # D = 50 =&gt; N =&gt; 42, so L = 40 and R = 50
    my $l = 40;
    my $r = $d;

    # Otherwise this does not work under -Mbignum and we do not yet have "no
    # bignum;" :(
    $l = $l-&gt;numify if ref($l);
    $r = $r-&gt;numify if ref($r);
    $lg2 = $lg2-&gt;numify if ref($lg2);
    $lg10 = $lg10-&gt;numify if ref($lg10);

    # binary search for the right value (could this be written as the reverse of
    # lg(n!)?)
    while ($r - $l &gt; 1) {
        my $n = int(($r - $l) / 2) + $l;
        my $ramanujan
          = int(($n * log($n) - $n + log($n * (1 + 4*$n*(1+2*$n))) / 6 + $lg2)
                / $lg10);
        $ramanujan &gt; $d ? $r = $n : $l = $n;
    }
    $l;
}

sub _log {
    # internal log function to calculate ln() based on Taylor series.
    # Modifies $x in place.
    my ($x, $scale) = @_;
    my $class = ref $x;

    # in case of $x == 1, result is 0
    return $x -&gt; bzero() if $x -&gt; is_one();

    # XXX TODO: rewrite this in a similar manner to bexp()

    # http://www.efunda.com/math/taylor_series/logarithmic.cfm?search_string=log

    # u = x-1, v = x+1
    #              _                               _
    # Taylor:     |    u    1   u^3   1   u^5       |
    # ln (x)  = 2 |   --- + - * --- + - * --- + ... |  x &gt; 0
    #             |_   v    3   v^3   5   v^5      _|

    # This takes much more steps to calculate the result and is thus not used
    # u = x-1
    #              _                               _
    # Taylor:     |    u    1   u^2   1   u^3       |
    # ln (x)  = 2 |   --- + - * --- + - * --- + ... |  x &gt; 1/2
    #             |_   x    2   x^2   3   x^3      _|

    # scale used in intermediate computations
    my $scaleup = $scale + 4;

    my ($v, $u, $numer, $denom, $factor, $f);

    $v = $x -&gt; copy();
    $v = $v -&gt; binc();                  # v = x+1
    $x = $x -&gt; bdec();
    $u = $x -&gt; copy();                  # u = x-1; x = x-1

    $x = $x -&gt; bdiv($v, $scaleup);        # first term: u/v

    $numer = $u -&gt; copy();              # numerator
    $denom = $v -&gt; copy();              # denominator

    $u = $u -&gt; bmul($u);                # u^2
    $v = $v -&gt; bmul($v);                # v^2

    $numer = $numer -&gt; bmul($u);        # u^3
    $denom = $denom -&gt; bmul($v);        # v^3

    $factor = $class -&gt; new(3);
    $f = $class -&gt; new(2);

    while (1) {
        my $next = $numer -&gt; copy() -&gt; bround($scaleup)
          -&gt; bdiv($denom -&gt; copy() -&gt; bmul($factor) -&gt; bround($scaleup), $scaleup);

        $next-&gt;{accuracy} = undef;
        $next-&gt;{precision} = undef;
        my $x_prev = $x -&gt; copy();
        $x = $x -&gt; badd($next);

        last if $x -&gt; bacmp($x_prev) == 0;

        # calculate things for the next term
        $numer  = $numer -&gt; bmul($u);
        $denom  = $denom -&gt; bmul($v);
        $factor = $factor -&gt; badd($f);
    }

    $x = $x -&gt; bmul($f);             # $x *= 2
    $x = $x -&gt; bround($scale);
}

sub _log_10 {
    # Internal log function based on reducing input to the range of 0.1 .. 9.99
    # and then "correcting" the result to the proper one. Modifies $x in place.
    my ($x, $scale) = @_;
    my $class = ref $x;

    # Taking blog() from numbers greater than 10 takes a *very long* time, so we
    # break the computation down into parts based on the observation that:
    #  blog(X*Y) = blog(X) + blog(Y)
    # We set Y here to multiples of 10 so that $x becomes below 1 - the smaller
    # $x is the faster it gets. Since 2*$x takes about 10 times as
    # long, we make it faster by about a factor of 100 by dividing $x by 10.

    # The same observation is valid for numbers smaller than 0.1, e.g. computing
    # log(1) is fastest, and the further away we get from 1, the longer it
    # takes. So we also 'break' this down by multiplying $x with 10 and subtract
    # the log(10) afterwards to get the correct result.

    # To get $x even closer to 1, we also divide by 2 and then use log(2) to
    # correct for this. For instance if $x is 2.4, we use the formula:
    #  blog(2.4 * 2) == blog(1.2) + blog(2)
    # and thus calculate only blog(1.2) and blog(2), which is faster in total
    # than calculating blog(2.4).

    # In addition, the values for blog(2) and blog(10) are cached.

    # Calculate the number of digits before the dot, i.e., 1 + floor(log10(x)):
    #   x = 123      =&gt; dbd =  3
    #   x = 1.23     =&gt; dbd =  1
    #   x = 0.0123   =&gt; dbd = -1
    #   x = 0.000123 =&gt; dbd = -3
    #   etc.

    my $dbd = $LIB-&gt;_num($x-&gt;{_e});
    $dbd = -$dbd if $x-&gt;{_es} eq '-';
    $dbd += $LIB-&gt;_len($x-&gt;{_m});

    # more than one digit (e.g. at least 10), but *not* exactly 10 to avoid
    # infinite recursion

    my $calc = 1;               # do some calculation?

    # No upgrading or downgrading in the intermediate computations.

    my $upg = $class -&gt; upgrade();
    my $dng = $class -&gt; downgrade();
    $class -&gt; upgrade(undef);
    $class -&gt; downgrade(undef);

    # disable the shortcut for 10, since we need log(10) and this would recurse
    # infinitely deep
    if ($x-&gt;{_es} eq '+' &amp;&amp;                     # $x == 10
        ($LIB-&gt;_is_one($x-&gt;{_e}) &amp;&amp;
         $LIB-&gt;_is_one($x-&gt;{_m})))
    {
        $dbd = 0;               # disable shortcut
        # we can use the cached value in these cases
        if ($scale &lt;= $LOG_10_A) {
            $x = $x-&gt;bzero();
            $x = $x-&gt;badd($LOG_10); # modify $x in place
            $calc = 0;                      # no need to calc, but round
        }
        # if we can't use the shortcut, we continue normally
    } else {
        # disable the shortcut for 2, since we maybe have it cached
        if (($LIB-&gt;_is_zero($x-&gt;{_e}) &amp;&amp;        # $x == 2
             $LIB-&gt;_is_two($x-&gt;{_m})))
        {
            $dbd = 0;           # disable shortcut
            # we can use the cached value in these cases
            if ($scale &lt;= $LOG_2_A) {
                $x = $x-&gt;bzero();
                $x = $x-&gt;badd($LOG_2); # modify $x in place
                $calc = 0;                     # no need to calc, but round
            }
            # if we can't use the shortcut, we continue normally
        }
    }

    # if $x = 0.1, we know the result must be 0-log(10)
    if ($calc != 0 &amp;&amp;
        ($x-&gt;{_es} eq '-' &amp;&amp;                    # $x == 0.1
         ($LIB-&gt;_is_one($x-&gt;{_e}) &amp;&amp;
          $LIB-&gt;_is_one($x-&gt;{_m}))))
    {
        $dbd = 0;               # disable shortcut
        # we can use the cached value in these cases
        if ($scale &lt;= $LOG_10_A) {
            $x = $x-&gt;bzero();
            $x = $x-&gt;bsub($LOG_10);
            $calc = 0;          # no need to calc, but round
        }
    }

    return $x if $calc == 0;    # already have the result

    # default: these correction factors are undef and thus not used
    my $l_10;                   # value of ln(10) to A of $scale
    my $l_2;                    # value of ln(2) to A of $scale

    my $two = $class-&gt;new(2);

    # $x == 2 =&gt; 1, $x == 13 =&gt; 2, $x == 0.1 =&gt; 0, $x == 0.01 =&gt; -1
    # so don't do this shortcut for 1 or 0
    if (($dbd &gt; 1) || ($dbd &lt; 0)) {
        # convert our cached value to an object if not already (avoid doing this
        # at import() time, since not everybody needs this)
        $LOG_10 = $class-&gt;new($LOG_10, undef, undef) unless ref $LOG_10;

        # got more than one digit before the dot, or more than one zero after
        # the dot, so do:
        #  log(123)    == log(1.23) + log(10) * 2
        #  log(0.0123) == log(1.23) - log(10) * 2

        if ($scale &lt;= $LOG_10_A) {
            # use cached value
            $l_10 = $LOG_10-&gt;copy(); # copy for mul
        } else {
            # else: slower, compute and cache result

            # shorten the time to calculate log(10) based on the following:
            # log(1.25 * 8) = log(1.25) + log(8)
            #               = log(1.25) + log(2) + log(2) + log(2)

            # first get $l_2 (and possible compute and cache log(2))
            $LOG_2 = $class-&gt;new($LOG_2, undef, undef) unless ref $LOG_2;
            if ($scale &lt;= $LOG_2_A) {
                # use cached value
                $l_2 = $LOG_2-&gt;copy(); # copy() for the mul below
            } else {
                # else: slower, compute and cache result
                $l_2 = $two-&gt;copy();
                $l_2 = $l_2-&gt;_log($scale); # scale+4, actually
                $LOG_2 = $l_2-&gt;copy(); # cache the result for later
                # the copy() is for mul below
                $LOG_2_A = $scale;
            }

            # now calculate log(1.25):
            $l_10 = $class-&gt;new('1.25');
            $l_10 = $l_10-&gt;_log($scale); # scale+4, actually

            # log(1.25) + log(2) + log(2) + log(2):
            $l_10 = $l_10-&gt;badd($l_2);
            $l_10 = $l_10-&gt;badd($l_2);
            $l_10 = $l_10-&gt;badd($l_2);
            $LOG_10 = $l_10-&gt;copy(); # cache the result for later
            # the copy() is for mul below
            $LOG_10_A = $scale;
        }
        $dbd-- if ($dbd &gt; 1);       # 20 =&gt; dbd=2, so make it dbd=1
        $l_10 = $l_10-&gt;bmul($class-&gt;new($dbd)); # log(10) * (digits_before_dot-1)
        my $dbd_sign = '+';
        if ($dbd &lt; 0) {
            $dbd = -$dbd;
            $dbd_sign = '-';
        }
        ($x-&gt;{_e}, $x-&gt;{_es}) =
          $LIB -&gt; _ssub($x-&gt;{_e}, $x-&gt;{_es}, $LIB-&gt;_new($dbd), $dbd_sign);
    }

    # Now: 0.1 &lt;= $x &lt; 10 (and possible correction in l_10)

    ### Since $x in the range 0.5 .. 1.5 is MUCH faster, we do a repeated div
    ### or mul by 2 (maximum times 3, since x &lt; 10 and x &gt; 0.1)

    $HALF = $class-&gt;new($HALF) unless ref($HALF);

    my $twos = 0;               # default: none (0 times)
    while ($x-&gt;bacmp($HALF) &lt;= 0) { # X &lt;= 0.5
        $twos--;
        $x = $x-&gt;bmul($two);
    }
    while ($x-&gt;bacmp($two) &gt;= 0) { # X &gt;= 2
        $twos++;
        $x = $x-&gt;bdiv($two, $scale+4); # keep all digits
    }
    $x = $x-&gt;bround($scale+4);
    # $twos &gt; 0 =&gt; did mul 2, &lt; 0 =&gt; did div 2 (but we never did both)
    # So calculate correction factor based on ln(2):
    if ($twos != 0) {
        $LOG_2 = $class-&gt;new($LOG_2, undef, undef) unless ref $LOG_2;
        if ($scale &lt;= $LOG_2_A) {
            # use cached value
            $l_2 = $LOG_2-&gt;copy(); # copy() for the mul below
        } else {
            # else: slower, compute and cache result
            $l_2 = $two-&gt;copy();
            $l_2 = $l_2-&gt;_log($scale); # scale+4, actually
            $LOG_2 = $l_2-&gt;copy(); # cache the result for later
            # the copy() is for mul below
            $LOG_2_A = $scale;
        }
        $l_2 = $l_2-&gt;bmul($twos);      # * -2 =&gt; subtract, * 2 =&gt; add
    } else {
        undef $l_2;
    }

    $x = $x-&gt;_log($scale);       # need to do the "normal" way
    $x = $x-&gt;badd($l_10) if defined $l_10; # correct it by ln(10)
    $x = $x-&gt;badd($l_2) if defined $l_2;   # and maybe by ln(2)

    # Restore globals

    $class -&gt; upgrade($upg);
    $class -&gt; downgrade($dng);

    # all done, $x contains now the result
    $x;
}

sub _pow {
    # Calculate a power where $y is a non-integer, like 2 ** 0.3
    my ($x, $y, @r) = @_;
    my $class = ref($x);

    # if $y == 0.5, it is sqrt($x)
    $HALF = $class-&gt;new($HALF) unless ref($HALF);
    return $x-&gt;bsqrt(@r, $y) if $y-&gt;bcmp($HALF) == 0;

    # Using:
    # a ** x == e ** (x * ln a)

    # u = y * ln x
    #                _                         _
    # Taylor:       |   u    u^2    u^3         |
    # x ** y  = 1 + |  --- + --- + ----- + ...  |
    #               |_  1    1*2   1*2*3       _|

    # we need to limit the accuracy to protect against overflow
    my $fallback = 0;
    my ($scale, @params);
    ($x, @params) = $x-&gt;_find_round_parameters(@r);

    return $x if $x-&gt;is_nan();  # error in _find_round_parameters?

    # no rounding at all, so must use fallback
    if (scalar @params == 0) {
        # simulate old behaviour
        $params[0] = $class-&gt;div_scale(); # and round to it as accuracy
        $params[1] = undef;               # disable P
        $scale = $params[0]+4;            # at least four more for proper round
        $params[2] = $r[2];               # round mode by caller or undef
        $fallback = 1;                    # to clear a/p afterwards
    } else {
        # the 4 below is empirical, and there might be cases where it is not
        # enough...
        $scale = abs($params[0] || $params[1]) + 4; # take whatever is defined
    }

    # When user set globals, they would interfere with our calculation, so
    # disable them and later re-enable them.

    my $ab = $class -&gt; accuracy();
    my $pb = $class -&gt; precision();
    $class -&gt; accuracy(undef);
    $class -&gt; precision(undef);

    # Disabling upgrading and downgrading is no longer necessary to avoid an
    # infinite recursion, but it avoids unnecessary upgrading and downgrading in
    # the intermediate computations.

    my $upg = $class -&gt; upgrade();
    my $dng = $class -&gt; downgrade();
    $class -&gt; upgrade(undef);
    $class -&gt; downgrade(undef);

    # We also need to disable any set A or P on $x (_find_round_parameters took
    # them already into account), since these would interfere, too.

    $x-&gt;{accuracy} = undef;
    $x-&gt;{precision} = undef;

    my ($limit, $v, $u, $below, $factor, $next, $over);

    $u = $x-&gt;copy()-&gt;blog(undef, $scale)-&gt;bmul($y);
    my $do_invert = ($u-&gt;{sign} eq '-');
    $u = $u-&gt;bneg()  if $do_invert;
    $v = $class-&gt;bone();        # 1
    $factor = $class-&gt;new(2);   # 2
    $x = $x-&gt;bone();                 # first term: 1

    $below = $v-&gt;copy();
    $over = $u-&gt;copy();

    $limit = $class-&gt;new("1E-". ($scale-1));
    while (3 &lt; 5) {
        # we calculate the next term, and add it to the last
        # when the next term is below our limit, it won't affect the outcome
        # anymore, so we stop:
        $next = $over-&gt;copy()-&gt;bdiv($below, $scale);
        last if $next-&gt;bacmp($limit) &lt;= 0;
        $x = $x-&gt;badd($next);
        # calculate things for the next term
        $over *= $u;
        $below *= $factor;
        $factor = $factor-&gt;binc();

        last if $x-&gt;{sign} !~ /^[-+]$/;
    }

    if ($do_invert) {
        my $x_copy = $x-&gt;copy();
        $x = $x-&gt;bone-&gt;bdiv($x_copy, $scale);
    }

    # shortcut to not run through _find_round_parameters again
    if (defined $params[0]) {
        $x = $x-&gt;bround($params[0], $params[2]); # then round accordingly
    } else {
        $x = $x-&gt;bfround($params[1], $params[2]); # then round accordingly
    }
    if ($fallback) {
        # clear a/p after round, since user did not request it
        $x-&gt;{accuracy} = undef;
        $x-&gt;{precision} = undef;
    }

    # Restore globals. We need to do it like this, because setting one
    # undefines the other.

    if (defined $ab) {
        $class -&gt; accuracy($ab);
    } else {
        $class -&gt; precision($pb);
    }

    $class -&gt; upgrade($upg);
    $class -&gt; downgrade($dng);

    $x;
}

# These functions are only provided for backwards compabibility so that old
# version of Math::BigRat etc. don't complain about missing them.

sub _e_add {
    my ($x, $y, $xs, $ys) = @_;
    return $LIB -&gt; _sadd($x, $xs, $y, $ys);
}

sub _e_sub {
    my ($x, $y, $xs, $ys) = @_;
    return $LIB -&gt; _ssub($x, $xs, $y, $ys);
}

1;

__END__

=pod

=head1 NAME

Math::BigFloat - arbitrary size floating point math package

=head1 SYNOPSIS

  use Math::BigFloat;

  # Configuration methods (may be used as class methods and instance methods)

  Math::BigFloat-&gt;accuracy();     # get class accuracy
  Math::BigFloat-&gt;accuracy($n);   # set class accuracy
  Math::BigFloat-&gt;precision();    # get class precision
  Math::BigFloat-&gt;precision($n);  # set class precision
  Math::BigFloat-&gt;round_mode();   # get class rounding mode
  Math::BigFloat-&gt;round_mode($m); # set global round mode, must be one of
                                  # 'even', 'odd', '+inf', '-inf', 'zero',
                                  # 'trunc', or 'common'
  Math::BigFloat-&gt;config("lib");  # name of backend math library

  # Constructor methods (when the class methods below are used as instance
  # methods, the value is assigned the invocand)

  $x = Math::BigFloat-&gt;new($str);               # defaults to 0
  $x = Math::BigFloat-&gt;new('0x123');            # from hexadecimal
  $x = Math::BigFloat-&gt;new('0o377');            # from octal
  $x = Math::BigFloat-&gt;new('0b101');            # from binary
  $x = Math::BigFloat-&gt;from_hex('0xc.afep+3');  # from hex
  $x = Math::BigFloat-&gt;from_hex('cafe');        # ditto
  $x = Math::BigFloat-&gt;from_oct('1.3267p-4');   # from octal
  $x = Math::BigFloat-&gt;from_oct('01.3267p-4');  # ditto
  $x = Math::BigFloat-&gt;from_oct('0o1.3267p-4'); # ditto
  $x = Math::BigFloat-&gt;from_oct('0377');        # ditto
  $x = Math::BigFloat-&gt;from_bin('0b1.1001p-4'); # from binary
  $x = Math::BigFloat-&gt;from_bin('0101');        # ditto
  $x = Math::BigFloat-&gt;from_ieee754($b, "binary64");  # from IEEE-754 bytes
  $x = Math::BigFloat-&gt;bzero();                 # create a +0
  $x = Math::BigFloat-&gt;bone();                  # create a +1
  $x = Math::BigFloat-&gt;bone('-');               # create a -1
  $x = Math::BigFloat-&gt;binf();                  # create a +inf
  $x = Math::BigFloat-&gt;binf('-');               # create a -inf
  $x = Math::BigFloat-&gt;bnan();                  # create a Not-A-Number
  $x = Math::BigFloat-&gt;bpi();                   # returns pi

  $y = $x-&gt;copy();        # make a copy (unlike $y = $x)
  $y = $x-&gt;as_int();      # return as BigInt
  $y = $x-&gt;as_float();    # return as a Math::BigFloat
  $y = $x-&gt;as_rat();      # return as a Math::BigRat

  # Boolean methods (these don't modify the invocand)

  $x-&gt;is_zero();          # if $x is 0
  $x-&gt;is_one();           # if $x is +1
  $x-&gt;is_one("+");        # ditto
  $x-&gt;is_one("-");        # if $x is -1
  $x-&gt;is_inf();           # if $x is +inf or -inf
  $x-&gt;is_inf("+");        # if $x is +inf
  $x-&gt;is_inf("-");        # if $x is -inf
  $x-&gt;is_nan();           # if $x is NaN

  $x-&gt;is_positive();      # if $x &gt; 0
  $x-&gt;is_pos();           # ditto
  $x-&gt;is_negative();      # if $x &lt; 0
  $x-&gt;is_neg();           # ditto

  $x-&gt;is_odd();           # if $x is odd
  $x-&gt;is_even();          # if $x is even
  $x-&gt;is_int();           # if $x is an integer

  # Comparison methods

  $x-&gt;bcmp($y);           # compare numbers (undef, &lt; 0, == 0, &gt; 0)
  $x-&gt;bacmp($y);          # compare absolutely (undef, &lt; 0, == 0, &gt; 0)
  $x-&gt;beq($y);            # true if and only if $x == $y
  $x-&gt;bne($y);            # true if and only if $x != $y
  $x-&gt;blt($y);            # true if and only if $x &lt; $y
  $x-&gt;ble($y);            # true if and only if $x &lt;= $y
  $x-&gt;bgt($y);            # true if and only if $x &gt; $y
  $x-&gt;bge($y);            # true if and only if $x &gt;= $y

  # Arithmetic methods

  $x-&gt;bneg();             # negation
  $x-&gt;babs();             # absolute value
  $x-&gt;bsgn();             # sign function (-1, 0, 1, or NaN)
  $x-&gt;bnorm();            # normalize (no-op)
  $x-&gt;binc();             # increment $x by 1
  $x-&gt;bdec();             # decrement $x by 1
  $x-&gt;badd($y);           # addition (add $y to $x)
  $x-&gt;bsub($y);           # subtraction (subtract $y from $x)
  $x-&gt;bmul($y);           # multiplication (multiply $x by $y)
  $x-&gt;bmuladd($y,$z);     # $x = $x * $y + $z
  $x-&gt;bdiv($y);           # division (floored), set $x to quotient
                          # return (quo,rem) or quo if scalar
  $x-&gt;btdiv($y);          # division (truncated), set $x to quotient
                          # return (quo,rem) or quo if scalar
  $x-&gt;bmod($y);           # modulus (x % y)
  $x-&gt;btmod($y);          # modulus (truncated)
  $x-&gt;bmodinv($mod);      # modular multiplicative inverse
  $x-&gt;bmodpow($y,$mod);   # modular exponentiation (($x ** $y) % $mod)
  $x-&gt;bpow($y);           # power of arguments (x ** y)
  $x-&gt;blog();             # logarithm of $x to base e (Euler's number)
  $x-&gt;blog($base);        # logarithm of $x to base $base (e.g., base 2)
  $x-&gt;bexp();             # calculate e ** $x where e is Euler's number
  $x-&gt;bnok($y);           # x over y (binomial coefficient n over k)
  $x-&gt;bsin();             # sine
  $x-&gt;bcos();             # cosine
  $x-&gt;batan();            # inverse tangent
  $x-&gt;batan2($y);         # two-argument inverse tangent
  $x-&gt;bsqrt();            # calculate square root
  $x-&gt;broot($y);          # $y'th root of $x (e.g. $y == 3 =&gt; cubic root)
  $x-&gt;bfac();             # factorial of $x (1*2*3*4*..$x)

  $x-&gt;blsft($n);          # left shift $n places in base 2
  $x-&gt;blsft($n,$b);       # left shift $n places in base $b
                          # returns (quo,rem) or quo (scalar context)
  $x-&gt;brsft($n);          # right shift $n places in base 2
  $x-&gt;brsft($n,$b);       # right shift $n places in base $b
                          # returns (quo,rem) or quo (scalar context)

  # Bitwise methods

  $x-&gt;bblsft($y);         # bitwise left shift
  $x-&gt;bbrsft($y);         # bitwise right shift
  $x-&gt;band($y);           # bitwise and
  $x-&gt;bior($y);           # bitwise inclusive or
  $x-&gt;bxor($y);           # bitwise exclusive or
  $x-&gt;bnot();             # bitwise not (two's complement)

  # Rounding methods
  $x-&gt;round($A,$P,$mode); # round to accuracy or precision using
                          # rounding mode $mode
  $x-&gt;bround($n);         # accuracy: preserve $n digits
  $x-&gt;bfround($n);        # $n &gt; 0: round to $nth digit left of dec. point
                          # $n &lt; 0: round to $nth digit right of dec. point
  $x-&gt;bfloor();           # round towards minus infinity
  $x-&gt;bceil();            # round towards plus infinity
  $x-&gt;bint();             # round towards zero

  # Other mathematical methods

  $x-&gt;bgcd($y);            # greatest common divisor
  $x-&gt;blcm($y);            # least common multiple

  # Object property methods (do not modify the invocand)

  $x-&gt;sign();              # the sign, either +, - or NaN
  $x-&gt;digit($n);           # the nth digit, counting from the right
  $x-&gt;digit(-$n);          # the nth digit, counting from the left
  $x-&gt;length();            # return number of digits in number
  ($xl,$f) = $x-&gt;length(); # length of number and length of fraction
                           # part, latter is always 0 digits long
                           # for Math::BigInt objects
  $x-&gt;mantissa();          # return (signed) mantissa as BigInt
  $x-&gt;exponent();          # return exponent as BigInt
  $x-&gt;parts();             # return (mantissa,exponent) as BigInt
  $x-&gt;sparts();            # mantissa and exponent (as integers)
  $x-&gt;nparts();            # mantissa and exponent (normalised)
  $x-&gt;eparts();            # mantissa and exponent (engineering notation)
  $x-&gt;dparts();            # integer and fraction part
  $x-&gt;fparts();            # numerator and denominator
  $x-&gt;numerator();         # numerator
  $x-&gt;denominator();       # denominator

  # Conversion methods (do not modify the invocand)

  $x-&gt;bstr();         # decimal notation, possibly zero padded
  $x-&gt;bsstr();        # string in scientific notation with integers
  $x-&gt;bnstr();        # string in normalized notation
  $x-&gt;bestr();        # string in engineering notation
  $x-&gt;bdstr();        # string in decimal notation
  $x-&gt;bfstr();        # string in fractional notation

  $x-&gt;as_hex();       # as signed hexadecimal string with prefixed 0x
  $x-&gt;as_bin();       # as signed binary string with prefixed 0b
  $x-&gt;as_oct();       # as signed octal string with prefixed 0
  $x-&gt;to_ieee754($format); # to bytes encoded according to IEEE 754-2008

  # Other conversion methods

  $x-&gt;numify();           # return as scalar (might overflow or underflow)

=head1 DESCRIPTION

Math::BigFloat provides support for arbitrary precision floating point.
Overloading is also provided for Perl operators.

All operators (including basic math operations) are overloaded if you
declare your big floating point numbers as

  $x = Math::BigFloat -&gt; new('12_3.456_789_123_456_789E-2');

Operations with overloaded operators preserve the arguments, which is
exactly what you expect.

=head2 Input

Input values to these routines may be any scalar number or string that looks
like a number. Anything that is accepted by Perl as a literal numeric constant
should be accepted by this module.

=over

=item *

Leading and trailing whitespace is ignored.

=item *

Leading zeros are ignored, except for floating point numbers with a binary
exponent, in which case the number is interpreted as an octal floating point
number. For example, "01.4p+0" gives 1.5, "00.4p+0" gives 0.5, but "0.4p+0"
gives a NaN. And while "0377" gives 255, "0377p0" gives 255.

=item *

If the string has a "0x" or "0X" prefix, it is interpreted as a hexadecimal
number.

=item *

If the string has a "0o" or "0O" prefix, it is interpreted as an octal number. A
floating point literal with a "0" prefix is also interpreted as an octal number.

=item *

If the string has a "0b" or "0B" prefix, it is interpreted as a binary number.

=item *

Underline characters are allowed in the same way as they are allowed in literal
numerical constants.

=item *

If the string can not be interpreted, NaN is returned.

=item *

For hexadecimal, octal, and binary floating point numbers, the exponent must be
separated from the significand (mantissa) by the letter "p" or "P", not "e" or
"E" as with decimal numbers.

=back

Some examples of valid string input

    Input string                Resulting value

    123                         123
    1.23e2                      123
    12300e-2                    123

    67_538_754                  67538754
    -4_5_6.7_8_9e+0_1_0         -4567890000000

    0x13a                       314
    0x13ap0                     314
    0x1.3ap+8                   314
    0x0.00013ap+24              314
    0x13a000p-12                314

    0o472                       314
    0o1.164p+8                  314
    0o0.0001164p+20             314
    0o1164000p-10               314

    0472                        472     Note!
    01.164p+8                   314
    00.0001164p+20              314
    01164000p-10                314

    0b100111010                 314
    0b1.0011101p+8              314
    0b0.00010011101p+12         314
    0b100111010000p-3           314

    0x1.921fb5p+1               3.14159262180328369140625e+0
    0o1.2677025p1               2.71828174591064453125
    01.2677025p1                2.71828174591064453125
    0b1.1001p-4                 9.765625e-2

=head2 Output

Output values are usually Math::BigFloat objects.

Boolean operators C&lt;is_zero()&gt;, C&lt;is_one()&gt;, C&lt;is_inf()&gt;, etc. return true or
false.

Comparison operators C&lt;bcmp()&gt; and C&lt;bacmp()&gt;) return -1, 0, 1, or
undef.

=head1 METHODS

Math::BigFloat supports all methods that Math::BigInt supports, except it
calculates non-integer results when possible. Please see L&lt;Math::BigInt&gt; for a
full description of each method. Below are just the most important differences:

=head2 Configuration methods

=over

=item accuracy()

    $x-&gt;accuracy(5);           # local for $x
    CLASS-&gt;accuracy(5);        # global for all members of CLASS
                               # Note: This also applies to new()!

    $A = $x-&gt;accuracy();       # read out accuracy that affects $x
    $A = CLASS-&gt;accuracy();    # read out global accuracy

Set or get the global or local accuracy, aka how many significant digits the
results have. If you set a global accuracy, then this also applies to new()!

Warning! The accuracy I&lt;sticks&gt;, e.g. once you created a number under the
influence of C&lt;&lt; CLASS-&gt;accuracy($A) &gt;&gt;, all results from math operations with
that number will also be rounded.

In most cases, you should probably round the results explicitly using one of
L&lt;Math::BigInt/round()&gt;, L&lt;Math::BigInt/bround()&gt; or L&lt;Math::BigInt/bfround()&gt;
or by passing the desired accuracy to the math operation as additional
parameter:

    my $x = Math::BigInt-&gt;new(30000);
    my $y = Math::BigInt-&gt;new(7);
    print scalar $x-&gt;copy()-&gt;bdiv($y, 2);           # print 4300
    print scalar $x-&gt;copy()-&gt;bdiv($y)-&gt;bround(2);   # print 4300

=item precision()

    $x-&gt;precision(-2);        # local for $x, round at the second
                              # digit right of the dot
    $x-&gt;precision(2);         # ditto, round at the second digit
                              # left of the dot

    CLASS-&gt;precision(5);      # Global for all members of CLASS
                              # This also applies to new()!
    CLASS-&gt;precision(-5);     # ditto

    $P = CLASS-&gt;precision();  # read out global precision
    $P = $x-&gt;precision();     # read out precision that affects $x

Note: You probably want to use L&lt;/accuracy()&gt; instead. With L&lt;/accuracy()&gt; you
set the number of digits each result should have, with L&lt;/precision()&gt; you
set the place where to round!

=back

=head2 Constructor methods

=over

=item from_hex()

    $x -&gt; from_hex("0x1.921fb54442d18p+1");
    $x = Math::BigFloat -&gt; from_hex("0x1.921fb54442d18p+1");

Interpret input as a hexadecimal string.A prefix ("0x", "x", ignoring case) is
optional. A single underscore character ("_") may be placed between any two
digits. If the input is invalid, a NaN is returned. The exponent is in base 2
using decimal digits.

If called as an instance method, the value is assigned to the invocand.

=item from_oct()

    $x -&gt; from_oct("1.3267p-4");
    $x = Math::BigFloat -&gt; from_oct("1.3267p-4");

Interpret input as an octal string. A single underscore character ("_") may be
placed between any two digits. If the input is invalid, a NaN is returned. The
exponent is in base 2 using decimal digits.

If called as an instance method, the value is assigned to the invocand.

=item from_bin()

    $x -&gt; from_bin("0b1.1001p-4");
    $x = Math::BigFloat -&gt; from_bin("0b1.1001p-4");

Interpret input as a hexadecimal string. A prefix ("0b" or "b", ignoring case)
is optional. A single underscore character ("_") may be placed between any two
digits. If the input is invalid, a NaN is returned. The exponent is in base 2
using decimal digits.

If called as an instance method, the value is assigned to the invocand.

=item from_ieee754()

Interpret the input as a value encoded as described in IEEE754-2008.  The input
can be given as a byte string, hex string or binary string. The input is
assumed to be in big-endian byte-order.

        # both $dbl and $mbf are 3.141592...
        $bytes = "\x40\x09\x21\xfb\x54\x44\x2d\x18";
        $dbl = unpack "d&gt;", $bytes;
        $mbf = Math::BigFloat -&gt; from_ieee754($bytes, "binary64");

=item bpi()

    print Math::BigFloat-&gt;bpi(100), "\n";

Calculate PI to N digits (including the 3 before the dot). The result is
rounded according to the current rounding mode, which defaults to "even".

This method was added in v1.87 of Math::BigInt (June 2007).

=back

=head2 Arithmetic methods

=over

=item bmuladd()

    $x-&gt;bmuladd($y,$z);

Multiply $x by $y, and then add $z to the result.

This method was added in v1.87 of Math::BigInt (June 2007).

=item binv()

    $x-&gt;binv();

Invert the value of $x, i.e., compute 1/$x.

=item bdiv()

    $q = $x-&gt;bdiv($y);
    ($q, $r) = $x-&gt;bdiv($y);

In scalar context, divides $x by $y and returns the result to the given or
default accuracy/precision. In list context, does floored division
(F-division), returning an integer $q and a remainder $r so that $x = $q * $y +
$r. The remainer (modulo) is equal to what is returned by C&lt;&lt; $x-&gt;bmod($y) &gt;&gt;.

=item bmod()

    $x-&gt;bmod($y);

Returns $x modulo $y. When $x is finite, and $y is finite and non-zero, the
result is identical to the remainder after floored division (F-division). If,
in addition, both $x and $y are integers, the result is identical to the result
from Perl's % operator.

=item bexp()

    $x-&gt;bexp($accuracy);            # calculate e ** X

Calculates the expression C&lt;e ** $x&gt; where C&lt;e&gt; is Euler's number.

This method was added in v1.82 of Math::BigInt (April 2007).

=item bnok()

    $x-&gt;bnok($y);   # x over y (binomial coefficient n over k)

Calculates the binomial coefficient n over k, also called the "choose"
function. The result is equivalent to:

    ( n )      n!
    | - |  = -------
    ( k )    k!(n-k)!

This method was added in v1.84 of Math::BigInt (April 2007).

=item bsin()

    my $x = Math::BigFloat-&gt;new(1);
    print $x-&gt;bsin(100), "\n";

Calculate the sinus of $x, modifying $x in place.

This method was added in v1.87 of Math::BigInt (June 2007).

=item bcos()

    my $x = Math::BigFloat-&gt;new(1);
    print $x-&gt;bcos(100), "\n";

Calculate the cosinus of $x, modifying $x in place.

This method was added in v1.87 of Math::BigInt (June 2007).

=item batan()

    my $x = Math::BigFloat-&gt;new(1);
    print $x-&gt;batan(100), "\n";

Calculate the arcus tanges of $x, modifying $x in place. See also L&lt;/batan2()&gt;.

This method was added in v1.87 of Math::BigInt (June 2007).

=item batan2()

    my $y = Math::BigFloat-&gt;new(2);
    my $x = Math::BigFloat-&gt;new(3);
    print $y-&gt;batan2($x), "\n";

Calculate the arcus tanges of C&lt;$y&gt; divided by C&lt;$x&gt;, modifying $y in place.
See also L&lt;/batan()&gt;.

This method was added in v1.87 of Math::BigInt (June 2007).

=item as_float()

This method is called when Math::BigFloat encounters an object it doesn't know
how to handle. For instance, assume $x is a Math::BigFloat, or subclass
thereof, and $y is defined, but not a Math::BigFloat, or subclass thereof. If
you do

    $x -&gt; badd($y);

$y needs to be converted into an object that $x can deal with. This is done by
first checking if $y is something that $x might be upgraded to. If that is the
case, no further attempts are made. The next is to see if $y supports the
method C&lt;as_float()&gt;. The method C&lt;as_float()&gt; is expected to return either an
object that has the same class as $x, a subclass thereof, or a string that
C&lt;ref($x)-E&lt;gt&gt;new()&gt; can parse to create an object.

In Math::BigFloat, C&lt;as_float()&gt; has the same effect as C&lt;copy()&gt;.

=item to_ieee754()

Encodes the invocand as a byte string in the given format as specified in IEEE
754-2008. Note that the encoded value is the nearest possible representation of
the value. This value might not be exactly the same as the value in the
invocand.

    # $x = 3.1415926535897932385
    $x = Math::BigFloat -&gt; bpi(30);

    $b = $x -&gt; to_ieee754("binary64");  # encode as 8 bytes
    $h = unpack "H*", $b;               # "400921fb54442d18"

    # 3.141592653589793115997963...
    $y = Math::BigFloat -&gt; from_ieee754($h, "binary64");

All binary formats in IEEE 754-2008 are accepted. For convenience, som aliases
are recognized: "half" for "binary16", "single" for "binary32", "double" for
"binary64", "quadruple" for "binary128", "octuple" for "binary256", and
"sexdecuple" for "binary512".

See also L&lt;https://en.wikipedia.org/wiki/IEEE_754&gt;.

=back

=head2 ACCURACY AND PRECISION

See also: L&lt;Rounding|/Rounding&gt;.

Math::BigFloat supports both precision (rounding to a certain place before or
after the dot) and accuracy (rounding to a certain number of digits). For a
full documentation, examples and tips on these topics please see the large
section about rounding in L&lt;Math::BigInt&gt;.

Since things like C&lt;sqrt(2)&gt; or C&lt;1 / 3&gt; must presented with a limited
accuracy lest a operation consumes all resources, each operation produces
no more than the requested number of digits.

If there is no global precision or accuracy set, B&lt;and&gt; the operation in
question was not called with a requested precision or accuracy, B&lt;and&gt; the
input $x has no accuracy or precision set, then a fallback parameter will
be used. For historical reasons, it is called C&lt;div_scale&gt; and can be accessed
via:

    $d = Math::BigFloat-&gt;div_scale();       # query
    Math::BigFloat-&gt;div_scale($n);          # set to $n digits

The default value for C&lt;div_scale&gt; is 40.

In case the result of one operation has more digits than specified,
it is rounded. The rounding mode taken is either the default mode, or the one
supplied to the operation after the I&lt;scale&gt;:

    $x = Math::BigFloat-&gt;new(2);
    Math::BigFloat-&gt;accuracy(5);              # 5 digits max
    $y = $x-&gt;copy()-&gt;bdiv(3);                 # gives 0.66667
    $y = $x-&gt;copy()-&gt;bdiv(3,6);               # gives 0.666667
    $y = $x-&gt;copy()-&gt;bdiv(3,6,undef,'odd');   # gives 0.666667
    Math::BigFloat-&gt;round_mode('zero');
    $y = $x-&gt;copy()-&gt;bdiv(3,6);               # will also give 0.666667

Note that C&lt;&lt; Math::BigFloat-&gt;accuracy() &gt;&gt; and
C&lt;&lt; Math::BigFloat-&gt;precision() &gt;&gt; set the global variables, and thus B&lt;any&gt;
newly created number will be subject to the global rounding B&lt;immediately&gt;. This
means that in the examples above, the C&lt;3&gt; as argument to C&lt;bdiv()&gt; will also
get an accuracy of B&lt;5&gt;.

It is less confusing to either calculate the result fully, and afterwards
round it explicitly, or use the additional parameters to the math
functions like so:

    use Math::BigFloat;
    $x = Math::BigFloat-&gt;new(2);
    $y = $x-&gt;copy()-&gt;bdiv(3);
    print $y-&gt;bround(5),"\n";               # gives 0.66667

    or

    use Math::BigFloat;
    $x = Math::BigFloat-&gt;new(2);
    $y = $x-&gt;copy()-&gt;bdiv(3,5);             # gives 0.66667
    print "$y\n";

=head2 Rounding

=over

=item bfround ( +$scale )

Rounds to the $scale'th place left from the '.', counting from the dot.
The first digit is numbered 1.

=item bfround ( -$scale )

Rounds to the $scale'th place right from the '.', counting from the dot.

=item bfround ( 0 )

Rounds to an integer.

=item bround  ( +$scale )

Preserves accuracy to $scale digits from the left (aka significant digits) and
pads the rest with zeros. If the number is between 1 and -1, the significant
digits count from the first non-zero after the '.'

=item bround  ( -$scale ) and bround ( 0 )

These are effectively no-ops.

=back

All rounding functions take as a second parameter a rounding mode from one of
the following: 'even', 'odd', '+inf', '-inf', 'zero', 'trunc' or 'common'.

The default rounding mode is 'even'. By using
C&lt;&lt; Math::BigFloat-&gt;round_mode($round_mode); &gt;&gt; you can get and set the default
mode for subsequent rounding. The usage of C&lt;$Math::BigFloat::$round_mode&gt; is
no longer supported.
The second parameter to the round functions then overrides the default
temporarily.

The C&lt;as_number()&gt; function returns a BigInt from a Math::BigFloat. It uses
'trunc' as rounding mode to make it equivalent to:

    $x = 2.5;
    $y = int($x) + 2;

You can override this by passing the desired rounding mode as parameter to
C&lt;as_number()&gt;:

    $x = Math::BigFloat-&gt;new(2.5);
    $y = $x-&gt;as_number('odd');      # $y = 3

=head1 NUMERIC LITERALS

After C&lt;use Math::BigFloat ':constant'&gt; all numeric literals in the given scope
are converted to C&lt;Math::BigFloat&gt; objects. This conversion happens at compile
time.

For example,

    perl -MMath::BigFloat=:constant -le 'print 2e-150'

prints the exact value of C&lt;2e-150&gt;. Note that without conversion of constants
the expression C&lt;2e-150&gt; is calculated using Perl scalars, which leads to an
inaccuracte result.

Note that strings are not affected, so that

    use Math::BigFloat qw/:constant/;

    $y = "1234567890123456789012345678901234567890"
            + "123456789123456789";

does not give you what you expect. You need an explicit Math::BigFloat-&gt;new()
around at least one of the operands. You should also quote large constants to
prevent loss of precision:

    use Math::BigFloat;

    $x = Math::BigFloat-&gt;new("1234567889123456789123456789123456789");

Without the quotes Perl converts the large number to a floating point constant
at compile time, and then converts the result to a Math::BigFloat object at
runtime, which results in an inaccurate result.

=head2 Hexadecimal, octal, and binary floating point literals

Perl (and this module) accepts hexadecimal, octal, and binary floating point
literals, but use them with care with Perl versions before v5.32.0, because some
versions of Perl silently give the wrong result. Below are some examples of
different ways to write the number decimal 314.

Hexadecimal floating point literals:

    0x1.3ap+8         0X1.3AP+8
    0x1.3ap8          0X1.3AP8
    0x13a0p-4         0X13A0P-4

Octal floating point literals (with "0" prefix):

    01.164p+8         01.164P+8
    01.164p8          01.164P8
    011640p-4         011640P-4

Octal floating point literals (with "0o" prefix) (requires v5.34.0):

    0o1.164p+8        0O1.164P+8
    0o1.164p8         0O1.164P8
    0o11640p-4        0O11640P-4

Binary floating point literals:

    0b1.0011101p+8    0B1.0011101P+8
    0b1.0011101p8     0B1.0011101P8
    0b10011101000p-2  0B10011101000P-2

=head2 Math library

Math with the numbers is done (by default) by a module called
Math::BigInt::Calc. This is equivalent to saying:

    use Math::BigFloat lib =&gt; "Calc";

You can change this by using:

    use Math::BigFloat lib =&gt; "GMP";

B&lt;Note&gt;: General purpose packages should not be explicit about the library to
use; let the script author decide which is best.

Note: The keyword 'lib' will warn when the requested library could not be
loaded. To suppress the warning use 'try' instead:

    use Math::BigFloat try =&gt; "GMP";

If your script works with huge numbers and Calc is too slow for them, you can
also for the loading of one of these libraries and if none of them can be used,
the code will die:

    use Math::BigFloat only =&gt; "GMP,Pari";

The following would first try to find Math::BigInt::Foo, then Math::BigInt::Bar,
and when this also fails, revert to Math::BigInt::Calc:

    use Math::BigFloat lib =&gt; "Foo,Math::BigInt::Bar";

See the respective low-level library documentation for further details.

See L&lt;Math::BigInt&gt; for more details about using a different low-level library.

=head1 EXPORTS

C&lt;Math::BigFloat&gt; exports nothing by default, but can export the C&lt;bpi()&gt;
method:

    use Math::BigFloat qw/bpi/;

    print bpi(10), "\n";

=over

=item stringify, bstr()

Both stringify and bstr() now drop the leading '+'. The old code would return
'+1.23', the new returns '1.23'. See the documentation in L&lt;Math::BigInt&gt; for
reasoning and details.

=item brsft()

The following will probably not print what you expect:

    my $c = Math::BigFloat-&gt;new('3.14159');
    print $c-&gt;brsft(3,10),"\n";     # prints 0.00314153.1415

It prints both quotient and remainder, since print calls C&lt;brsft()&gt; in list
context. Also, C&lt;&lt; $c-&gt;brsft() &gt;&gt; will modify $c, so be careful.
You probably want to use

    print scalar $c-&gt;copy()-&gt;brsft(3,10),"\n";
    # or if you really want to modify $c
    print scalar $c-&gt;brsft(3,10),"\n";

instead.

=item Modifying and =

Beware of:

    $x = Math::BigFloat-&gt;new(5);
    $y = $x;

It will not do what you think, e.g. making a copy of $x. Instead it just makes
a second reference to the B&lt;same&gt; object and stores it in $y. Thus anything
that modifies $x will modify $y (except overloaded math operators), and vice
versa. See L&lt;Math::BigInt&gt; for details and how to avoid that.

=item precision() vs. accuracy()

A common pitfall is to use L&lt;/precision()&gt; when you want to round a result to
a certain number of digits:

    use Math::BigFloat;

    Math::BigFloat-&gt;precision(4);           # does not do what you
                                            # think it does
    my $x = Math::BigFloat-&gt;new(12345);     # rounds $x to "12000"!
    print "$x\n";                           # print "12000"
    my $y = Math::BigFloat-&gt;new(3);         # rounds $y to "0"!
    print "$y\n";                           # print "0"
    $z = $x / $y;                           # 12000 / 0 =&gt; NaN!
    print "$z\n";
    print $z-&gt;precision(),"\n";             # 4

Replacing L&lt;/precision()&gt; with L&lt;/accuracy()&gt; is probably not what you want,
either:

    use Math::BigFloat;

    Math::BigFloat-&gt;accuracy(4);          # enables global rounding:
    my $x = Math::BigFloat-&gt;new(123456);  # rounded immediately
                                          #   to "12350"
    print "$x\n";                         # print "123500"
    my $y = Math::BigFloat-&gt;new(3);       # rounded to "3
    print "$y\n";                         # print "3"
    print $z = $x-&gt;copy()-&gt;bdiv($y),"\n"; # 41170
    print $z-&gt;accuracy(),"\n";            # 4

What you want to use instead is:

    use Math::BigFloat;

    my $x = Math::BigFloat-&gt;new(123456);    # no rounding
    print "$x\n";                           # print "123456"
    my $y = Math::BigFloat-&gt;new(3);         # no rounding
    print "$y\n";                           # print "3"
    print $z = $x-&gt;copy()-&gt;bdiv($y,4),"\n"; # 41150
    print $z-&gt;accuracy(),"\n";              # undef

In addition to computing what you expected, the last example also does B&lt;not&gt;
"taint" the result with an accuracy or precision setting, which would
influence any further operation.

=back

=head1 BUGS

Please report any bugs or feature requests to
C&lt;bug-math-bigint at rt.cpan.org&gt;, or through the web interface at
L&lt;https://rt.cpan.org/Ticket/Create.html?Queue=Math-BigInt&gt; (requires login).
We will be notified, and then you'll automatically be notified of progress on
your bug as I make changes.

=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc Math::BigFloat

You can also look for information at:

=over 4

=item * GitHub

L&lt;https://github.com/pjacklam/p5-Math-BigInt&gt;

=item * RT: CPAN's request tracker

L&lt;https://rt.cpan.org/Dist/Display.html?Name=Math-BigInt&gt;

=item * MetaCPAN

L&lt;https://metacpan.org/release/Math-BigInt&gt;

=item * CPAN Testers Matrix

L&lt;http://matrix.cpantesters.org/?dist=Math-BigInt&gt;

=back

=head1 LICENSE

This program is free software; you may redistribute it and/or modify it under
the same terms as Perl itself.

=head1 SEE ALSO

L&lt;Math::BigInt&gt; and L&lt;Math::BigRat&gt; as well as the backend libraries
L&lt;Math::BigInt::FastCalc&gt;, L&lt;Math::BigInt::GMP&gt;, and L&lt;Math::BigInt::Pari&gt;,
L&lt;Math::BigInt::GMPz&gt;, and L&lt;Math::BigInt::BitVect&gt;.

The pragmas L&lt;bigint&gt;, L&lt;bigfloat&gt;, and L&lt;bigrat&gt; might also be of interest. In
addition there is the L&lt;bignum&gt; pragma which does upgrading and downgrading.

=head1 AUTHORS

=over 4

=item *

Mark Biggar, overloaded interface by Ilya Zakharevich, 1996-2001.

=item *

Completely rewritten by Tels L&lt;http://bloodgate.com&gt; in 2001-2008.

=item *

Florian Ragwitz E&lt;lt&gt;flora@cpan.orgE&lt;gt&gt;, 2010.

=item *

Peter John Acklam E&lt;lt&gt;pjacklam@gmail.comE&lt;gt&gt;, 2011-.

=back

=cut
</pre></body></html>